Buchstabenhäufigkeit

[Lisa.99]

Hallo!
Ich sitze seit ca. 4 Wochen an einem Programm und komme wirklich nicht weiter.
Das erste Problem ist, dass bei den Buchstaben die im Text nicht vorhanden sind, die Null nicht ins String Grid geschrieben wird.
Wenn das läuft würde nur noch die Schleife fehlen, womit ich die Prozente berechnen kann der einzelnen Buchstaben um danach einen Vergleich anzustellen mit vorhandenen Prozentzahlen um die Sprache zu erkennen.
Ich weiß, dass es ganz schön viel ist, aber ich weiß wirklich nicht mehr weiter.
Danke schonmal im voraus!

Hier mein Quelltext:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.Grids, Vcl.StdCtrls, Vcl.ExtCtrls;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    Edit1: TEdit;
    Label1: TLabel;
    Button1: TButton;
    StringGrid1: TStringGrid;
    Button2: TButton;
    Label2: TLabel;
    Edit2: TEdit;
    Button3: TButton;
    Button4: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var  n1: integer;

  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var text : string;
    i, anzahl, Index, Ordnungszahl, result, b, ergebnis : integer;
    Buchstabe, key : char;
begin
 if not (key in [#65..#90, #97..#122, #8]) then
  key := '0';

 StringGrid1.Cells[0,0]:= 'Buchstabe';
 StringGrid1.Cells[1,0]:= 'Häufigkeit';
 StringGrid1.Cells[2,0]:= 'Prozent';
 for i := 0 to 26 do
 begin
   StringGrid1.Cells[0,i+1]:= char (i+65);
 end;
 text:= Edit1.Text;
 text:=stringreplace(text,' ','',[rfReplaceAll]);
 for n1 := 1 to length (text) do
    begin
    Buchstabe := text[n1];
    Buchstabe := Upcase (Buchstabe);
    Ordnungszahl:= Ord(Buchstabe);
    Index:= Ordnungszahl-64;
    if Index in [1..26] then
      begin
      anzahl := StrToIntDef(StringGrid1.Cells[1,Index],0);
      anzahl := anzahl + 1;
      StringGrid1.Cells[1,Index] := inttostr(anzahl);
      end;
    end;
   Edit2.Text:= inttostr(n1-1);
end;

procedure TForm1.Button2Click(Sender: TObject);
var n2, j1, i1, Bu, Er, A, B, C, D, E, F, G, H, I, J, K , L, M, N, O, P, Q, R, S, T, U, V, W, X, Y, Z, E1: integer;
begin
  {for j1 := 1 to StringGrid1.RowCount do
     begin
       if strtoint(StringGrid1.Cells[1,n2]) >= 1 then
        begin
          Bu:= strToint(StringGrid1.Cells[1,n2]);
          Er:= (Bu*100)/n1;
          StringGrid1.Cells[2,n2]:= inttostr(Er);
        end;
     end;}

  n1:= strtoint(Edit2.Text);
  A:= strtoint(StringGrid1.Cells[1,1]);
  if A >0 then
   begin
  E1:= (A*100)div n1;
  StringGrid1.Cells[2,1]:= inttostr(E1);
    end
  else
    begin
      E1:=0;
      StringGrid1.Cells[2,1]:= inttostr(E1);
    end;
end;

procedure TForm1.Button3Click(Sender: TObject);
begin
Close;
end;


end.

[Klaus01]

Zitat:

Das erste Problem ist, dass bei den Buchstaben die im Text nicht vorhanden sind, die Null nicht ins String Grid geschrieben wird.

Du könntest die Zellen des StringGrids mit "0" vorbelegen.
Denn in der Schleife werden nicht vorhandene Buchstaben nicht erfasst.

Grüße
Klaus

[Jumpy]

Bezogen auf das, was du schon hast, würde ich einfach anfänglich in einer Schleife durch alle Buchstaben laufen und das String-Grid überall auf 0 setzen.


Wenn ich es aber neu/anders machen würde, würde ich mir zunächst eine Struktur schaffen, um darin für jeden Buchstaben die Anzahl zu speichern, also z.B. ein Array. Dann analysiere ich den Text und erhöhe im Array für jeden Buchstaben um 1, wenn der Buchstabe mal wieder kommt.
Erst danach, wenn der Text analysiert ist, gebe ich den ganzen Kram im StringGrid aus, dazu brauch ich dann nur eine Schleife über alle Buchstaben und kann dann Buchstabe, Anzahl und Prozent als Anzahl/Length(Text) ins StringGird schreiben.

[Luckie]

Ich würde für die Datenhaltung kein StringGrid nehmen, sondern ein zweidimensionales Array oder besser ein Array mit einem Record oder sogar Objekte in einer ObJectList.Weil morgen findest du einen Listview schicker oder eine andere GridKomponente. Dann trennst du auch die Ermittlung der Daten und brauchst nur noch die Liste in das Grid übertragen.

[rokli]

Hallo Lisa.99!

Schön, das Du da bist!

Deine Aufgabe könnte man so nach dem guten alten EVA Prinzip (am besten mit einem Array) zerlegen:

E wie Eingabe (durcharbeiten des Textes und Zählen der Buchstaben)
V wie Verarbeitung (berechnen der Prozente) und
A wie Ausgabe (in das Grid).

Dann hast Du am Ende 3 Prozeduren, die übersichtlich die einzelnen Arbeitsschritte enthalten. Und wenn was nicht funktionieren sollte, kannst Du gezielt nach dem Fehler suchen.

@Luckie: Sind das vielleicht schon Kanonen und Spatzen?

Gruß

[Luckie]

Ich habe aus der Kanone mal eine Zwille gemacht. :)

Quick and dirty ohne Klassen ohne Objektlisten:

Ermitteln der Häufigkeit:

Delphi-Quellcode:

unit Unit6;

interface

uses
  SysUtils;

type TCharRecord = record
    FChar: AnsiChar;
    FCharCnt: Cardinal;
end;

var
  CharRecordArray: array [1..26] of TCharRecord;

procedure CntCharOccurrence(Text: AnsiString);

implementation

procedure CntCharOccurrence(Text: AnsiString);
var
  i, j: Integer;
  MyOrdChar: Integer;
  s: AnsiString;
begin
  // Init array
  for j := 1 to 26 do
  begin
    CharRecordArray[j].FChar := Chr(j + 64);
    CharRecordArray[j].FCharCnt := 0;
  end;

  s := AnsiUpperCase(Text);
  for i := 1 to Length(s) do
  begin
    MyOrdChar := Ord(s[i]) - 64; // A = 1, B = 2, ...
    if (MyOrdChar in [1..26]) then
    begin
      CharRecordArray[MyOrdChar].FCharCnt := CharRecordArray[MyOrdChar].FCharCnt + 1;
    end;
  end;
end;

end.

Aufruf:

Delphi-Quellcode:

procedure TForm5.btn1Click(Sender: TObject);
var
  i: Integer;
  s: AnsiString;
begin
  s := '';
  CntCharOccurrence(mmo1.Text);
  for i := 1 to 26 do
  begin
    s := s + Format('%s: %d', [CharRecordArray[i].FChar, CharRecordArray[i].FCharCnt]) + #13#10;
  end;
  ShowMessage(s);
end;

Die Erweiterung um den prozentualen Anteil sollte jetzt kein Problem sein. Den Record um das entsprechende Feld erweitern und nach der Ermittlung der Häufigkeit noch mal in einer Schleife das Array durchgehen und den Prozentualen Anteil ermitteln.

[rokli]

Zwille ist cool! :lol:

[Luckie]

Hier die Erweiterung und ein paar Code Verschönerungen:

Delphi-Quellcode:

unit Unit6;

interface

uses
  SysUtils;

type TCharRecord = record
    FChar: AnsiChar;
    FCharCnt: Cardinal;
    FPercentage: Extended;
end;

var
  CharRecordArray: array [1..26] of TCharRecord;

procedure CntCharOccurrence(Text: AnsiString);

implementation

procedure CntCharOccurrence(Text: AnsiString);
var
  i: Integer;
  MyOrdChar: Integer;
  s: AnsiString;
  BaseValue: Integer;
  Percentage: Extended;
begin
  // Init array
  for i := Low(CharRecordArray) to High(CharRecordArray) do
  begin
    CharRecordArray[i].FChar := Chr(i + 64);
    CharRecordArray[i].FCharCnt := 0;
    CharRecordArray[i].FPercentage := 0;
  end;
  // calcualte occurence
  s := AnsiUpperCase(Text);
  s := StringReplace(s, ' ', '', [rfReplaceAll]);
  for i := 1 to Length(s) do
  begin
    MyOrdChar := Ord(s[i]) - 64; // A = 1, B = 2, ...
    if (MyOrdChar in [1..26]) then
    begin
      CharRecordArray[MyOrdChar].FCharCnt := CharRecordArray[MyOrdChar].FCharCnt + 1;
    end;
  end;
  // calculate percentage
  BaseValue := Length(s);
  for i := Low(CharRecordArray) to High(CharRecordArray) do
  begin
    Percentage := CharRecordArray[i].FCharCnt / BaseValue * 100;
    CharRecordArray[i].FPercentage := Percentage;
  end;
end;

end.

Delphi-Quellcode:

procedure TForm5.btn1Click(Sender: TObject);
var
  i: Integer;
  s: AnsiString;
begin
  s := '';
  CntCharOccurrence(mmo1.Text);
  for i := Low(CharRecordArray) to High(CharRecordArray) do
  begin
    s := s + Format('%s: %d' + #9 + '(%2.2f%%)', [CharRecordArray[i].FChar, CharRecordArray[i].FCharCnt, CharRecordArray[i].FPercentage]) + #13#10;
  end;
  ShowMessage(s);
end;

[rokli]

OT: Wer das wohl noch kennt, geschweige denn bauen kann... und damit schießen! :wink:

[p80286]

Solange Du Dich auf ANSI-Char beschränkst reicht auch

Delphi-Quellcode:

var
  cntarr:array[0..255] of cardinal;

const
  maxbuff = 4096;
  
var
  edat   : file;
  buffer : array [1..maxbuff] of byte;
  gelesen:integer;
  i      : integer;
begin
  fillchar(cntarr,#0,sizeof(cntarr));
  assignfile(edat,efile);
  reset(edat,1);
  repeat
    blockread(edat,buffer,maxbuff,gelesen);
    for i:=1 to gelesen do
      inc(cntarr[buffer[i]],1);
  until eof(edat) or application.terminated;
  closefile(edat);
end;

Gruß
K-H

[Luckie]

Meine IDE kann noch kein Unicode, deswegen habe ich explizit den Datentyp AnsiString genommen, damit es zu keinen Problemen mit neueren IDE's und Compilern kommt.

[Sherlock]

OT: Ist der TB nicht was feines?
:roll:

Sherlock
- der wieder stänkert, obwohl das Jahrespensum doch bereits erfüllt schien...mea culpa.

[t.roller]

Ich habe auch eine Lösung:
Es arbeitet mit der Buchstabenhäufigkeit lt. Tabelle in
Buchstabenhäufigkeit in deutschsprachigen Texten

Jeder gefundene Buchstabe wird gelöscht und verkürzt den Text, was nachfolgende Suchen beschleunigt.

Delphi-Quellcode:

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.Grids, Vcl.ExtDlgs;

type
  TForm1 = class(TForm)
    StringGrid1: TStringGrid;
    Memo11: TMemo;
    Memo13: TMemo;
    Button4: TButton;
    OpenTextFileDialog1: TOpenTextFileDialog;
    Button1: TButton;
    procedure Button4Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
      Rect: TRect; State: TGridDrawState);

  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;
  nextLetter : Integer;
  LOT : Integer;  //Length(Memo11.text);

implementation

{$R *.dfm}

function CountChars(const subtext, Text: String): Integer;
var Text3 : String;
begin
inc(nextLetter);
Text3:= StringReplace(Text, subtext, '', [rfReplaceAll, rfIgnoreCase]);
Result := Length(Text) - Length(Text3);
Form1.Memo11.text:= Text3;
Form1.StringGrid1.Cells[0,nextLetter]:= subtext;
Form1.StringGrid1.Cells[1,nextLetter]:= INTTOSTR(Result);
Form1.StringGrid1.Cells[2,nextLetter]:= FLOATTOSTR(Result / (LOT/100));
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
Memo11.Clear; Memo13.Clear;
if OpenTextfileDialog1.Execute then
BEGIN
  Memo11.Lines.LoadFromFile(OpenTextfileDialog1.FileName);
  nextLetter:=0;
  Application.ProcessMessages;
  LOT:= Length(Memo11.text);
END;
end;

procedure TForm1.Button4Click(Sender: TObject);
begin
    StringGrid1.Cells[0,0]:= 'Buchstabe';
    StringGrid1.Cells[1,0]:= 'Häufigkeit';
    StringGrid1.Cells[2,0]:= 'Prozent';
    Memo13.Lines.Add('Memo11-Length: '+INTTOSTR(Length(Memo11.text)));
    Memo13.Lines.Add('e: '+INTTOSTR(CountChars('e',Memo11.Text)));
    Memo13.Lines.Add('n:'+INTTOSTR(CountChars('n',Memo11.Text)));
    Memo13.Lines.Add('i: '+INTTOSTR(CountChars('i',Memo11.Text)));
    Memo13.Lines.Add('s: '+INTTOSTR(CountChars('s',Memo11.Text)));
    Memo13.Lines.Add('r: '+INTTOSTR(CountChars('r',Memo11.Text)));
    Memo13.Lines.Add('a: '+INTTOSTR(CountChars('a',Memo11.Text)));
    Memo13.Lines.Add('t: '+INTTOSTR(CountChars('t',Memo11.Text)));
    Memo13.Lines.Add('d: '+INTTOSTR(CountChars('d',Memo11.Text)));
    Memo13.Lines.Add('h: '+INTTOSTR(CountChars('h',Memo11.Text)));
    Memo13.Lines.Add('u: '+INTTOSTR(CountChars('u',Memo11.Text)));
    Memo13.Lines.Add('l: '+INTTOSTR(CountChars('l',Memo11.Text)));
    Memo13.Lines.Add('c: '+INTTOSTR(CountChars('c',Memo11.Text)));
    Memo13.Lines.Add('g: '+INTTOSTR(CountChars('g',Memo11.Text)));
    Memo13.Lines.Add('m: '+INTTOSTR(CountChars('m',Memo11.Text)));
    Memo13.Lines.Add('o: '+INTTOSTR(CountChars('o',Memo11.Text)));
    Memo13.Lines.Add('b: '+INTTOSTR(CountChars('b',Memo11.Text)));
    Memo13.Lines.Add('w: '+INTTOSTR(CountChars('w',Memo11.Text)));
    Memo13.Lines.Add('f: '+INTTOSTR(CountChars('f',Memo11.Text)));
    Memo13.Lines.Add('k: '+INTTOSTR(CountChars('k',Memo11.Text)));
    Memo13.Lines.Add('z: '+INTTOSTR(CountChars('z',Memo11.Text)));
    Memo13.Lines.Add('p: '+INTTOSTR(CountChars('p',Memo11.Text)));
    Memo13.Lines.Add('v: '+INTTOSTR(CountChars('v',Memo11.Text)));
    Memo13.Lines.Add('ß: '+INTTOSTR(CountChars('ß',Memo11.Text)));
    Memo13.Lines.Add('j: '+INTTOSTR(CountChars('j',Memo11.Text)));
    Memo13.Lines.Add('y: '+INTTOSTR(CountChars('y',Memo11.Text)));
    Memo13.Lines.Add('x: '+INTTOSTR(CountChars('x',Memo11.Text)));
    Memo13.Lines.Add('q: '+INTTOSTR(CountChars('q',Memo11.Text)));
    Memo13.Lines.Add('ä: '+INTTOSTR(CountChars('ä',Memo11.Text)));
    Memo13.Lines.Add('ö: '+INTTOSTR(CountChars('ö',Memo11.Text)));
    Memo13.Lines.Add('ü: '+INTTOSTR(CountChars('ü',Memo11.Text)));
    Memo13.Lines.Add('0: '+INTTOSTR(CountChars('0',Memo11.Text)));
    Memo13.Lines.Add('1: '+INTTOSTR(CountChars('1',Memo11.Text)));
    Memo13.Lines.Add('2: '+INTTOSTR(CountChars('2',Memo11.Text)));
    Memo13.Lines.Add('3: '+INTTOSTR(CountChars('3',Memo11.Text)));
    Memo13.Lines.Add('4: '+INTTOSTR(CountChars('4',Memo11.Text)));
    Memo13.Lines.Add('5: '+INTTOSTR(CountChars('5',Memo11.Text)));
    Memo13.Lines.Add('6: '+INTTOSTR(CountChars('6',Memo11.Text)));
    Memo13.Lines.Add('7: '+INTTOSTR(CountChars('7',Memo11.Text)));
    Memo13.Lines.Add('8: '+INTTOSTR(CountChars('8',Memo11.Text)));
    Memo13.Lines.Add('9: '+INTTOSTR(CountChars('9',Memo11.Text)));
    Memo13.Lines.Add('Memo11-Length: '+INTTOSTR(Length(Memo11.text)));
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  nextLetter:=0;
  Memo11.Lines.LoadFromFile('F:\schtasks.txt');
  Application.ProcessMessages;
  LOT:= Length(Memo11.text);
end;

procedure TForm1.StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer; Rect: TRect; State: TGridDrawState);
var s: string;
begin
  s := StringGrid1.Cells[ACol, ARow]; 
  StringGrid1.Canvas.FillRect(Rect); 
  DrawText(StringGrid1.Canvas.Handle, PChar(s), Length(s), Rect,
  DT_SINGLELINE or DT_Center or DT_VCENTER); // Text zentrieren
end;

end.

[DeddyH]

Vielleicht denke ich zu simpel, aber würde es für Ansi nicht auch einfach so gehen (die nicht darstellbaren Zeichen habe ich bewusst nicht herausgefiltert)?

Delphi-Quellcode:

type
  TCharCounter = class
  private
    FCounts: array [AnsiChar] of Cardinal;
    FTotal: int64;
  public
    procedure ReadString(const s: AnsiString);
    function GetCount(c: AnsiChar): integer;
    function GetPercentage(c: AnsiChar): single;
    constructor Create;
  end;

constructor TCharCounter.Create;
begin
  FillChar(FCounts, SizeOf(FCounts), 0);
end;

function TCharCounter.GetCount(c: AnsiChar): integer;
begin
  Result := FCounts[c];
end;

function TCharCounter.GetPercentage(c: AnsiChar): single;
begin
  if FTotal = 0 then
    Result := 0
  else
    Result := GetCount(c) / FTotal * 100;
end;

procedure TCharCounter.ReadString(const s: AnsiString);
var
  i: Cardinal;
begin
  FTotal := 0;
  for i := Low(s) to High(s) do
    begin
      FCounts[s[i]] := FCounts[s[i]] + 1;
      inc(FTotal);
    end;
end;

[Jumpy]

Zitat:

Zitat von DeddyH (Beitrag 1361462)

Delphi-Quellcode:

FCounts[s[i]] := FCounts[s[i]] + 1;

Das scheint mir aber nicht richtig zu sein, oder?

[DeddyH]

Wieso nicht? Mal in Langform:

Delphi-Quellcode:

procedure TCharCounter.ReadString(const s: AnsiString);
var
  i: Cardinal;
  c: AnsiChar;
begin
  FTotal := 0;
  for i := Low(s) to High(s) do
    begin
      c := s[i];
      FCounts[c] := FCounts[c] + 1;
      inc(FTotal);
    end;
end;

[Luckie]

Und wie weißt du jetzt, wie häufig jeder einzelne Buchstabe vorkommt?

[DeddyH]

Die Anzahl steht je Zeichen im Array.

[edit] Nachtrag: Das Nullen des Arrays beim erneuten Einlesen habe ich noch vergessen.

Delphi-Quellcode:

procedure TCharCounter.ReadString(const s: AnsiString);
var
  i: Cardinal;
begin
  FTotal := 0;
  FillChar(FCounts, SizeOf(FCounts), 0);
  for i := Low(s) to High(s) do
    begin
      FCounts[s[i]] := FCounts[s[i]] + 1;
      inc(FTotal);
    end;
end;

[Jumpy]

Zitat:

Zitat von DeddyH (Beitrag 1361502)

Wieso nicht? Mal in Langform:

Irgendwie sehe ich den Trick nicht, wieso der Char der Index im Array ist? Ich steh da wohl auf der Leitung :oops:

[DeddyH]

Wenn Du je Zeichen die Anzahl ermitteln willst, bietet es sich doch an, das Zeichen dann auch als Index zu verwenden, oder?

[p80286]

Das ist keine Char-Table sondern eine Count-Table. also am Position $31 wir das Vorkommen von "1" gezählt.

Gruß
K-H

[Lisa.99]

Danke für eure schnellen Antworten.
Verstehe leider viele Quelltexte nicht. In der Schule lernen wir nur wenig und es kann passieren, dass ich das erklären muss. Will auch verstehen, wieso ich das so machen muss.
Wie bekomme ich es hin, mein string grid auf null zu setzen?
Bin ein Mädchen :-D

[Luckie]

Dann frag, was du nicht verstehst.

Zu deiner Frage: In dem du 0 in die betreffende Zelle schreibst?

[t.roller]

Zitat:

Zitat von Lisa.99 (Beitrag 1361592)

Wie bekomme ich es hin, mein string grid auf null zu setzen?
Bin ein Mädchen :-D

Delphi-Quellcode:

procedure TForm1.ButtonClick(Sender: TObject);
var I: Integer;
begin
  for I := 0 to StringGrid1.RowCount - 1 do
    StringGrid1.Rows[I].Clear();
end;

[Lisa.99]

Danke! Das mit der Prozedur werde ich dann mal versuchen.
Ich muss ja, wenn ich die Prozente der einzelnen Buchstaben berechnen muss eine Schleife nutzen. Das habe ich ja auch in meinem Quelltext schon versucht! Mein Problem ist, dass ich nicht weiß, wie die Schleife direkt auszusehen hat. Das was bei mir grün ist, ist meine versuchte Schleife. Wenn ich diese aber durchlaufe, dann sagt er mir, dass er das nicht berechnen kann. Was ist daran der Fehler?

[Luckie]

Die genaue Fehlermeldung wäre jetzt hilfreich.

[Jumpy]

Wenn's nur um das grüne geht, da zählst du zu weit:

for j1 := 1 to StringGrid1.RowCount-1 do

[Lisa.99]

Dankeschön. Kann es leider erst am Montag wieder ausprobieren. Ich versuche das mal und wenn dann immer noch eine Fehlermeldung kommen sollte, dann werde ich sie euch schreiben. Danke habt mir aber schon sehr geholfen :-D

[t.roller]

Aus Spass neue Version gemacht:

Delphi-Quellcode:

unit Unit1;  //20170213

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes,
  Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.Grids, Vcl.ExtDlgs,
  Winapi.MMSystem, Vcl.ExtCtrls;

type
  TForm1 = class(TForm)
    StringGrid1: TStringGrid;
    Memo11: TMemo;
    OpenTextFileDialog1: TOpenTextFileDialog;
    bnOpenTextfileDialog: TButton;
    bnCLEAR: TButton;
    Edit1: TEdit;
    bnRUN: TButton;
    bnCLOSE: TButton;
    procedure FormCreate(Sender: TObject);
    procedure bnOpenTextfileDialogClick(Sender: TObject);
    procedure StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
              Rect: TRect; State: TGridDrawState);
    procedure bnCLEARClick(Sender: TObject);
    procedure bnRUNClick(Sender: TObject);
    procedure bnCLOSEClick(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

  cArray = array of ANSIchar;

var
  Form1: TForm1;
  nextLetter : Integer;
  LOT : Integer;
  CA : cArray;

implementation

{$R *.dfm}

function StrToCharArray(s: ANSIstring): cArray;
var x: integer;
begin
  setlength(result,length(s));
  for x:=length(s) downto 1 do result[x-1]:=s[x];
end;

function RemoveChars(const str: string; const ch: ANSIchar): string;
var i, Count: Integer; InvalidChars : set of ANSIChar;
begin
  InvalidChars := [ch, UPCASE(ch)];
  SetLength(Result, Length(str));
  Count := 0;
  for i := 1 to Length(str) do
  if not (str[i] in InvalidChars) then begin inc(Count); Result[Count] := str[i]; end;
  SetLength(Result, Count);
end;
//------------------------------------------------------------------------------
procedure TForm1.bnCLEARClick(Sender: TObject);
var I: Integer;
begin
  for I := 0 to StringGrid1.RowCount - 1 do StringGrid1.Rows[I].Clear();
end;

procedure TForm1.bnCLOSEClick(Sender: TObject); begin Application.Terminate; end;

procedure TForm1.bnRUNClick(Sender: TObject);
var Text3 : String; iResult, iText, I : Integer;
    Ticks: DWord; Res, Proz : Single;
begin
    StringGrid1.Cells[0,0]:= 'Buchstabe';
    StringGrid1.Cells[1,0]:= 'Häufigkeit';
    StringGrid1.Cells[2,0]:= 'Prozent';
Ticks := timeGetTime;

for I := Low(CA) to High(CA) do
BEGIN
  iText:= Length(Memo11.Text);
  inc(nextLetter);
  Text3:= RemoveChars(Memo11.text, CA[I]);
  Application.ProcessMessages;
  iResult := iText - Length(Text3);
  Memo11.text:= Text3;
  StringGrid1.Cells[0,nextLetter]:= CA[I];
  StringGrid1.Cells[1,nextLetter]:= INTTOSTR(iResult);
  Proz:= iResult / (LOT/100);
  StringGrid1.Cells[2,nextLetter]:= Format(' %.3f %',[Proz]);
END;
  Res := 0.001 * (timeGetTime - Ticks);
  Edit1.Text:= Format('Time for creating : '+' %.3f  sec',[Res]);
end;

procedure TForm1.bnOpenTextfileDialogClick(Sender: TObject);
begin
  Memo11.Clear; bnCLEAR.Click;
if OpenTextfileDialog1.Execute then
BEGIN
  Memo11.Lines.LoadFromFile(OpenTextfileDialog1.FileName);
  nextLetter:=0;
  Application.ProcessMessages;
  LOT:= Length(Memo11.text);
END;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Height:= Screen.Height-40;
  nextLetter:=0;
  Memo11.Lines.LoadFromFile(ExtractFilePath(Application.ExeName)+'\schtasks.txt');
  Application.ProcessMessages;
  LOT:= Length(Memo11.text);
  CA:= StrToCharArray('enisratdhulcgmobwfkzpvßjyxqäöü0123456789'); //40
end;

procedure TForm1.StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState);
var s: string;
begin
  s := StringGrid1.Cells[ACol, ARow];
  StringGrid1.Canvas.FillRect(Rect);
  DrawText(StringGrid1.Canvas.Handle, PChar(s), Length(s), Rect,
  DT_SINGLELINE or DT_Center or DT_VCENTER);
end;

end.

[t.roller]

Buchstabenhäufigkeit in ausgewählten Sprachen

[Lisa.99]

Guten Morgen alle Zusammen!
Mein Problem ist weiterhin, dass er mir die Prozentzahlen nicht ausgibt.
Als Fehler zeigt er mir " '' ist kein gültiger Integerwert"
Ich denke, dass das Problem darin liegt, weil nicht alle Zellen einen Wert drin stehen haben. Nur die Buchstaben, die in dem Text vorhanden sind, wird die Anzahl hineingeschrieben. Die Buchstaben, die nicht in dem Text vorkommen, da sind die Zellen leer.

[p80286]

Jetzt wäre es interessant zu wissen welchen Sourcecode Du hast.
Auf jeden Fall solltest Du 0 als Initalwert nutzen.

Gruß
k-H

[Lisa.99]

Habe nur das um die Buchstabenanzahl anzuzeigen:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var text : string;
    i, anzahl, Index, Ordnungszahl : integer;
    Buchstabe, key : char;
begin
 if not (key in [#65..#90, #97..#122, #8]) then
  key := #0;

 StringGrid1.Cells[0,0]:= 'Buchstabe';
 StringGrid1.Cells[1,0]:= 'Häufigkeit';
 StringGrid1.Cells[2,0]:= 'Prozent';

 for i := 0 to 26 do
 begin
   StringGrid1.Cells[0,i+1]:= char (i+65);
 end;
 text:= Edit1.Text;
 text:=stringreplace(text,' ','',[rfReplaceAll]);
 for n1 := 1 to length (text) do
    begin
    Buchstabe := text[n1];
    Buchstabe := Upcase (Buchstabe);
    Ordnungszahl:= Ord(Buchstabe);
    Index:= Ordnungszahl-64;
    if Index in [1..26] then
      begin
      anzahl := StrToIntDef(StringGrid1.Cells[1,Index],0);
      anzahl := anzahl + 1;
      StringGrid1.Cells[1,Index] := inttostr(anzahl);
      end;
    end;
   Edit2.Text:= inttostr(n1-1);
end;

[Luckie]

Die Fehlermeldung besagt erst mal, dass du versucht ein Leerzeichen in einen Integer umzuwandeln. Das geht natürlich nicht, das ein Leerzeichen keine gültige Ziffer bzw. Zahl ist.

Jetzt wäre natürlich noch interessant, wie du die Prozente berechnest. Sonst kann man dir irgendwie schlecht helfen. Aber da hab eich dir ja schon funktionierenden Quellcode gegeben.

[p80286]

ich glabe wir haben vergessen zu erwähnen, daß die Daten, die in einem Programm verarbeitet werden, nicht in der Oberfläche abgelegt werden sollten.
Hier haben wir ein wunderbares Beispiel dafür, das es keine Ersparnis ist, gleich alles in einem Grid abzulegen, statt in einem Array/liste was auch immer. Da wäre es ein Zweizeiler die Prozente zu erhalten.

Gruß
K-H

Oh, das steht ja schon alles in #4 :oops:

[Luckie]

Und in #8 hat sie ein komplettes Beispiel. Sie muss nur noch die Ausgabe in einem Stringgrid anstatt in der Messagebox programmieren. Und ein Stringgrid kann sie ja füllen, wie ihr Code zeigt.

[Lisa.99]

Er zählt leider die Satzzeichen mit, wenn er die Buchstabenanzahl berechnen soll, aber das will ich nicht.

Delphi-Quellcode:

begin
 if not (key in [#65..#90, #97..#122, #8]) then
  key := #0;

 StringGrid1.Cells[0,0]:= 'Buchstabe';
 StringGrid1.Cells[1,0]:= 'Häufigkeit';

 for i := 0 to 26 do
 begin
   StringGrid1.Cells[0,i+1]:= char (i+65);
 end;
 text:= Edit1.Text;
 text:=stringreplace(text,' ','',[rfReplaceAll]);
 for n1 := 1 to length (text) do
    begin
    Buchstabe := text[n1];
    Buchstabe := Upcase (Buchstabe);
    Ordnungszahl:= Ord(Buchstabe);
    Index:= Ordnungszahl-64;
    if Index in [1..26] then
      begin
      anzahl := StrToIntDef(StringGrid1.Cells[1,Index],0);
      anzahl := anzahl + 1;
      StringGrid1.Cells[1,Index] := inttostr(anzahl);
      end;
    end;
   Edit2.Text:= inttostr(n1-1);
end;

[Luckie]

Überlege dir doch mal wie du NUR die Buchstaben zählen würdest. Schritt für Schritt.

Code:

Zeichen Buchstabe Zähler um eins erhöhen
Zeichen Buchstabe Zähler um eins erhöhen
Zeichen Buchstabe Zähler um eins erhöhen
Zeichen Buchstabe Zähler um eins erhöhen
Zeichen kein Buchstabe, Zähler nicht erhöhen
Zeichen Buchstabe Zähler um eins erhöhen
Zeichen Buchstabe Zähler um eins erhöhen
...

Das heißt, du "überprüfst" im Kopf, ohne dass du es bewusst wahrnimmst, ob du gerade einen Buchstaben zählst oder nicht. Das musst du jetzt in Code umsetzen:

Code:

wenn Buchstabe
  Zähler erhöhen
ansonsten 
  tue nichts

Da der "ansonsten"-Zweig leer ist, kann man ihn natürlich weglassen. Letztendlich läuft es darauf hinaus den Zähler nur hoch zu zählen, wenn ein Buchstabe Buchstaben vorliegt. Das kann man jetzt sprachtechnisch unterschiedlich lösen. Am einfachsten wäre der in-Operator:

Code:

Wenn Zeichen in Buchstaben-ASCII-Bereich, dann zähle hoch

[p80286]

Und warum zählst Du nicht alle Zeichen und gibst dann die Zählung der Buchstaben aus?
Ohne Mehraufwand wäre dann auch die Zählung der Satzzeichen, Umlaute oder was auch immer verfügbar.

Gruß
K-H

[Luckie]

Lass sie erst mal das eine Problem lösen. Optimieren kann sie dann immer noch, wenn sie es verstanden hat.