Abstrakte Methode mit Enum -> Unterschiedliche Definitionen

[scrat1979]

Liebe Kameraden,

Ich habe eine Vorfahrenklasse für eine Client-Server-Komponente erstellt. Von dieser leite ich dann weitere Komponenten entsprechend dem Einsatzzweck ab. Hierbei stoße ich auf folgendes Problem ( Der Einsatzweck der Komponente ist irrelevant, es geht um die abstrakte Methode ):

Meine Vorfahrenklasse (auf das Nötigste reduziert ):

Delphi-Quellcode:

unit uCustomClient;

interface

uses [...], uMKLANConstants;

TMKCustomClient = class(TComponent)
  [...]
  protected
    procedure DoOnServerCommand(ServerCommand : TSrvCmd; Data : TStream); virtual; abstract; // <- Um das "TSrvCmd" geht es
  [...]
end;

Das TSrvCmd ist in der o.g. Unit "uMKLANConstants" definiert:

Delphi-Quellcode:

type
  TSrvCmd = (Command1, Command2);

So, nun möchte ich das Set TSrvCmd in der abgeleiteten Komponente (und NUR in dieser!) erweitern um die entsprechenden Funktionen zu implementieren, z.B.:

Delphi-Quellcode:

Type TSrvCmd = (Command1, Command2, Command3, Command4, Command5);

TMKChatClient = class(TMKCustomClient)
  [...]
  protected
    procedure DoOnServerCommand(ServerCommand : TSrvCmd; Data : TStream); override;
  [...]
end;

Jetzt meckert mir der Compiler, dass die Definitionen von DoOnServerCommand unterschiedlich sind. Mir ist absolut klar, dass es sich für den Compiler um zwei verschiedene "inkompatible" Sets handelt, da sie in verschiedenen Units deklariert wurden. Die Fehlerursache ist mir also klar, ABER wie kann ich das geplante umsetzen? Natürlich könnte ich in der o.g. Unit das Set "unendlich" erweitern, allerdings hätte ich dann bei vielen abgeleiteten Komponenten "unnötige" Einträge in TSrvCmd drin - und das möchte ich der Übersicht halber eben vermeiden.

[jaenicke]

Das wird so leider nicht funktionieren, denn die Größe eines Sets hängt von der Anzahl der Elemente ab. Fügst du also Elemente hinzu, kann es sein, dass sich die Größe des Sets ändert.

Ich würde das über eine Klasse oder Interfaces regeln. Die kannst du dann ableiten, um weitere Einträge hinzuzufügen.

[scrat1979]

Zitat:

Zitat von jaenicke (Beitrag 1374755)

Das wird so leider nicht funktionieren, denn die Größe eines Sets hängt von der Anzahl der Elemente ab. Fügst du also Elemente hinzu, kann es sein, dass sich die Größe des Sets ändert.

Ich würde das über eine Klasse oder Interfaces regeln. Die kannst du dann ableiten, um weitere Einträge hinzuzufügen.

Ich habe es befürchtet. Könntest Du mir ein kleines Beispiel geben wie ich das über Klassen lösen soll? Ist mir gerade nicht wirklich klar. Sollte es zu kompliziert sein, dann werde ich es über Konstanten lösen und den Typ SrvCmd auf Integer ändern :-)

Schönes Wochenende schonmal und Danke für die schnelle Antwort :thumb:

[Uwe Raabe]

Du könntest es auch über ein

Delphi-Quellcode:

overload

regeln:

Delphi-Quellcode:

type
  TSrvCmd = (Command1, Command2);

type
  TMKCustomClient = class
  protected
    procedure DoOnServerCommand(ServerCommand : TSrvCmd; Data : TStream); virtual; abstract;
  end;

type
  TSrvCmd2 = (Command1a, Command2a, Command3, Command4, Command5);

type
  TMKChatClient = class(TMKCustomClient)
  protected
    procedure DoOnServerCommand(ServerCommand : TSrvCmd; Data : TStream); override; overload;
    procedure DoOnServerCommand(ServerCommand : TSrvCmd2; Data : TStream); overload;
  end;

procedure TMKChatClient.DoOnServerCommand(ServerCommand: TSrvCmd; Data: TStream);
begin
  { hier setzen wir voraus, daß die Ordnungszahlen der ersten beiden Werte von TSrvCmd2 denen von TSrvCmd entsprechen }
  DoOnServerCommand(TSrvCmd2(ServerCommand), Data);
end;

procedure TMKChatClient.DoOnServerCommand(ServerCommand: TSrvCmd2; Data: TStream);
begin
  case ServerCommand of
    Command1a: ;
    Command2a: ;
    Command3: ;
    Command4: ;
    Command5: ;
  end;
end;

[scrat1979]

Besten Dank für eure Antworten! Die Sache mit dem Casten sieht interessant aus. Mich würde abschließend trotzdem noch interessieren wie es mit den Klassen aussehen würde :oops:

Nochmals danke für eure Hilfe und schönes Wochenende 8-)

[himitsu]

Mit gleichnamigen Enums

Delphi-Quellcode:

{$SCOPEDENUMS ON}

type
  TSrvCmd1 = (Command1, Command2);
  TSrvCmd2 = (Command1, Command2, Command3, Command4, Command5);

DoOnServerCommand(TSrvCmd1.Command1, xxx);

oder ein Subset der Selben

Delphi-Quellcode:

type
  TSrvCmd2 = (Command1, Command2, Command3, Command4, Command5);
  TSrvCmd1 = Command1..Command2;