Richedit Suche funktioniert nach Migration nicht mehr

[milpr]

Hallo liebe Community,

Ich gehe gerade meine ersten Schritte in Delphi RAD 10.1, nachdem ich viele Jahre lang in Delphi 5 und Delphi 7 programmiert habe. Eine Migration eines von mir über die Jahre entwickelten Programmes nach Delphi 10.1 hat überraschend gut funktioniert. Jetzt habe ich aber auf den zweiten Blick doch Abweichungen und Fehler bemerkt. So habe ich in dem Programm eine Routine im Einsatz, die in einem Richedit (Form2.richedit1) ein Wort sucht und kursiv setzt. Diese Routine funktionierte bisher unter Delphi 7 tadellos. Unter Delphi RAD 10.1 werden aber die falschen Abschnitte kursiv gesetzt, Delphi setzt Wörter ca. 10 Zeichen nach dem zu suchenden Wort kursiv.
Ich habe dafür keine Erklärung, außer das "Selstart" eventuell irgendwelche Formatierungsanweisungen unterschlägt und daher nicht die richtige Stelle markiert.

Hat irgendjemand eine Idee, wie ich die Routine wieder zum Laufen bringe?

Danke für Euren Input!

Die Routine:


procedure Tform1.kursiv(SearchToken :string);
(* das zu formatierende Wort *)
var StringPos: integer;
begin

(* Position des gesuchten Wortes ermitteln *)
StringPos := Pos(SearchToken,form2.RichEdit1.Text);
if StringPos > 0 then
begin

(* SelStart-Zählung beginnt bei 0, daher 1 abziehen *)
form2.RichEdit1.SelStart := StringPos-1;
form2.RichEdit1.SelLength := Length(SearchToken);

(* formatieren *)
form2.RichEdit1.SelAttributes.Style := [fsItalic];
(* Cursor an Textanfang setzen und Markierung aufheben *)
form2.RichEdit1.SelLength := 0;
form2.RichEdit1.SelStart := 0;
end;
end;

[nahpets]

In form2.RichEdit1.SelText müsste doch der markierte Text stehen. Prüfe mal bitte, ob da der gewünschte Text drinne ist. Wenn ja, ist es ein optisches Problem der RichEdit-Komponente bei der Darstellung.

Ist da aber was anderes drinne, als erwartet, scheint das Auffinden der gesuchten Zeichenfolge nicht zu funktionieren.

[milpr]

Danke für den Hinweis, habe ich gleich ausprobiert:

Tatsächlich ist in dem form2.RichEdit1.SelText der falsche Text enthalten, der dann auch kursiv wird. Aber wieso?? :?

[HolgerX]

Hmm..

Suche mal hier in DP nach Richedit und Berlin...

Ich glaube da war was mit der Zeilenlänge aufgrund UniCode und Zeilenumbruch..

[milpr]

Das habe ich vorher schon gemacht, aber außer einem Beitrag von 2009 (mit "Berlin" als Stadt) leider nichts gefunden...

[nahpets]

Naja, die Frage ist: Was steht in RichEdit1.Text, nur der pure Text? Oder der Text plus all das RTF-Zeugs, dass für die Darstellung benötigt wird?

Wenn Du im Richedit formatierten Text markierst, wird dann mit ShowMessage(Richedit.SelText) nur der reine Text ausgegeben oder mit den Formatierungsinformationen des Textes.

Es könnte sein, das hier unterschieden wird und Du mit Pos die Position des Suchbegriffes im Text mit Formatierungshinweisen bekommst, aber die Positionierung in SelText wird ohne die Formatierungshinweisen gemacht.

Was passiert, wenn Du vor der Suche etwas anders machst:

Delphi-Quellcode:

procedure Tform1.kursiv(SearchToken :string);
(* das zu formatierende Wort *)
var StringPos: integer;
begin
  (* Den gesamten Text markieren.*)
  form2.RichEdit1.SelStart := 0;
  form2.RichEdit1.SelEnd   := Length(form2.RichEdit1.Text);

  (* Position des gesuchten Wortes im markierten Text ermitteln *)
  StringPos := Pos(SearchToken,form2.RichEdit1.SelText);
  if StringPos > 0 then
  begin

    (* SelStart-Zählung beginnt bei 0, daher 1 abziehen *)
    form2.RichEdit1.SelStart := StringPos - 1;
    form2.RichEdit1.SelLength := Length(SearchToken);

    (* formatieren *)
    form2.RichEdit1.SelAttributes.Style := [fsItalic];

    (* Cursor an Textanfang setzen und Markierung aufheben *)
    form2.RichEdit1.SelLength := 0;
    form2.RichEdit1.SelStart := 0;
  end;
end;

[himitsu]

Verwende die Suchfunktion des RichEdits.
TRichEdit.FindText

Embarcadero ist blöd, hat das Richedit zerstört
und ignoriert meine Bugfixe seit Jahren.

Die haben inzwischen auf eine neuere RichEdit-Version umgestellt und RichEdit nutzt jetzt #13 als Zeilenumbruch.
Embarcadero wandelt das aber in #13#10 um, allerdings nicht bei SelStart und SelLength, wo die Positionsangaben immernoch auf #13 bezogen und somit je Zeile um 1 Zeichen verschoben sind.

[nahpets]

Das ist aber ein saugemeiner Fehler :-(

[himitsu]

http://qc.embarcadero.com/wc/qcmain.aspx?d=81621


Was "Fehler" betrifft :zwinker:
Warum ist diese Funktion in Form1, wo sie doch vorwiegend ausschließlich nur Dinge von Form2 benutzt?

[milpr]

Ja ich weiß, das ist nicht sonderlich elegant. Aber an dem Programm programmiere ich seit mittlerweile über 10 Jahren und es ist über die Jahre ziemlich gewachsen und enthält aktuell über 16000 Zeilen Code. Das könnte man sicherlich an der ein oder anderen Stelle optimieren. Nur wann die Zeit dafür nehmen... :oops:

Ansonsten möchte ich allen, die hier geantwortet haben Danken: Nach dem Einsatz von Findtext funktioniert die Routine wieder, wie sie soll. Hätte ich ohne euch nicht so schnell hinbekommen! Vielen herzlichen Dank!!!

:thumb: :thumb: :thumb:

procedure Tform1.testkursiv(SearchToken :string);
(* das zu formatierende Wort *)
var StringPos: integer;
begin
(* Position des gesuchten Wortes ermitteln *)
StringPos := form2.RichEdit1.findtext(SearchToken, 0, length(form2.RichEdit1.Text), [stMatchCase]);
if StringPos > 0 then
begin

form2.RichEdit1.SelStart := StringPos;
form2.RichEdit1.SelLength := Length(SearchToken);
(* ...und formatieren *)
form2.RichEdit1.SelAttributes.Style := [fsItalic];

(* Cursor an Textanfang setzen und Markierung aufheben *)
form2.RichEdit1.SelLength := 0;
form2.RichEdit1.SelStart := 0;

end;
end;

[p80286]

Zitat:

Zitat von milpr (Beitrag 1359563)

Ja ich weiß, das ist nicht sonderlich elegant. Aber an dem Programm programmiere ich seit mittlerweile über 10 Jahren und es ist über die Jahre ziemlich gewachsen und enthält aktuell über 16000 Zeilen Code. Das könnte man sicherlich an der ein oder anderen Stelle optimieren. Nur wann die Zeit dafür nehmen... :oops:

Da Du die Routine gerade jetzt anpackst, dann mach es jetzt richtig!

Gruß
K-H