Proxy-Einstellungen automatisch erkennen mit IDHttp

[MartinK]

Einige meiner Programm bieten die Option der verwendung eines Proxy-Servers nach Vorgabe Proxy-Server / Port / Username / Passwort an
Diese Einstellungen sind aber leider nicht immer bekannt.

Diverse Programme haben hierzu auch eine komfortablere Funktion wie"Proxy-Einstellungen automatisch erkennen"
wie realisiert man so etwas zuverlässig zusammen mit IDHttp ?

lG Martin

[geskill]

Ich würde mal ins blaue Raten und sagen die werden aus dem Internet Explorer übernommen. Also müsste man schauen wie man an die Daten des Internet Explorers kommt.

[DeddyH]

Zitat:

Zitat von geskill (Beitrag 1207606)

Also müsste man schauen wie man an die Daten des Internet Explorers kommt.

http://www.delphipraxis.net/19756-pr...-abfragen.html

[GPRSNerd]

Zitat:

Zitat von DeddyH (Beitrag 1207609)

Zitat:

Zitat von geskill (Beitrag 1207606)

Also müsste man schauen wie man an die Daten des Internet Explorers kommt.

http://www.delphipraxis.net/19756-pr...-abfragen.html

Die Funktionen zum Auslesen der Proxyeinstellungen nutze ich auch.
Ich biete dem User in meinem Programm, welches auch IdHTTP nutzt, drei Optionen für den Proxy:
1. Automatische Einstellungen (mit den Funktionen oben)
2. Manuelle Einstellungen
3. Kein Proxy

IdHTTP parametrisiere ich dann folgendermaßen:

Delphi-Quellcode:

    with IdHTTP do
    begin
      case ProxyTyp of
      1:
        begin
          if STGCommonUnit.GetProxyServer(STGCommonUnit.http, ProxyServerAuto, ProxyPortAuto) then
          begin
            ProxyParams.ProxyServer := ProxyServerAuto;
            ProxyParams.ProxyPort   := ProxyPortAuto;
          end
          else
          begin
            ProxyParams.Clear;
          end;
        end;
      2:
        begin
          ProxyParams.ProxyServer   := ProxyServer;
          ProxyParams.ProxyPort     := ProxyPort;
          ProxyParams.ProxyUsername := ProxyUser;
          ProxyParams.ProxyPassword := ProxyPassword;
        end;
      else
        begin
          ProxyParams.Clear;
        end;
      end;

[Andreas L.]

Mozilla Firefox speichert seine Proxy-Einstellungen in der Datei prefs.js im Verzeichnis %APPDATA%\Mozilla\Firefox\profiles\<<PROFILENAME>> \ ab.

Mit pos und copy kann man die Daten wunderbar extrahieren.

Auszug aus prefs.js:

Code:

user_pref("network.proxy.http", "127.0.0.1");
user_pref("network.proxy.http_port", 8080);
user_pref("network.proxy.type", 1);

[MartinK]

Vielen Dank für die tips !

Liebe Grüße ...Martin

[MartinK]

Hmmm
Zumindest hier in unserem Firmen-Netzwerk funktioniert "GetProxyServer" nicht.
Ich vermute mal, dass das daran liegt das wir dabei Username / Passwort aus den Windows-Anmeldedaten übernehmen.

Interessant ist aber, dass es Software gibt die hiermit problemlos zurecht kommt (automatische Verwendung der proxy-Einstellungen). Zb DropBox, Napster etc.
Wie machen das denn diese Programme?

lG M

[CCRDude]

Vermutlich verwenden die direkt die wininet.dll, und übergeben InternetOpen das Flag INTERNET_OPEN_TYPE_PRECONFIG.

[mjustin]

Zitat:

Zitat von MartinK (Beitrag 1207908)

Hmmm
Zumindest hier in unserem Firmen-Netzwerk funktioniert "GetProxyServer" nicht.
Ich vermute mal, dass das daran liegt das wir dabei Username / Passwort aus den Windows-Anmeldedaten übernehmen.

Interessant ist aber, dass es Software gibt die hiermit problemlos zurecht kommt (automatische Verwendung der proxy-Einstellungen). Zb DropBox, Napster etc.
Wie machen das denn diese Programme?

Die erste Frage die sich stellt ist: gibt GetProxyServer keinen Server zurück, oder gibt es einen zurück aber die Anmeldung ist nicht möglich?

Die Indy IdHTTP Komponente unterstützt auch NTLM Anmeldung. Dann wird die Verbindung mit den Anmeldedaten des Betriebssystems hergestellt. Im Prinzip sollte es also gehen (aktuelle Indy Version?)

[MartinK]

Erneut Hallo
- getProxyServer gibt keinen Server und keinen Port zurück

- Ich denke mal ich muss die Authentication mit NTLM machen. Aber das ist nicht so leicht wie gesagt. Ich finde keine funktionierenden Beispiele was alles zu tun ist.
was ich aktuell mache und leider NICHT funktioniert (407 Proxy Authorisation required) ist

Delphi-Quellcode:

uses IdAuthenticationNTLM

//.....

procedure TForm1.IdHTTPSelectProxyAuthorization(Sender: TObject;  var AuthenticationClass: TIdAuthenticationClass; AuthInfo: TIdHeaderList);
begin
  IDHTTP.ProxyParams.BasicAuthentication := False;
  AuthenticationClass := TIdNTLMAuthentication;
end;

//.....
procedure TForm1.Button1Click(Sender: TObject);
begin
  IdHTTP.HTTPOptions := IdHTTP.HTTPOptions + [hoKeepOrigProtocol] + [hoInProcessAuth];
  IdHTTP.ProxyParams.ProxyServer   := eProxyServer.Text;
  IdHTTP.ProxyParams.ProxyPort     := StrToInt(eProxyPort.Text);
  IdHTTP.ProxyParams.ProxyUsername := eUsername.Text;
  IdHTTP.ProxyParams.ProxyPassword := ePassword.Text;
  Memo1.text := IdHTTP.Get('http://www.google.de');
end;

lG Martin

PS: Seit nun fast 2 Wochen ohne Internet und Festnetzanschluss. Danke liebe Telekom für die "superflüssige Umstellung" von meinem vorherigen Provider :(

[MartinK]

Es ist echt zum Haare raufen
ich bekomme das aufgrund fehlender Beispiele echt nicht gebacken :(

Kennt sich jemand mit WinINET aus?
..evtl würde ich von indy weg auf win.init wechselen.
Allerdings bräuchte ich auch hier ein Beispiel.

lG M

[CCRDude]

Ein Beispiel wofür?

Delphi-Quellcode:

FInternetHandle := InternetOpenA('MyAppUserAgent', INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);

Das Herunterladen mal grob skizziert:

Delphi-Quellcode:

function TpkInternetHTTP.Download(Server, Path: AnsiString; Stream: TStream): boolean;
var
   hSession, hRequest: TInternetHandle;
   dwConnIC, dwConnHOR, dwSize, dwIndex: DWord;
   iEC: integer;
   pc: PAnsiChar;
   buf: string[32];
   wPort: Word;
   sPort: AnsiString;
begin
   Result := false;
   FCurrentBytes := 0;
   FTotalBytes := 0;
   FErrorCode := 0;
   // InternetConnect
   dwConnIC := 0;
   wPort := INTERNET_DEFAULT_HTTP_PORT;
   if Pos(':', Server) > 0 then begin
      sPort := Server;
      Delete(sPort, 1, Pos(':', sPort));
      SetLength(Server, Length(Server) - Length(sPort) - 1);
      wPort := StrToIntDef(sPort, INTERNET_DEFAULT_HTTP_PORT);
   end;
   hSession := InternetConnectA(FInternetHandle, PAnsiChar(Server), wPort, nil, nil, INTERNET_SERVICE_HTTP, 0, dwConnIC);
   if hSession = 0 then begin
      FErrorCode := GetLastError;
      Exit;
   end;
   try
      // HttpOpenRequest
      dwConnHOR := 0;
      hRequest := HttpOpenRequestA(hSession, nil, PAnsiChar(Path), nil, nil, nil, INTERNET_FLAG_RELOAD or INTERNET_FLAG_NO_CACHE_WRITE, dwConnHOR);
      if hRequest = 0 then begin
         FErrorCode := GetLastError;
         Exit;
      end;
      try
         // HttpSendRequest
         dwSize := 0;
         if HttpSendRequestA(hRequest, nil, 0, nil, 0) then begin
            // HttpQueryInfo - status
            SetLength(buf, 32);
            dwSize := Length(buf);
            dwIndex := 0;
            if HttpQueryInfoA(hRequest, HTTP_QUERY_STATUS_CODE, buf[1], dwSize, dwIndex) then begin
               Val(Copy(buf, 1, dwSize), FStatusCode, iEC);
               if iEC > 0 then begin
                  FStatusCode := 0;
                  // TODO : error handling
               end;
            end else begin
               FStatusCode := 0;
               // TODO : error handling
            end;            
            if (FStatusCode = 404) then begin
               FErrorCode := ERROR_NO_MORE_FILES;
               Exit;
            end;
            // HttpQueryInfo - length
            SetLength(buf, 32);
            dwSize := Length(buf);
            dwIndex := 0;
            if HttpQueryInfoA(hRequest, HTTP_QUERY_CONTENT_LENGTH, buf[1], dwSize, dwIndex) then begin
               Val(Copy(buf, 1, dwSize), FTotalBytes, iEC);
               if iEC > 0 then begin
                  FTotalBytes := 0;
                  // TODO : error handling here
               end;
            end else begin
               FTotalBytes := 0;
               // TODO : error handling here
            end;
            GetMem(pc, FBlockSize + 1);
            try
               repeat
                  if InternetReadFile(hRequest, pc, FBlockSize, dwSize) then begin
                     Stream.WriteBuffer(pc^, dwSize);
                     Inc(FCurrentBytes, dwSize);
                     // FireProgress;
                  end
                  else dwSize := 0;
               until dwSize = 0;
               // FireProgress;
            finally
               FreeMem(pc);
            end;
            // FireProgress;
            Result := true;
         end else begin
            FErrorCode := GetLastError;
         end;
      finally
         InternetCloseHandle(hRequest);
      end;
   finally
      InternetCloseHandle(hSession);
   end;
   Stream.Seek(0, soFromBeginning);
end;

[DeddyH]

Und die WinInet-Referenz findet man hier.

[MartinK]

Ich bin generell niemand der erwartet alles "ins nest gelegt zu bekommen".
ich kann nur folgendes sagen: wer sich mal auf die WWW-recherche zum Thema "NTLM" macht wird viele Fragen, (Fehl)Versuche, etc finden
allerdings aber wenige (keine?) echten Hilfen und v.a. keine "ja ich hab's geschafft und zwar so" Informationen.

Das gilt übrigens auch für die Indy-entwickler selbst.
Aber ich lasse mich gerne eines besseren belehren.

Meine eigenen Bemühungen diesbzgl. muss ich wohl leider einfrieren :oops:. Das Thema ist einfach ziemlich speziell bzw. komplex und/oder "ich bin dafür einfach programmierseitig nicht gut genug" bzw. kann derzeit nicht die dafür notwendige Energie einfliessen lassen.

[kuba]

Wer bis hier gelesen hat sollte vielleicht hier weiterlesen ...

[MartinK]

Ich habe mich heute nochmal an das Thema gemacht.

Good news: inzwischen funktioniert IDHTTP bei mir auf einem NTML authentifiziertem Proxy-Server!
Der Code sollte ebenso "Digest" und "Basic" Proxy Authentifizierung beherrschen, was ich aber in Ermangelung eines entsprechenden Proxies noch nicht austesten konnte.

Was ist zu tun:
- Ein IDHTTP Element auf das Form legen
- Ein IdSSLIOHandlerSocketOpenSSL auf das Form legen
- Beim IDHTTP Element im IOHandler "IdSSLIOHandlerSocketOpenSSL" auswählen

- Folgende evtl. noch fehlenden Anweisungen in die Uses Klausel aufnehmen:
IdBaseComponent, IdComponent, IdTCPConnection, IdTCPClient, IdAuthenticationSSPI , IdAuthentication , IdAuthenticationDigest , IdHeaderList, IdIOHandler, IdIOHandlerSocket, IdIOHandlerStack, IdSSL, IdSSLOpenSSL ;

- URL und Port des Proxies irgendwo übergeben (uB in FormCreate)

Delphi-Quellcode:

           IdHTTP1.ProxyParams.ProxyServer   := 'MyProxyServer';
           IdHTTP1.ProxyParams.ProxyPort     := 'MyProxyPort';

- Folgendes in IdHTTPMainSelectProxyAuthorization aufnehmen

Delphi-Quellcode:

procedure TForm1.IdHTTPMainSelectProxyAuthorization(Sender: TObject; var AuthenticationClass: TIdAuthenticationClass; AuthInfo: TIdHeaderList);
begin
  // First check for NTLM authentication, as you do not need to set username and password because Indy will automatically
  // handle passing your Windows Domain username and password to the proxy server
  if (pos('Proxy-Authenticate: NTLM', IdHTTPMain.Response.RawHeaders.Text)>0)
    then begin
           IdHTTP1.ProxyParams.BasicAuthentication := false;
           AuthenticationClass := TIdSSPINTLMAuthentication;
         end
    else begin
           //Next check for Basic
           if (pos('Proxy-Authenticate: Basic', IdHTTP1.Response.RawHeaders.Text)>0)
             then begin
                    AuthenticationClass := TIdBasicAuthentication;
                    IdHTTP1.ProxyParams.BasicAuthentication := true;
                   end
             else begin
                    // Then Digest
                    if (pos('Proxy-Authenticate: Digest', IdHTTPMain.Response.RawHeaders.Text)>0)
                      then AuthenticationClass := TIdDigestAuthentication
                  end;
           //.------------
           IdHTTP1.ProxyParams.ProxyUsername := 'YourUsername';
           IdHTTP1.ProxyParams.ProxyPassword := 'YourPassword';
         end;

end;

- Get-Funktion aufrufen um etwas zu machen. Z.B.

Delphi-Quellcode:

  Memo1.Lines.Text :=  IdHTTP1.Get('http://www.google.de');

Viel Spaß
Martin