Verwirrung um TImage und den DPI Wert

[Athris]

Guten Nachmittag,

vorweg muss ich gestehen dass ich in Sachen Bildbearbeitung in Delphi noch sehr neu bin.

Kurz zu meinem Projekt:
Mein aktuelles Hobby Projekt geht in die Richtung Bildbearbeitung.
Über einen Dialog lasse ich den Benutzer Länge und Breite seines Werkes in Pixel einstellen und passe dementsprechend Width und Length meines TImages an.
Auf diesem TImage kann der Benutzer Labels platzieren, andere Bilder oder halt drauf herummalen.
Die Speicherung des Bildes verläuft über TImage.Picture.SaveToFile ab.

Jetzt habe ich festgestellt, dass laut Windows die erzeugten Bilder stets eine DPI Anzahl von 96 DPI besitzen (laut Suche ist dies der Standard für Monitore). Jetzt würde ich aber gerne die Bilder auch für den Druck verwenden, bei dem eher Richtung 300 DPI gegangen wird. Aus dieser Problematik entstehen meine Fragen:
1. Gibt es die Möglichkeit die DPI Zahl eines TImages festzusetzen?
2. Gibt es eventuell sogar die Möglichkeit, dass der Benutzer (wie bei Photoshop) selbst einen DPI Wert angibt?
3. Mache ich vielleicht etwas bei der Speicherung falsch?

Ich weiß natürlich das DPI generell für Dots per Inch steht, also angibt aus wie vielen Pixeln ein Inch besteht. Aber dennoch verwirrt mich das Thema etwas.
Wie machen dass den andere Grafikanwendungen?


Meine Verwirrung wird noch einmal von folgendem Szenario unterstrichen:
1. Ich möchte eine Grafik erstellen die beim Ausdruck 5,90x9,10cm groß ist
2. Ich erstelle also in meinem Programm eine Grafik mit den Maßen 697x1075 Pixel. Die Grafik erhält nach der Speicherung laut Windows 96 DPI
2. In Photoshop erstelle ich die selbe Grafik mit den selben Maßen, aber bei DPI gebe ich 300 an
3. Ich öffne beide Grafiken in Paint und klicke auf DRUCKEN / SEITE EINRICHTEN. Dort gebe ich an das Paint nicht skalieren soll (also 100% Größe)
4. Beim Druck ist mein erstes Bild mit 96 DPI eine ganze DIN A4 Seite groß, während das zweite Bild aus Photoshop die perfekte Größe hat... 5,9 x 9,1 cm

[Redeemer]

Welches Dateiformat verwendest du?
Lade die Grafiken mal hier hoch, dann kann man die binär analysieren.

[jfheins]

Zitat:

Zitat von Athris (Beitrag 1383606)

Meine Verwirrung wird noch einmal von folgendem Szenario unterstrichen:
1. Ich möchte eine Grafik erstellen die beim Ausdruck 5,90x9,10cm groß ist
2. Ich erstelle also in meinem Programm eine Grafik mit den Maßen 697x1075 Pixel. Die Grafik erhält nach der Speicherung laut Windows 96 DPI
2. In Photoshop erstelle ich die selbe Grafik mit den selben Maßen, aber bei DPI gebe ich 300 an
3. Ich öffne beide Grafiken in Paint und klicke auf DRUCKEN / SEITE EINRICHTEN. Dort gebe ich an das Paint nicht skalieren soll (also 100% Größe)
4. Beim Druck ist mein erstes Bild mit 96 DPI eine ganze DIN A4 Seite groß, während das zweite Bild aus Photoshop die perfekte Größe hat... 5,9 x 9,1 cm

Für mich ist das das erwartete Verhalten ... aber zur Erklärung:

Die Bilder auf dem PC sind ja alle in Pixel-Maßen. Die dpi-Angabe ist davon separat im Bild gespeichert und gibt lediglich die Anregung, wie groß das Bild später bei einem eventuellen Druck sein soll.

Also beim Druck wird geguckt: Ah ja, in dem Bild stehen 150 dpi drin, dass sollen wohl 150 Pixel von dem Bild auf einen Zoll skaliert werden. Irgendeine Skalierung findet da ja immer statt, weil beim Erstellen des Bildes meistens nicht klar ist, welche Auflösung das Ausgabemedium hat.
Um dein Bild nicht nur am Bildschirm, sondern auch auf dem Papier auf die gewünschte Größe zu bekommen, musst du einen passenden dpi-Wert im Bild speichern. Falls Delphi da nichts bereit stellt: https://msdn.microsoft.com/en-us/lib...(v=vs.85).aspx
Du kannst auch nachträglich die Bitmap (/was auch immer) Datei öffnen und den Wert schreiben.

[Athris]

Also verstehe ich das richtig, dass der unter EIGENSCHAFTEN aufgelistete DPI Wert nur ein Hinweiswert für z.B. eine Applikation oder ein Drucker ist?

Das heißt ich müsste bei der Neuerstellung eines Bildes den Benutzer nach dem gewünschten DPI Wert fragen und diese beim Speichern des Bildes in die Datei reinschreiben?

Grundsätzlich speichere ich meine Bilder zurzeit so:

Delphi-Quellcode:

function SaveImage(vstrImagePath: String; vpntImage: TPicture): boolean;
var
  strDateiendung: string;
  pntBitmap: TBitmap;
  pntJPEGImage: TJPEGImage;
  pntPNGImage: TPngImage;
begin
  Result := False;
  pntBitmap := TBitmap.Create;
  try
    try
      pntBitmap.Assign(vpntImage);
      strDateiendung := UpperCase(ExtractFileExt(vstrImagePath));
      if strDateiendung = '.BMP' then begin
        pntBitmap.SaveToFile(vstrImagePath);
        Result := True
      end
      else if strDateiendung = '.PNG' then begin
        pntPNGImage := TPngImage.Create();
        try
          pntPNGImage.Assign(pntBitmap);
          pntPNGImage.SaveToFile(vstrImagePath);
          Result := True;
        finally
          pntPNGImage.Free;
        end;
      end
      else if (strDateiendung = '.JPG') or (strDateiendung = '.JPEG') then begin
        pntJPEGImage := TJPEGImage.Create();
        try
          pntJPEGImage.Assign(pntBitmap);
          pntJPEGImage.SaveToFile(vstrImagePath);
          Result := True;
        finally
          pntJPEGImage.Free;
        end;
      end;
    except on
      E:Exception do begin
        MessageDlg('Fehler beim Speichern der Grafikdatei '+vstrImagePath+': '+E.Message, mtError, [mbOk], 0);
      end;
    end;
  finally
    pntBitmap.Free;
  end;

[TiGü]

Zitat:

Zitat von Athris (Beitrag 1383626)

Das heißt ich müsste bei der Neuerstellung eines Bildes den Benutzer nach dem gewünschten DPI Wert fragen und diese beim Speichern des Bildes in die Datei reinschreiben?

Ja, so wie das die Programme auch machen (bzw. einen Default-Wert annehmen).
Das hier sollte dich auf die richtige Spur führen:
http://www.delphipraxis.net/913313-post14.html

[Athris]

Grundsätzlich kann ich also beim Speichern meinem Bitmap dieses "Flag" setzen und dann die Datei als .bmp speichern oder auch als .png bzw. .jpg (siehe meine gepostete Funktion)?

[TiGü]

Probiere es wie folgt, anstatt der 300.0 musst du natürlich deine gewünschten Werte übergeben:

Delphi-Quellcode:

unit GdiPlus.Save;

interface

uses
  System.SysUtils,
  Winapi.GDIPOBJ,
  Winapi.GDIPUTIL,
  Winapi.GDIPAPI,
  Vcl.Graphics;

function SaveImage(const vstrImagePath: String; const vpntImage: TPicture): Boolean;

implementation

function SaveImage(const vstrImagePath: String; const vpntImage: TPicture): Boolean;
var
  strDateiendung: string;
  pntBitmap: TBitmap;
  Bitmap: TGPBitmap;
  clsidEncoder: TGUID;
  EncoderResult: Integer;

  function GetEncoder(const AFileExt: string; out pClsid: TGUID): Integer;
  begin
    Result := -1;
    if AFileExt = '.BMP' then
    begin
      Result := GetEncoderClsid('image/bmp', pClsid)
    end
    else if AFileExt = '.PNG' then
    begin
      Result := GetEncoderClsid('image/png', pClsid)
    end
    else if (AFileExt = '.JPG') or (AFileExt = '.JPEG') then
    begin
      Result := GetEncoderClsid('image/jpeg', pClsid)
    end;
  end;

begin
  Result := False;
  pntBitmap := TBitmap.Create;
  try
    try
      pntBitmap.Assign(vpntImage);
      Bitmap := TGPBitmap.Create(pntBitmap.Handle, pntBitmap.Palette);
      try
        Bitmap.SetResolution(300.0, 300.0);

        strDateiendung := UpperCase(ExtractFileExt(vstrImagePath));
        EncoderResult := GetEncoder(strDateiendung, clsidEncoder);

        if EncoderResult > 0 then
          Result := Bitmap.Save(vstrImagePath, clsidEncoder) = TStatus.Ok;
      finally
        Bitmap.Free;
      end;
    except
      on E: Exception do
      begin
        raise Exception.Create('Fehler beim Speichern der Grafikdatei ' + vstrImagePath + ': ' + E.ClassName + ': ' + E.Message);
      end;
    end;
  finally
    pntBitmap.Free;
  end;
end;

end.

[Athris]

Ich wusste gar nicht dass man dem Bitmap Save einen Encoder für die Umwandlung mitgeben kann :D

Wobei GetEncoder() bei .BMP leider Result = 0 liefert.

Muss die Bedingung

Delphi-Quellcode:

if EncoderResult > 0 then

vielleicht

Delphi-Quellcode:

if EncoderResult >= 0 then

heißen?

/edit
Und ich habe gerade festgestellt, dass laut Photoshop die DPI Werte etwas "ungerundet" aussehen:
.jpg: 300 dpi --> Richtig
.png: 299,999 dpi
.bmp: 300,125 dpi

[TiGü]

Zitat:

Zitat von Athris (Beitrag 1383637)

Ich wusste gar nicht dass man dem Bitmap Save einen Encoder für die Umwandlung mitgeben kann :D

Wobei GetEncoder() bei .BMP leider Result = 0 liefert.

Muss die Bedingung

Delphi-Quellcode:

if EncoderResult > 0 then

vielleicht

Delphi-Quellcode:

if EncoderResult >= 0 then

heißen?

Ja, möglich. Ich habs nur schnell runtergetippt. Bitte entsprechend ändern.
Das ist ein GDI+-Bitmap und hat mit dem TBitmap wenig zu tun. Daher die Möglichkeit des Encoders.

[bernau]

Ein Bild selber hat nur zweidimensionale Pixelinformationen. Die DPI wird immer vom der Tatsächlich gedruckten Größe in Verbindung einer Bitmap bestimmt.

Wenn du ein Bild mit 100 Pixel Kantenlänge so druckst, daß es genau ein INCH breit ist, dann wird das Bild mit 100 DPI gedruckt.
Wird das gleiche Bild zwei INCH breit gedruckt, dann hat es 50 DPI.

Der Drucker kann zwar mehr. Aber die Bildinformation von 100 Pixel lässt ja nicht mehr zu.

Wenn das gleiche Bild mit 0,1 INCH Breite gedruckt wird, dann hat es 1000 DPI.

Es bring also nichts die DPI beim Bild zu speichern. Es kommt immer darauf an in welcher Skalierung es ausgegeben wird.

Zitat:

1. Ich möchte eine Grafik erstellen die beim Ausdruck 5,90x9,10cm groß ist
2. Ich erstelle also in meinem Programm eine Grafik mit den Maßen 697x1075 Pixel. Die Grafik erhält nach der Speicherung laut Windows 96 DPI

5,90 cm = 2,32 inch. Mit 697 Pixeln, wird die Grafik mit (697 / 2,32) 300dpi gedruckt/angezeigt und nicht mit 96dpi.

Windows ist wie meine Frau. Nur weil sie etwas sagt, muss es noch lange nicht stimmen. ;-)
(Spaßalarm: Bevor das Macho-basching anfängt. Meine Aussagen stimmen auch nicht immer.)