IsValidURL: Testen, ob URL über HTTP erreichbar ist

[PeterPanino]

Hallo! Ich möchte in Delphi XE2 auf möglichst einfache und schnelle Weise testen, ob ein String eine über HTTP erreichbare URL darstellt: Ich habe dafür folgenden Code geschrieben:

Delphi-Quellcode:

uses ... IdHTTP;

function IsValidURL(const AURL: string): Boolean;
var
  ThisIdHTTP: TIdHTTP;
  strDummy: string;
begin
  Result := True;
  ThisIdHTTP := TIdHTTP.Create(nil);
  try
    try
      strDummy := ThisIdHTTP.Get(AURL);
    except
      Result := False;
    end;
  finally
    ThisIdHTTP.Free;
  end;
end;

procedure TForm1.btn1Click(Sender: TObject);
begin
  if IsValidURL(edt1.Text) then
    ShowMessage('This URL is valid')
  else
    ShowMessage('This URL is NOT valid');
end;

Oder gibt es eine einfachere/schnellere Möglichkeit?

Edit 27.03.2013 10:43: Eigentlich sollte die Funktion IsURLReachable heißen, denn das ist genau das, was sie tut: Prüfen, ob die URL über HTTP erreichbar ist.

[Aviator]

Vielleicht hilft dir das hier weiter wenn du nur wissen willst, ob es eine gültige URL ist.

Des Weiteren gibt es (wenn ich mich jetzt nicht täusche) auch in der WinInet bereits eine IsValidUrl Function.

Schau es dir einfach mal an.

[PeterPanino]

Danke.

[mjustin]

Schneller als Get

Delphi-Quellcode:

      strDummy := ThisIdHTTP.Get(AURL);

ist Head

Delphi-Quellcode:

      strDummy := ThisIdHTTP.Head(AURL);

Damit braucht das Programm nur Indy, das Winsock benutzt.
(Wininet ist nur ein Aufsatz auf Winsock, dessen Resourcen man durch Verwendung von Indy einspart.)

[PeterPanino]

Zitat:

Zitat von mjustin (Beitrag 1209063)

Schneller als Get

Delphi-Quellcode:

      strDummy := ThisIdHTTP.Get(AURL);

ist Head

Delphi-Quellcode:

      strDummy := ThisIdHTTP.Head(AURL);

Damit braucht das Programm nur Indy, das Winsock benutzt.
(Wininet ist nur ein Aufsatz auf Winsock, dessen Resourcen man durch Verwendung von Indy einspart.)

Mit

Delphi-Quellcode:

strDummy := ThisIdHTTP.Head(AURL);

meldet der Compiler:

E2010 Inkompatible Typen: 'string' und 'procedure, untyped pointer or untyped parameter'

Mit

Delphi-Quellcode:

ThisIdHTTP.Head(AURL);

allein (ohne Zuweisung zu einem String) wird kein Fehler ausgegeben.

[PeterPanino]

Der Vollständigkeit halber hier noch die dazu analoge Version für HTTPS-URLs:

Delphi-Quellcode:

uses ... IdHTTP, IdSSLOpenSSL;

function IsHTTPSURLReachable(const AURL: string): Boolean;
var
  lHTTP: TIdHTTP;
  lIOHandler: TIdSSLIOHandlerSocketOpenSSL;
begin
  Result := True;
  lHTTP := TIdHTTP.Create(nil);
  lIOHandler := TIdSSLIOHandlerSocketOpenSSL.Create(nil);
  try
    try
      lHTTP.IOHandler := lIOHandler;
      lHTTP.HandleRedirects := True;
      lHTTP.Head(AURL);
    except
      Result := False;
    end;
  finally
    lHTTP.Free;
    lIOHandler.Free;
  end;
end;

Edit: Die beiden DLLs müssen sich noch im Suchpfad (Programmverzeichnis) befinden:
ssleay32.dll
libeay32.dll
Die neuesten Versionen der DLLs kriegt ihr hier:
http://indy.fulgan.com/SSL/