Array-Eigenschaft als Parameter

[Redeemer]

Ich möchte gerne eine Nicht-Standard-Array-Eigenschaft (TBitmap.Scanline[Row: Integer], TPngImage.ScanLine[Index: Integer] oder TPngImage.AlphaScanline[Index: Integer]) als Parameter an eine Methode übergeben. Geht das und wenn ja, wie?

Danke schon einmal!

[Der schöne Günther]

Was du meinst sind Indexer. Das ist kein Array, es sieht nur so aus. In Wirklichkeit ist ein

Delphi-Quellcode:

myBitmap.ScanLine[x]

ein Aufruf von

Delphi-Quellcode:

myBitmap.GetScanLine(x)

das einen einzigen Wert zurückgibt. Wenn du Daten als gesamtes Array übergeben willst musst du auch erst ein echtes Array zusammenbauen.

[Redeemer]

„Array-Eigenschaft“ ist der Name aus der Dokumentation.
Ich weiß, dass es keine Arrays sind, und möchte sie halt nicht erst umwandeln müssen.

[Der schöne Günther]

Ich sehe bei TBitmap.GetScanLine(..) nur dass er für jeden Aufruf explizit sich etwas zusammenbaut, das sind keine Daten die sowieso schon am Stück vorliegen.

Alternativ könntest du deiner Methode eine anonyme Methode als Parameter übergeben die angibt wie er seine Daten herholen kann, aber das macht die Sache nicht leserlicher und verkompliziert alles weiter. Ich würde mir lokal ein Array zusammenbauen mit den Dingen die du drin haben willst und es dann übergeben, ich sehe keinen Weg dran vorbei.

[Blup]

Man könnte mit einem Adapter arbeiten. Auch andere Informationen wie Höhe, Breite, Pixelformat lassen sich mit einbeziehen.

Delphi-Quellcode:

unit ScanLineAdapter;

interface

type
  IScanLineAdapter = interface(IInterface)
    ['{A19606EB-4B25-4862-86D5-ED26E7F07F8C}']
    function GetScanLine(AIndex: Integer): Pointer;
  end;

  TScanLineAdapter = class(TInterfacedObject, IScanLineAdapter)
  protected
    function GetScanLine(AIndex: Integer): Pointer; virtual; abstract;
  end;

  TBitmapScanLineAdapter = class(TScanLineAdapter)
  private
    FItem: TBitmap;
  protected
    function GetScanLine(AIndex: Integer): Pointer; override;
  public
    constructor Create(AItem: TBitmap);
  end;

  TPngImageScanLineAdapter = class(TScanLineAdapter)
  private
    FItem: TPngImage;
  protected
    function GetScanLine(AIndex: Integer): Pointer; override;
  public
    constructor Create(AItem: TPngImage);
  end;

  TPngImageAlphaScanLineAdapter = class(TScanLineAdapter)
  private
    FItem: TPngImage;
  protected
    function GetScanLine(AIndex: Integer): Pointer; override;
  public
    constructor Create(AItem: TPngImage);
  end;

implementation

{ TBitmapScanLineAdapter }

constructor TBitmapScanLineAdapter.Create(AItem: TBitmap);
begin
  inherited Create;

  FItem := AItem;
end;

function TBitmapScanLineAdapter.GetScanLine(AIndex: Integer): Pointer;
begin
  Result := FItem.ScanLine[AIndex];
end;

{ TPngImageScanLineAdapter }

constructor TPngImageScanLineAdapter.Create(AItem: TPngImage);
begin
  inherited Create;

  FItem := AItem;
end;

function TPngImageScanLineAdapter.GetScanLine(AIndex: Integer): Pointer;
begin
  Result := FItem.ScanLine[AIndex];
end;

{ TPngImageAlphaScanLineAdapter }

constructor TPngImageAlphaScanLineAdapter.Create(AItem: TPngImage);
begin
  inherited Create;

  FItem := AItem;
end;

function TPngImageAlphaScanLineAdapter.GetScanLine(AIndex: Integer): Pointer;
begin
  Result := FItem.AlphaScanline[AIndex];
end;

end.

Das Interface sorgt hier für die automatische Freigabe des Adapters.

Delphi-Quellcode:

procedure TuWasMitScanline(AScanLineAdapter: IScanLineAdapter);
var
  lData: Pointer;
begin
  lData := AScanLineAdapter.GetScanLine(3);
  {...}
end;

TuWasMitScanline(TPngImageAlphaScanLineAdapter.Create(FPngImage));

[Redeemer]

Ich danke dir. Mal schauen, ob sich das überhaupt lohnt, so oft kommt es nicht vor. Ich dachte, es gäbe da eine Konstruktion ähnlich wie Methoden-Klassen (z.B.

Delphi-Quellcode:

TNotifyEvent

).