Exception wird nicht angezeigt - Ist das ein Fehler?

[samso]

Wenn ich ein Nicht-Modales-Formular anzeige das entfernt werden soll falls eine Exception auftritt, dann wird die Exception bei Delphi 10.1 (Berlin) nicht angezeigt (bzw. die Exception wird vermutlich angezeigt und sofort geschlossen). Bei (meinem) Delphi 2007 hat das noch einwandfrei funktioniert.

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
begin
  Application.CreateForm(TForm2, Form2);
  try
    Form2.Show;
    raise Exception.Create('Ein Fehler');
  finally
    Form2.Release;
  end;
end;

Das liegt mit Sicherheit daran, dass die Dialogbox der Exception als Parent das Fenster "Form2" benutzt. Weil das Fenster aber im Rahmen der Fehlerbehandlung geschlossen wird, verschwindet auch die Fehlermeldung und kann vom Benutzer nicht gesehen werden. So etwas ähnliches gab es bei Delphi 2007 auch schon*. Damals wurden Fehlermeldungen nicht mehr angezeigt, wenn sie innerhalb des FormCreate auftraten. Für diesen Fehler hatte ich damals einen Bugfix eingebaut. Möglicherweise hat dieser Bugfix auch dazu geführt, das der obige Code bei mir einwandfrei funktionierte. Daran erinnere ich mich nicht mehr :?

Meine Frage: Ist das als Bug von Delphi zu werten (=>QC), oder sollte ich das durch Änderung des Designs meiner Anwendung lösen?

*QC #75756/#78400/#78883: No exceptionmessage shown if form is released

[hoika]

Hallo,
also bei mir werden Exceptions im FormCreate angezeigt ... (D2007, XE, XE4)

[samso]

Hallo Hoika,
danke fürs Testen. Vielleicht hätte ich das nicht so ausführlich schreiben sollen. Denn das war nicht die Frage. Die Frage bezog sich eher auf den sehr speziellen Fall, den ich versuchte mit dem Quelltext darzustellen. Die Frage dabei ist eigentlich, ob es das Wert ist, dazu einen Fehlerbericht zu produzieren. Ich habe mal ein Testprojekt angehangen.

[Uwe Raabe]

Es ist tatsächlich so, daß die Exception-Meldung das aktive Fenster als Parent benutzt. Dieses hat aber zu diesem Zeitpunkt bereits ein CM_RELEASE in der Message-Queue, von dem es aber noch nichts weiß.

Jetzt könnte man ja hingehen und bei der Anzeige der Exception-Box nachschauen, ob so eine Message im aktiven Fenster in der Queue steht, aber das würde auch nur diesen einen Fall abdecken. Es kann ja auch sein, daß dieses Release erst später z.B. durch einen Timer ausgelöst wird. Womöglich ist das Verschwinden der Message-Box dann ja auch erwünscht.

In solchen Fällen ist dann wohl der Entwickler gefragt, der ja um diese Besonderheiten wissen sollte. Hier müsste also das Parent-Fenster für die Message-Box gezielt auf ein valides anderes Fenster umgelegt werden. Konkret lässt sich das in dem Beispielprojekt durch ein simples

Delphi-Quellcode:

SetFocus

erreichen. Wie das im produktiven Fall am sinnvollsten umgesetzt werden kann, vermag ich so nicht zu sagen.

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
begin
  Application.CreateForm(TForm2, Form2);
  try
    Form2.Show;
    raise Exception.Create('Ein Fehler');
  finally
    SetFocus;
    Form2.Release;
  end;
end;

[himitsu]

Jupp, der Exception-Dialog aus TApplication.ShowException nutzt eine MessageBox
und die wird von der VCL an das grade "aktive" Fenster gehängt ... wird jenes geschlossen, dann ist auch der MessageBox weg. :stupid:

Das Selbe funktioniert auch wunderschön bei ShowModal-Dialogen.

Zitat:

Delphi-Quellcode:

procedure TCustomForm.Release;
begin
  PostMessage(Handle, CM_RELEASE, 0, 0);
end;

Das gibt die Form nicht sofort, sondern erst nach Anzeige des Fehlerdialogs frei.
Ein beherztes Form.Free, ein böses ProcessMessages oder vielleicht auch nur ein Form.Hide (eventuell mit ProcessMessages) und schon hat sich die Sache.

Das war schon in Delphi 7 so, war es noch in XE und wird sich wohl zukünftig in der VCL auch nicht ändern können, da bei einer Änderung des Verhaltens garantiert irgendwas Anderes knallen tut.
(k.A. was FMX hier verbockt)

[samso]

Ok, also eher kein Fehler. Ich danke Euch.

[himitsu]

Da hier die Form "lokal" ist und von außen geschlossen wird

Delphi-Quellcode:

// weg mit der bösen globalen Variable!!!

procedure TForm1.Button1Click(Sender: TObject);
var
  Form2: TForm2;
begin
  Form2 := TForm2.Create(Self);  // oder nil, da wir das ja eh alles immer selber freigeben
  try
    Form2.PopupParent := Self;  // damit die Form2 immer über der Form1 liegt (nicht nötig bei ShowModal)
    Form2.Show;  // hier natürlich ShowModal, da sonst ja das Release/Free die Form auch ohne Exception sofort schließt ;)
    raise Exception.Create('Ein Fehler');
  finally 
    Form2.Free;
  end;
end;

Delphi-Quellcode:

type
  TForm1 = class(TForm)
    ...
  protected
    procedure Notification(AComponent: TComponent; Operation: TOperation);
  private
    Form2: TForm2;
  end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Form2 := TForm2.Create(Self);
  try
    Form2.PopupParent := Self;  // damit die Form2 immer über der Form1 liegt (nicht nötig bei ShowModal)
    Form2.Show;  // hier natürlich ShowModal, da sonst ja das Free
    raise Exception.Create('Ein Fehler');
  except
    FreeAndNil(Form2);
    raise;
  end;
end; 

procedure TForm1.Notification(AComponent: TComponent; Operation: TOperation);
begin
  if Operation = opRemove then begin
    if AComponent = Form2 then  // Form2 sagt mir, dass es mich jetzt verlassen will > siehe das Create(Self)
      Form2 := nil;  // stattdessen könnte man auch die Form2-Variable im TForm2.Destroy auf nil setzen, aber TForm2 weiß ja eigentlich nichts von dieser Variable
  end;
  inherited;
end;

// und nicht das caFree im TForm2.OnClose vergessen, außer man will die bestehende Form später erneut anzeigen können