Radiogroup / TRadiogroup unter FMX / Firemonkey

[Delphi-Laie]

Hallo Delphifreunde!

Schon wieder fordert mich eine Tücke der Migration eines VCL- zu einem FMX-Projekt mehr oder minder heraus.

Für die visuelle Komponente (T)SpinEdit, die es unter FMX nicht gibt, konnte ich noch einen akzeptablen Ersatz in der Toolpalette auftreiben: (T)SpinBox.

Doch an (T)RadioGroup, die es auch nicht gibt, scheitere ich. Nun fand ich http://stackoverflow.com/questions/1...-a-single-form, das hilft schonmal etwas.

Alle Radiobuttons mit dem gleichen Gruppennamen ("GroupName") verhalten sich wie eine RadioGroup, das habe ich verstanden, und das passiert auch so: Es läßt sich immer nur ein Radiobutten der jeweiligen Gruppe auf aktivieren.

Doch wie spricht man diese gruppierten Radiobuttons unter einem gemeinsamen Namen an?

Man könnte sie auf einer Groupbox ablegen, das funktioniert auch, und im Strukturfenster ist die Unterordnung zu sehen.

Nun hatte ich gehofft, daß wegen dieser Hierarchie die einzelnen Radiobuttons über

Groupbox1.Radiobutton1
Groupbox2.Radiobutton2

usw. ansprechbar sein könnten, doch das klappt leider nicht. Also, nochmals zum Verständnis, ich suche das Analogon von / zu

Radiogroup1.Itemindex

oder

RadioGroup1.Controls[x]

unter FMX.

Läßt sich die (T)RadioGroup unter FMX soweit "nachbilden" oder "zusammenbasteln", daß ihre einzelnen gruppierten Radiobuttons unter einem gemeinsamen Namen ansprechbar sind, falls ja, wie?

Vielen Dank und Gruß

Delphi-Laie

[Uwe Raabe]

Zitat:

Zitat von Delphi-Laie (Beitrag 1352734)

Läßt sich die (T)RadioGroup unter FMX soweit "nachbilden" oder "zusammenbasteln", daß ihre einzelnen gruppierten Radiobuttons unter einem gemeinsamen Namen ansprechbar sind, falls ja, wie?

Kann ich leider nicht direkt beantworten, da ich das TMS FMX UI Pack verwende, in dem eine RadioGroup-Komponente enthalten ist. Also indirekt: Ja, aber das Wie darf ich dir so nicht zeigen.

[Delphi-Laie]

Gut, danke!

Daraus entnehme ich:

- die TRadioGroup-Klasse wurde in FMX nicht mit aufgenommen (warum, zum Teufel, nicht?)
- sie wird aber dennoch als so wichtig eingestuft, daß man ihr Fehlen schmerzlich vermißte, so daß "von dritter Hand" eine eigene "Ersatzklasse" kreiert wurde
- diese Klasse ist in einer professionellen Software "TMS FMX UI Pack" von TMS-Software enthalten, der Einblick in deren Quellcodes für Nichtkäufer deshalb nicht statthaft.

Habe ich das richtig verstanden?

[Harry Stahl]

Du könntest für die GroupBox z.B. einen Classhelper verwenden, um ItemIndex mit relativ wenig Veränderungsaufwand in der bisherigen Notation weiter zu verwenden.

Die Lösung setzt allerdings voraus, dass Du die "TAG"-Eigenschften der verwendeten TRadioButtons, die in der GroipBox liegen, selber zuvor manuell durchnumerierst.

Delphi-Quellcode:

unit Unit38;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.StdCtrls,
  FMX.Controls.Presentation, FMX.Layouts, FMX.ListBox, FMX.Edit, FMX.EditBox,
  FMX.SpinBox;

type
  TRadioGroupHelper = class helper for TGroupBox
    // Setzt voraus, dass die TAG-Werte der TRadioButton manuell zuvor auf 0..x durchnumeriert wurden
    function ItemIndex: Integer;
    procedure SetItemIndex (NewIndex: Integer);
  end;

  TForm38 = class(TForm)
    RadioButton0: TRadioButton;
    GroupBox1: TGroupBox;
    RadioButton1: TRadioButton;
    RadioButton2: TRadioButton;
    bnGetIndex: TButton;
    bnSetIndex: TButton;
    procedure bnGetIndexClick(Sender: TObject);
    procedure bnSetIndexClick(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form38: TForm38;

implementation

{$R *.fmx}

{ TRadioGroupHelper }

function TRadioGroupHelper.ItemIndex: Integer;
var
  L: Integer;
begin
  Result := -1;

  for L := 0 to ChildrenCount-1 do begin
    if  Children[L] is TRadioButton then begin
      if (Children[L] as TRadioButton).IsChecked then begin
        Result := (Children[L] as TRadioButton).Tag;
      end;
    end;
  end;
end;

procedure TRadioGroupHelper.SetItemIndex(NewIndex: Integer);
var
  L: Integer;
begin
  for L := 0 to ChildrenCount-1 do begin
    if  Children[L] is TRadioButton then begin
      if (Children[L] as TRadioButton).Tag = NewIndex then begin
        (Children[L] as TRadioButton).IsChecked := True;
      end;
    end;
  end;
end;

// Test

procedure TForm38.bnGetIndexClick(Sender: TObject);
begin
  ShowMessage (GroupBox1.ItemIndex.ToString);
end;

procedure TForm38.bnSetIndexClick(Sender: TObject);
begin
  GroupBox1.SetItemIndex (1); // statt GroupBox1.itemIndex := 1;
end;


end.

Davon abgesehen: Emba betont immer, dass sie das machen, was die User wünschen und dafür gibt es den Feature-Request. Schlage doch einfach mal vor, dass es auch eine RadioGoup-Komponente in FMX geben soll, wenn die Dir so sehr fehlt.

[Delphi-Laie]

Tausend Dank, Harry Stahl! Ich werde mich heranwagen.

Zitat:

Zitat von Harry Stahl (Beitrag 1352737)

Davon abgesehen: Emba betont immer, dass sie das machen, was die User wünschen und dafür gibt es den Feature-Request. Schlage doch einfach mal vor, dass es auch eine RadioGoup-Komponente in FMX geben soll, wenn die Dir so sehr fehlt.

Ich werde mich hüten. Wie käme ich dazu?

Schon einmal monierte ich das Fehlen von Selbstverständlichkeiten (meiner Ansicht nach) in FMX und äußerte, daß man als erstes nur die VCL durchzugehen und weitgehend nachzubilden braucht, um eine wesentliche, gewohnte Funktionalität zu erreichen - wie soll man sonst migrieren?! Einem Moderator fiel nichts besseres ein, als mir das Bleiben bei der VCL "vor den Latz zu knallen". Nunja, vielleicht war das gar nicht so verkehrt, allmählich bin ich wirklich soweit...Daniel äußerte sich differenzierter: "...anderes Konzept...". Deshalb nehme ich an, daß Embarcadero sich etwas dabei dachte (nur was?), darauf zu verzichten. Und ich war ziemlich erstaunt, daß sich in diesem hochfrequentierten Forum auch nach einigen FMX-Jahren dazu noch keine Diskussion fand. Daß diese jahrzehntelang bewährte und häufig benutze Komponente "TRadioGroup" auch in der neunten FMX-Version noch fehlt und von einem Drittanbieter bereitgestellt wird, empfinde ich als ein gewisses Armutszeugnis.

Ist nun auch egal, Dein Quellcode sieht sehr gut aus, ich werde ihn sehr bald zu verwenden versuchen, nochmals vielen Dank!

[Delphi-Laie]

Das funktioniert soweit so, wie eine gewöhnliche (T)RadioGroup, nochmals herzlichen Dank, Harry Stahl!

Was mich jedoch erst irritierte - weil anfangs nicht durchschaute - und auch jetzt noch stört, ist, daß auf den FMX-Formularen die Ereignisse "OnClick" bei diesen zu einer Radiogroup zusammengesetzten Radiobuttons (außer erstmaligem Setzen) und auch bei den Button nicht, wie gewohnt, schon dann reagiert, wenn der Mausklick erfolgt, sondern erst dann, wenn danach die Maus bewegt wird. Hält man die Maus ruhig und klickt, passiert mithin erstmal nichts. Allerdings erfolgt die graphische Reaktion an den visuellen Elementen sofort, also schon beim Mausklick, nur wird eben das On-Ereignis erst beim nachfolgenden Mausverschieben ausgelöst.

Weiß jemand, ob das so sein soll?

Edit: Das ist bei mir unter Windows 7 so, nicht jedoch unter Windows XP. Liegt demnach vielleicht an Windows.

[Bernhard Geyer]

Zitat:

Zitat von Delphi-Laie (Beitrag 1352742)

Ich werde mich hüten. Wie käme ich dazu?

Schon einmal monierte ich das Fehlen von Selbstverständlichkeiten (meiner Ansicht nach) in FMX und äußerte, daß man als erstes nur die VCL durchzugehen und weitgehend nachzubilden braucht, um eine wesentliche, gewohnte Funktionalität zu erreichen - wie soll man sonst migrieren?! Einem Moderator fiel nichts besseres ein, als mir das Bleiben bei der VCL "vor den Latz zu knallen".

Welche Diskussion/Beitrag soll das sein. Im Forum finde ich das nicht und auch im QC und Quality-Portal finde ich hierzu nichts.

Zitat:

Zitat von Delphi-Laie (Beitrag 1352742)

Und ich war ziemlich erstaunt, daß sich in diesem hochfrequentierten Forum auch nach einigen FMX-Jahren dazu noch keine Diskussion fand. Daß diese jahrzehntelang bewährte und häufig benutze Komponente "TRadioGroup" auch in der neunten FMX-Version noch fehlt und von einem Drittanbieter bereitgestellt wird, empfinde ich als ein gewisses Armutszeugnis.

Höchstwahrscheinlich vermisst diese RadioGroup keiner richtig. Im Quality-Portal hat bisher auch keiner danach nach gefragt.
Und Harry hat dir eine Lösung gezeigt wie du das Property wieder bekommst. Alternativ bau selbst ein Composit-Control das auch die Items-List nachbaut. ist kein Hexenwerk.

[Delphi-Laie]

Zitat:

Zitat von Bernhard Geyer (Beitrag 1352757)

Welche Diskussion/Beitrag soll das sein. Im Forum finde ich das nicht und auch im QC und Quality-Portal finde ich hierzu nichts.

http://www.delphipraxis.net/190588-b...ehlen-xe2.html

Zitat:

Zitat von Bernhard Geyer (Beitrag 1352757)

Höchstwahrscheinlich vermisst diese RadioGroup keiner richtig.

Auch die Leute von TMS-Software nicht?

Zitat:

Zitat von Bernhard Geyer (Beitrag 1352757)

Und Harry hat dir eine Lösung gezeigt wie du das Property wieder bekommst.

Yo, damit komme ich klar, und dafür bin ich ihm auch nach wie vor dankbar.

[Harry Stahl]

Zitat:

Zitat von Delphi-Laie (Beitrag 1352754)

Das funktioniert soweit so, wie eine gewöhnliche (T)RadioGroup, nochmals herzlichen Dank, Harry Stahl!

Gerne.

Zitat:

Zitat von Delphi-Laie (Beitrag 1352754)

Was mich jedoch erst irritierte - weil anfangs nicht durchschaute - und auch jetzt noch stört, ist, daß auf den FMX-Formularen die Ereignisse "OnClick" bei diesen zu einer Radiogroup zusammengesetzten Radiobuttons (außer erstmaligem Setzen) und auch bei den Button nicht, wie gewohnt, schon dann reagiert, wenn der Mausklick erfolgt, sondern erst dann, wenn danach die Maus bewegt wird. Hält man die Maus ruhig und klickt, passiert mithin erstmal nichts. Allerdings erfolgt die graphische Reaktion an den visuellen Elementen sofort, also schon beim Mausklick, nur wird eben das On-Ereignis erst beim nachfolgenden Mausverschieben ausgelöst.

Weiß jemand, ob das so sein soll?

Edit: Das ist bei mir unter Windows 7 so, nicht jedoch unter Windows XP. Liegt demnach vielleicht an Windows.

Das kann ich so nicht bestätigen. Für welches On-Event soll das denn gelten? Hier mal kurz beim OnClick getestet, wird sofort ausgelöst.

[Delphi-Laie]

Harry, allerbesten Dank für Deine Ausdauer mit mir bzw. meinem Anliegen!

Zitat:

Zitat von Harry Stahl (Beitrag 1352760)

Das kann ich so nicht bestätigen. Für welches On-Event soll das denn gelten? Hier mal kurz beim OnClick getestet, wird sofort ausgelöst.

Um das zu verdeutlichen, hänge ich hier das nächste kompilierte Projekt an.

Dieser Effekt tritt bei mir, wie gesagt, nicht unter XP, wohl aber unter Windows 7 auf, und zwar [I]ab dem zweiten Mausklick auf irgendein Control des Formulares (also nicht ab dem zweiten Mausklick auf das jeweilige Control). Also ab dem jeweils zweiten Male mit unbewegter Maus klicken - und nichts passiert. Erst beim darauffolgenden Verschieben der Maus wird OnClick nachträglich ausgelöst. Müßte an der verspäteten Aktualisierung des ausgegebenen ItemIndex' sichtbar werden. Hoffentlich ist dieser Effekt auch auf anderen Windows' reproduzierbar.

Ganz optimal wäre es natürlich, wenn man die jeweilien OnClick-Events der RadioButtons auch noch unter einem OnClick-Event zusammenfassen könnte, wie bei der VCL-TRadioGroup. Ob das möglich ist, weiß ich nicht, vermute es aber, weil die TRadioGroup das ja auch ermöglicht. Vermutlich können die Profis hier sofort ein "Ja" entgegnen. Leider wurde ich aus den Quelltexten der TRadioGroup bisher nicht so recht schlauer. Aber so, wie es jetzt steht, geht es auch.

Edit: Einen entscheidenden Satz, der das letztgenannte wieder fraglicher werden läßt, fand ich just in der Delphi-Hilfe: "Die Einträge in einem Optionsfeldgruppenobjekt sind spezielle Instanzen von TRadioButton, die von TCustomRadioGroup erzeugt wurden. TRadioButton-Instanzen, die unabhängig erzeugt wurden, können nicht in eine Optionsfeldgruppe aufgenommen werden."

[Bernhard Geyer]

Zitat:

Zitat von Delphi-Laie (Beitrag 1352758)

Zitat:

Zitat von Bernhard Geyer (Beitrag 1352757)

Welche Diskussion/Beitrag soll das sein. Im Forum finde ich das nicht und auch im QC und Quality-Portal finde ich hierzu nichts.

http://www.delphipraxis.net/190588-b...ehlen-xe2.html

Du kennst sicherlich den Sprung "Wie man in den Wald hineinruft..."


Und das man bei einem neuen Framework versuch Altlasten abzuschneiden halte ich für sehr gut.
Und da scheinbar der Aufschrei nicht so groß war bezüglich dieser fehlenden Features (oder hier Events) waren sie nicht so relevant bzw. sind für einen Ansatz einer Portablen Portierung kontraproduktiv (wie z.B. DPI-Events).

Zitat:

Zitat von Delphi-Laie (Beitrag 1352758)

Zitat:

Zitat von Bernhard Geyer (Beitrag 1352757)

Höchstwahrscheinlich vermisst diese RadioGroup keiner richtig.

Auch die Leute von TMS-Software nicht?

Die Aufgabe solcher Komponentenhersteller ist es auch Lösungen zu bieten für Anforderungen die nicht so allgemein nötig sind. Eine TRadioGroup wäre so eine

Zitat:

Zitat von Delphi-Laie (Beitrag 1352758)

Zitat:

Zitat von Bernhard Geyer (Beitrag 1352757)

Und Harry hat dir eine Lösung gezeigt wie du das Property wieder bekommst.

Yo, damit komme ich klar, und dafür bin ich ihm auch nach wie vor dankbar.

Wie gesagt ist das eine Möglichkeit. Eine andere wäre wenn du dir selbst als Compositcontrol so eine TRadioGroup zusammenstellst.

[Delphi-Laie]

Zitat:

Zitat von Bernhard Geyer (Beitrag 1352762)

Du kennst sicherlich den Sprung "Wie man in den Wald hineinruft..."

Eher den Spruch.

Irgendwie suchst Du auf Teufel komm raus Streit. Ich habe niemanden persönlich wegen des Fehlens dieser Komponente bzw. der OnClick-Funktionalität angegriffen. Dich schon gar nicht. Nimm Dir mal ein Beispiel an Harry, der von FMX begeistert ist und dennoch nicht patzig wird. Also, was soll das?

Zitat:

Zitat von Bernhard Geyer (Beitrag 1352762)

Und das man bei einem neuen Framework versuch Altlasten abzuschneiden halte ich für sehr gut.

OnClick auf ein(em) Formular ist Altlast? Warum wurde es dann später bei FMX nachgeschoben?

Zitat:

Zitat von Bernhard Geyer (Beitrag 1352762)

Und da scheinbar der Aufschrei nicht so groß war bezüglich dieser fehlenden Features (oder hier Events) waren sie nicht so relevant bzw. sind für einen Ansatz einer Portablen Portierung kontraproduktiv (wie z.B. DPI-Events).

Die Aufgabe solcher Komponentenhersteller ist es auch Lösungen zu bieten für Anforderungen die nicht so allgemein nötig sind. Eine TRadioGroup wäre so eine.

Dann ist diese TRadioGroup also seit Delphis Urzeiten am Bedarf vorbei entwickelt und sogar in die Standard-Controlgrupe aufgenommen, also völlig deplaciert worden.

Zitat:

Zitat von Delphi-Laie (Beitrag 1352758)

Wie gesagt ist das eine Möglichkeit. Eine andere wäre wenn du dir selbst als Compositcontrol so eine TRadioGroup zusammenstellst.

Und was hat diese Bemerkung nun für einen Mehrwert gegen über Deiner gleichlautenden zuvor?

Vergiß nicht, daß ein Forum einen reichen Wissensfundus darstellt. Vielleicht steht später ja auch mal jemand vor dem Wunsche, eine RadioGroup in ein FMX-Projekt aufzunehmen (noch ist Windows nicht tot), der findet dann evlt., wenn er etwas beflissener als Du sich zu suchen danach bemüht, und muß sich dafür nicht noch aus heiterem Himmel von jemand unbeteiligten angehen lassen, sondern braucht nur noch zu schöpfen.

[Sherlock]

Ich entwickle jetzt seit 11 Monaten ausschließlich FMX. Und ja, es fehlt so einiges. Und nein, es fehlt nicht, weil man es nicht braucht. Ich bin der festen Überzeugung, man hat es vergessen, was beim Framework-Transfer eine ganz normale Sache ist, die durch ein Qualitäts- und Produktmanagement jenseits des Marketings etwas gemildert werden kann. Andererseits gibt es einiges, was man in FMX mit viel Geduld und Recherche nachbilden kann. Dazu wieder andererseits sehe ich es nicht als Aufgabe eines Entwicklers, der für sein Werkzeug eine signifikante Summe bezahlt hat, sich aus allen Ecken und Enden des Internets Workarounds für "verlorene Features" zu suchen.

@Delphi-Laie: Es ist definitiv nicht die DP das korrekte Forum und Feature-Requests zu posten. Dafür ist die Quality Central unter http://qc.embarcadero.com zuständig (entweder hab ich die Adresse falsch gespeichert, oder der Laden ist gerade mal wieder down).

Sherlock

[Delphi-Laie]

Danke, Sherlock.

Ich wollte gerade noch etwas schreiben, aber gerade da war Dein Betrag schneller.

Zitat:

Zitat von Sherlock (Beitrag 1352863)

Und nein, es fehlt nicht, weil man es nicht braucht. Ich bin der festen Überzeugung, man hat es vergessen, was beim Framework-Transfer eine ganz normale Sache ist, die durch ein Qualitäts- und Produktmanagement jenseits des Marketings etwas gemildert werden kann.

Ich wiederhole mich und schreibe es vermutlich zum dritten Male: Man muß "nur" die VCL durchgehen, dann hat man genug vor sich und eine erstmal vollständige Erledigungsliste. Sicher ist nicht alles 1:1 abbildbar, die TRadioGroup vermutlich aber schon. Immerhin wird die Übernehmbarkeit, die Migrierbarkeit bestehender Projekte doch beworben?!

Zitat:

Zitat von Sherlock (Beitrag 1352863)

Andererseits gibt es einiges, was man in FMX mit viel Geduld und Recherche nachbilden kann. Dazu wieder andererseits sehe ich es nicht als Aufgabe eines Entwicklers, der für sein Werkzeug eine signifikante Summe bezahlt hat, sich aus allen Ecken und Enden des Internets Workarounds für "verlorene Features" zu suchen.

So etwas wollte ich Bernhard Geyer eigentlich entgegnen, hatte aber keine Lust auf einen Streit mit ihm. Seine Argumentation, auf die Spitze getrieben, liefe nämlich darauf hinaus, daß man sich alles selbst zu entwickeln hat.

So, kurz zum Nachbilden der TRadioGroup: Damit man den Mausklick auf eines der in den Groupboxen enthaltenen RadioButtons wie einen Mausklick auf eine TRadioGroup behandeln kann (so, wie wir es kennen), habe ich die Ereignisbehandlungsroutine der Groupboxen mit dem gewünschten Code gefüllt. In jede der OnClick-Ereignisbehandlungsroutinen der RadioButtons legte ich dann nur noch z.B.

Delphi-Quellcode:

GroupBox1.OnClick(Sender)

Es funktioniert!

Für Euch Profis ist das sicherlich Pillepalle. Für mich aber jedesmal Experimente nach der Versuch-Und-(Nicht-Nur-)Irrtum-Methode.

Zitat:

Zitat von Sherlock (Beitrag 1352863)

@Delphi-Laie: Es ist definitiv nicht die DP das korrekte Forum und Feature-Requests zu posten. Dafür ist die Quality Central unter http://qc.embarcadero.com zuständig (entweder hab ich die Adresse falsch gespeichert, oder der Laden ist gerade mal wieder down).

Ich weiß. Meine stille Hoffnung ist ja immer, daß Herr Eißing oder jemand sonst der deutschsprachigen Embarcadero-Mitarbeiter dieses Forum überfliegt. Eine bessere Form der Rückmeldung werden sie vermutlich nicht finden.

Edit: Noch etwas zu meinem oben genannten Fehlverhalten. Nicht die Ereignisbehandlungsroutine der RadioButtons wird verzögert, wie ich nun herausfand, sondern nur die graphische Umsetzung, d.h., das Hinüberspringen des schwarzen Punktes von einem Radiobutton (dem zuletzt aktiven) zum nunmehr aktuell aktiven.

[Uwe Raabe]

Zitat:

Zitat von Sherlock (Beitrag 1352863)

Dafür ist die Quality Central unter http://qc.embarcadero.com zuständig (entweder hab ich die Adresse falsch gespeichert, oder der Laden ist gerade mal wieder down).

Das Quality Central wurde schon vor einiger Zeit durch das Quality Portal ersetzt: https://quality.embarcadero.com

[Sherlock]

@Uwe: Ich wusste, ich hab was falsch gemacht... Danke! Ich hatte das noch in der Browserhistory, darum überhaupt die Idee.

Sherlock

[Delphi-Laie]

Diese Classhelper scheinen ein recht mächtiges Potential zu haben.

Zu meinem Erstaunen kann man dort auch Properties einbauen. So konnte ich diesen Classhelper soweit modifizieren, daß man in von den vorgefertigten (T)RadioGroups gewohnter Manier auf den ItemIndex sowohl lesend als auch schreibend zugreifen kann. Für alle, die das interessiert, hier Harry Stahls von mir etwas modifizierter Quellcode:

Delphi-Quellcode:

type
  TRadioGroupHelper = class helper for TGroupBox
    // Setzt voraus, dass die TAG-Werte der TRadioButton manuell zuvor auf 0..x durchnumeriert wurden
    function GetItemIndex: Integer;
    procedure SetItemIndex (NewIndex: Integer);
    property ItemIndex: Integer read GetItemIndex write SetItemIndex;
  end;

function TRadioGroupHelper.GetItemIndex: Integer;
var
  L: Integer;
begin
  Result := -1;
  for L := 0 to ChildrenCount-1 do begin
    if Children[L] is TRadioButton then begin
      if (Children[L] as TRadioButton).IsChecked then begin
        Result := (Children[L] as TRadioButton).Tag;
      end;
    end;
  end;
end;

procedure TRadioGroupHelper.SetItemIndex(NewIndex: Integer);
var
  L: Integer;
begin
  for L := 0 to ChildrenCount-1 do begin
    if Children[L] is TRadioButton then begin
      if (Children[L] as TRadioButton).Tag = NewIndex then begin
        (Children[L] as TRadioButton).IsChecked := True;
      end;
    end;
  end;
end;

Edit: Die Groupboxen als Grundlage dieser selbstgebastelten RadioGroups benenne ich einfach in RadioGroup1 usw. um, und schon ist am Quelltext kaum noch etwas zu ändern.

[Harry Stahl]

Gute Ergänzung:thumb: