TCustomControl: Focus erhalten wenn Programm aktiv wird

[DCoderHH]

Hallo,

ich habe mir ein TCustomControl erstellt. Dieses muss folgende Fälle unterscheiden können:

1) Das Control hat durch einen Mausklick den Fokus erhalten
erkenne ich über MouseDown(Button: TMouseButton; Shift: TShiftState; X, Y: Integer);

2) Das Control hat durch die Tab-Taste den Fokus erhalten
erkenne ich über WMSetFocus(...) und dadurch dass MouseDown(...) wurde nicht aufgerufen wurde

3) Das Control hat den Fokus erhalten, als das Programm aktiv wurde
(vorher war ein anderes Programm aktiv, dann wurde das eigene Programm aktiv durch Alt+Tab oder einen Mausklick (nicht auf das TCustomControl))

Wie kann ich nun Fall 3 erkennen?

[Sir Rufo]

Indem du auf TApplicationEvents.OnActivate hörst?

[TOndrej]

Zum Beispiel:

Delphi-Quellcode:

type
  TMyControl = class(TCustomControl)
  protected
    function MainWndHook(var Message: TMessage): Boolean;
    procedure Paint; override;
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  end;

constructor TMyControl.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  if not (csDesigning in ComponentState) then
    Application.HookMainWindow(MainWndHook);
end;

destructor TMyControl.Destroy;
begin
  if not (csDesigning in ComponentState) then
    Application.UnhookMainWindow(MainWndHook);
  inherited Destroy;
end;

function TMyControl.MainWndHook(var Message: TMessage): Boolean;
begin
  case Message.Msg of
    CM_ACTIVATE,
    CM_DEACTIVATE:
      Invalidate;
  end;
  Result := False;
end;

procedure TMyControl.Paint;
const
  Colors: array[Boolean] of TColor = (clSilver, clRed);
begin
  Canvas.Brush.Color := Colors[(csDesigning in ComponentState) or  Application.Active];
  Canvas.Brush.Style := bsSolid;
  Canvas.FillRect(ClientRect);
end;

[DCoderHH]

@TOndrej: Danke, das ist genau das was ich gesucht habe. Es funktioniert und kann in der Komponenten gekapselt werden.

[TOndrej]

Gern geschehen! :)