Verständnisfrage zu Pascal und Pointer im dynamischen Array

[ATS3788]

Delphi-Quellcode:

var
aResInfo : array of TIconResInfo;
SetLength(aResInfo ,   Count);
...........

// Das geht und ist richtig  *1
Stream.Write(Pointer(aResInfo)^ , SizeOf(TIconResInfo) * count );

/// Wo zeigt der Zeiger hierhin
Stream.Write(aResInfo , SizeOf(TIconResInfo) * count );

//// oder hierhin
Stream.Write(Pointer(aResInfo) , SizeOf(TIconResInfo) * count );

Hallo
jetzt mache ich schon viele Jahre mit Delphi rum und immer wieder habe
das gleiche Problem.:pale:
Könnt mir jemand erklären warum *1 geht und wo die anderen Zeiger hinzeigen

[Uwe Raabe]

In den beiden letzten Fällen wird der Speicherbereich deiner Array-Variablen in den Stream geschrieben. Dort steht aber nur der Pointer auf das Array drin.

Ich verwende eigentlich immer diese Schreibweise:

Delphi-Quellcode:

Stream.Write(aResInfo[0] , SizeOf(aResInfo[0]) * Length(aResInfo) );

Das funktioniert auch mit nicht-dynamischen Arrays, solange sie 0-basiert sind.

[himitsu]

So wird es vielleicht etwas deutlicher.

Delphi-Quellcode:

// Das geht und ist richtig.
Stream.Write(Pointer(aResInfo)^ , SizeOf(aResInfo[0]) * Length(aResInfo) );
Stream.Write(aResInfo[0] , SizeOf(aResInfo[0]) * Length(aResInfo));
// aka
Stream.Write(Pointer(aResInfo)^ , SizeOf(TIconResInfo) * Length(aResInfo) );
Stream.Write(aResInfo[0] , SizeOf(TIconResInfo) * Length(aResInfo));

// Das geht auch und ist ebenfalls richtig, nur nicht so, wie eigentlich gewollt ist.
Stream.Write(aResInfo , SizeOf(aResInfo) );
Stream.Write(Pointer(aResInfo) , SizeOf(aResInfo) ); // hier wird ja nur der Typ [s]gecastet[/s] anders interpretiert, also es ändert sich nichts an den Daten

[ATS3788]

Danke schön
Das muss ich erst mal wirken lassen.
Mach schon viele Jahre mit Pointer rum,
aber hier habe ich alle Jahre wieder das
berühmte Brett vor dem Kopf.:shock:

[p80286]

Delphi-Quellcode:

mypointer:=@(myarray[low]);

passt immer, bei statischen und dynamischen Arrays.
Da mußt Du Dir keine Ausnahmen und Besonderheiten merken.

Gruß
K-H

[DeddyH]

Du meinst bestimmt

Delphi-Quellcode:

mypointer:=@(myarray[low(myarray)]);

[p80286]

ja :oops:

Gruß
K-H

[Namenloser]

Zitat:

Zitat von ATS3788 (Beitrag 1252253)

Hallo
jetzt mache ich schon viele Jahre mit Delphi rum und immer wieder habe
das gleiche Problem.:pale:
Könnt mir jemand erklären warum *1 geht und wo die anderen Zeiger hinzeigen

Das einzig verwirrende daran ist, dass

Delphi-Quellcode:

Write

einen

Delphi-Quellcode:

var

-Parameter verwendet. Intern ist ein var-Parameter aber nichts anderes als ein Pointer (das ist auch der Grund, weshalb man bei var-Parametern den Typ weglassen kann). Für const gilt übrigens das gleiche, bloß dass der Compiler hier einen Schreibschutz enforciert.

Delphi-Quellcode:

procedure Write(var Buffer; Size: Cardinal);

...

procedure AndereFunktion;
var Buffer: array[255] of Byte;
begin
  Write(Buffer[0], SizeOf(Buffer));

Übersetzt der Compiler sozusagen in:

Delphi-Quellcode:

procedure Write(Buffer: Pointer; Size: Cardinal);

...

procedure AndereFunction;
var Buffer: array[255] of Byte;
begin
  Write(@Buffer[0], SizeOf(Buffer));

Man beachte das @.

Das zweite Ding ist jetzt, dass ein dynamisches Array intern auch ein Pointer ist, und zwar ein Pointer auf den Speicherbereich, wo die eigentlichen Daten des Arrays liegen. Deshalb klappt der Typecast auf Pointer.

Da der Compiler bei var-Parametern aber automatisch das @ ergänzt, muss vorher noch einmal mit ^ dereferenziert werden, weil es sonst „doppelt gemoppelt“ wäre. Das @ und das ^ kürzen sich quasi weg, und man hat wieder den rohen Pointer, den man haben will.

Also, um deine Eingangsfragen noch mal komplett zu beantworten:

Delphi-Quellcode:

/// Wo zeigt der Zeiger hierhin
Stream.Write(aResInfo , SizeOf(TIconResInfo) * count );

Wie gesagt, var-Parameter werden vom Compiler den Parameter automatisch in einen Pointer übersetzt, und bei allen Aufrufen wird automatisch ein @ ergänzt. @aResInfo ist der Pointer auf die lokale Variable aResInfo (die selber wiederum ein Pointer ist). Das heißt, er zeigt irgendwo auf den Stack.

Delphi-Quellcode:

//// oder hierhin
Stream.Write(Pointer(aResInfo) , SizeOf(TIconResInfo) * count );

Das ist wieder das gleiche. Der Typecast verändert die Adresse der Variablen ja nicht.