Umrechner, kleines Problem

[bibble]

Hallo, möchte ein Programm schreiben bei dem ich Dezimal und Dual gegenseitig umwandeln kann.
In die eine richtung habe ich es hinbekommen. Von Dual in Dezimal habe ich ein Strucktogramm gefunden und es danach programmiert, bekomme als Ergebniss jedoch immer 0.
Hier mein Quelltext:

Code:

procedure TForm1.Button1Click(Sender: TObject);
var dez;faktor,i:integer;
    duz:string;
begin
edit1.Text:=duz;
dez:=0;
faktor:=1;
begin
for i:=length(duz) downto 1 do
dez:=dez+faktor*strtoint(duz[i]);
faktor:=faktor*2;
end;
edit2.Text:=inttostr(dez);
end;

Wenn einer meinen Fehler entdeckt, würde ich mich freuen.

[DeddyH]

Schau mal genau, wo Du begin und end gesetzt hast. Bei entsprechender Einrückung sieht man das auf den ersten Blick.

[bibble]

ok, habe das zweite begin jetzt erst nach der schleife gesetzt. Mir wird jedoch immer noch als endergebnis die Zahl 0 ausgegebe :(
ich versteh es nicht :/

[Klaus01]

. vielleicht

Delphi-Quellcode:

edit1.Text:=duz;

nach

Delphi-Quellcode:

duz:=edit1.Text;

ändern.

Grüße
Klaus

[DeddyH]

Falsche Zuweisung am Anfang, so klappt es:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  dez, faktor, i: integer;
  duz: string;
begin
  //Edit1.Text := duz;
  duz := Edit1.Text;
  dez := 0;
  faktor := 1;
  for i := Length(duz) downto 1 do
    begin
      dez := dez + faktor * strtoint(duz[i]);
      faktor := faktor * 2;
    end;
  Edit2.Text := inttostr(dez);
end;

Ich würde das aber allgemeingültiger gestalten, z.B. so:

Delphi-Quellcode:

function BinaryToInt(const BinaryStr: string): integer;
const
  BITSPERBYTE = 8;
var
  i, faktor, MaxDigits: integer;
begin
  MaxDigits := SizeOf(Result) * BITSPERBYTE;
  if Length(BinaryStr) > MaxDigits then
    raise Exception.CreateFmt('Eingabe zu lang, maximal %d Zeichen erlaubt',
      [MaxDigits]);
  Result := 0;
  faktor := 1;
  for i := Length(BinaryStr) downto 1 do
    begin
      case BinaryStr[i] of
        '0':
          ; //Keine Änderung, daher keine Aktion nötig
        '1':
          Result := Result or faktor;
        else
          raise Exception.Create('Ungültige Eingabe, nur 0 und 1 erlaubt.');
      end;
      faktor := faktor shl 1;
    end;
end;

[bibble]

super es läuft jetzt. vielen dank :-D