[Gelöst] IdTCPServer <-> IdTCPClient verändert Daten

[DelTurbo]

Hallo,
erst mal sorry das ich im Moment das Board Floode. Aber ich komme wirklich nicht weiter.
Ich habe nun einen IdTCPServer und einen IdTCPClient erstellt. Alles klappt wunderbar soweit ich das im Moment beurteilen kann.

Gefunden habe ich das hier unter Punkt 2.3. Das scheint zwar noch für Indy 9 zu sein, aber ich habe es umgeschrieben so gut ich konnte.

Hier ist mein Code vom IdTCPServer.OnExecute und ein Bild wie die "Bilder" aussehen die ich bekomme.

Wäre toll wenn mir jemand Helfen könnte. Ich komme einfach nicht weiter.

Netten Gruß und vielen Dank im Voraus

Delphi-Quellcode:

procedure TfMain.IdTCPServer1Execute(AContext: TIdContext);
var
  Cli   :TIdTCPClient;
  IOhnd :TIdIOHandlerStack;
  Data  :string;
  Len   :Int64;
  MemStream   :TMemoryStream;
  Buf   :TIdBytes;
begin
  try
    GblURL:='192.168.0.244';
    Cli := nil;
    try
      // #### Create IOHandler ####
      IOhnd:=TIdIOHandlerStack.Create(nil);
      { Create & Connect to Server }
      Cli:=TIdTCPClient.Create(nil);
      Cli.IOHandler:=IOhnd;
      Cli.Host := GblUrl;
      Cli.Port := 80;
      { Connect to the remote server }
      Cli.Connect;
      { Read/Write loop }
      repeat begin
        { Read data from Client }
        Len :=AContext.Connection.IOHandler.InputBuffer.Size;
        if ( Len>0 ) then begin
          AContext.Connection.IOHandler.ReadBytes(Buf,Len,False);     //,Len,False
          { Write it to the Server }
          Cli.IOHandler.Write(Buf,Len);
        end;
        { Read data from Server }
        Len:=Cli.IOHandler.InputBuffer.Size;
        if ( Len>0 ) then begin
          Cli.IOHandler.ReadBytes(Buf,Cli.IOHandler.InputBuffer.Size,False);
          { Write it to the Server }
          AContext.Connection.IOHandler.Write(Buf);
        end;
        { Release system slizes }
        SleepEx(1, True);
        end;
      until (not AContext.Connection.Connected) or (not Cli.Connected);
    finally
      if Assigned(Cli) then
      begin
        Cli.Disconnect;
        Cli.Free
      end;
      { Disconnect real client }
      AContext.Connection.Disconnect;
      if ( Assigned(IOhnd) ) then begin
        IOhnd.Free;
      end;
    end;
  except
  end;
end;

[TiGü]

Hast du mal die Daten zwischengespeichert und das Bild zum debuggen/kontrollieren auf die Festplatte geschrieben, bevor du die Daten weiterversendest?

[DelTurbo]

Nein, nur das "richtige" Bild und das kaputte. Komigerweise stimmen die Größen überein. aber die Daten nicht.

Der Anfang ist immer richtig (gleiche Daten). Und dann kommen plötzlich andere Daten. Keine nullen oder sonst was, einfach andere Daten.

Gruß

Nachtrag: Ich habe Indy Version 10.6.0.0

[DelTurbo]

Öhm,
ich habe das gerade mal mit Indy 9 Probiert. Läuft einwandfrei. Ich kann sogar 59MB Dateien runterladen. Die Daten sind Richtig.

Muss ich das Verstehen?????

[DelTurbo]

So,
nun hab ich euch genug genervt. Habe das doch noch hinbekommen. Das OnExecute sollte so aussehen.

Trotzdem danke an alle

Delphi-Quellcode:

procedure TfMain.IdTCPServer1Execute(AContext: TIdContext);
var
  Cli   :TIdTCPClient;
  IOhnd :TIdIOHandlerStack;
  Data  :string;
  Len   :Int64;
  Buf   :TIdBytes;
begin
  try
    if ( PeerIPs.IndexOfName(AContext.Connection.Socket.Binding.PeerIP)<>-1 ) then begin   //bekannt
      GblUrl:=PeerIPs.Values[AContext.Connection.Socket.Binding.PeerIP];
    end else Exit;
    Cli := nil;
    try
      // #### Create IOHandler ####
      IOhnd:=TIdIOHandlerStack.Create(nil);
      { Create & Connect to Server }
      Cli:=TIdTCPClient.Create(nil);
      Cli.IOHandler:=IOhnd;
      Cli.Host := GblUrl;
      Cli.Port := 80;
      { Connect to the remote server }
      Cli.Connect;
      { Read/Write loop }
      repeat
        { Read data from Client }
        if ( AContext.Connection.IOHandler.InputBuffer.Size>0 ) then begin
          Len :=AContext.Connection.IOHandler.InputBuffer.Size;
          Data:=AContext.Connection.IOHandler.ReadString(Len);
          { Write it to the Server }
          Cli.IOHandler.Write(Data);
        end;
        { Read data from Server }
        if ( Cli.IOHandler.InputBuffer.Size>0 ) then begin
          Len:=Cli.IOHandler.InputBuffer.Size;
          Cli.IOHandler.ReadBytes(Buf,Len,False);
          { Write it to the Server }
          AContext.Connection.IOHandler.Write(Buf,Len);
        { Release system slizes }
        end;
        SleepEx(1, True);
        Cli.CheckForGracefulDisconnect(False);
        AContext.Connection.CheckForGracefulDisconnect(False);
      until (not AContext.Connection.Connected) or (not Cli.Connected);
    finally
      if Assigned(Cli) then
      begin
        Cli.Disconnect;
        Cli.Free
      end;
      { Disconnect real client }
      AContext.Connection.Disconnect;
      if ( Assigned(IOhnd) ) then begin
        IOhnd.Free;
      end;
    end;
  except
  end;
end;

[Bernhard Geyer]

Dein Exception-Handling schaut schon sehr "komisch" aus.

was macht das try..except mit leeren Exception-Block?
Was soll die Prüfung auf nil im Finally?
Kommentar bekannt? Bekannt für wen? Sicherlich nicht für einen der den Code in 2 Jahren nochmal anschaut
else mit exit? Wieso nicht gleich den Rest der Funktion gleich im then-Zweig laufen lassen?
nil-Setzen vor dem try...finally - Vor dem try sollen die Konstruktoren aufgerufen werden
// #### Create IOHandler #### Das sollte jeder nach zwei Wochen Delphi wissen das hier ein Konstruktor kommt
{ Connect to the remote server } Mehrwert Kommentar? Die Methode heißt connect
Die Disconnect würde ich im try-Zweig machen. Falls dort ein Excption auftritt wird mit free noch aufgeräumt.

Delphi-Quellcode:

  if PeerIPs.IndexOfName(AContext.Connection.Socket.Binding.PeerIP) <> -1 then
  begin 
    GblUrl := PeerIPs.Values[AContext.Connection.Socket.Binding.PeerIP];

    IOhnd := TIdIOHandlerStack.Create(nil);
    Cli := TIdTCPClient.Create(nil);
    try   
      Cli.IOHandler := IOhnd;
      Cli.Host := GblUrl;
      Cli.Port := 80;

      Cli.Connect;

      { Read/Write loop }
      repeat
        { Read data from Client }
        if AContext.Connection.IOHandler.InputBuffer.Size > 0 then
        begin
          Len := AContext.Connection.IOHandler.InputBuffer.Size;
          Data := AContext.Connection.IOHandler.ReadString(Len);
          { Write it to the Server }
          Cli.IOHandler.Write(Data);
        end;

        { Read data from Server }
        if Cli.IOHandler.InputBuffer.Size > 0 then
        begin
          Len := Cli.IOHandler.InputBuffer.Size;
          Cli.IOHandler.ReadBytes(Buf, Len, False);

          { Write it to the Server }
          AContext.Connection.IOHandler.Write(Buf,Len);
          { Release system slizes }
        end;

        SleepEx(1, True);
        Cli.CheckForGracefulDisconnect(False);
        AContext.Connection.CheckForGracefulDisconnect(False);
      until not AContext.Connection.Connected) or not Cli.Connected;

      Cli.Disconnect;
      AContext.Connection.Disconnect;
    finally
      Cli.Free
      IOhnd.Free;
    end;
  end;

[DelTurbo]

Hi,
das ist auch klar das man so nicht machen sollte. Aber ich habe das 1:1 aus der Quelle genommen und nur auf Indy10 geändert.

Und ich habe alles so gelassen, weil ich dachte es Hilft wenn man das "Original" und meine Änderungen sieht.

Aber vielleicht kannst du mir sagen wie man beim IdTcpServer an eine eindeutige SessionID kommt. Das such ich nun schon einen halben Tag. Ich meine NICHT die PeerIP. Die kann ja mehrfach da sein wenn jemand zu hause mehr als einen Rechner hat.

Gruß und Danke für den Hinweis.
PS.: Das ich 3 Themen aufgemacht habe, wollte ich nicht noch ein neues Thema aufmachen und dachte das finde ich schon. Ist aber nicht. Ich finde leider gar nichts.

[Bernhard Geyer]

Zitat:

Zitat von DelTurbo (Beitrag 1387761)

Aber vielleicht kannst du mir sagen wie man beim IdTcpServer an eine eindeutige SessionID kommt.

Ich verwende Indy nicht.

Zitat:

Zitat von DelTurbo (Beitrag 1387761)

PS.: Das ich 3 Themen aufgemacht habe, wollte ich nicht noch ein neues Thema aufmachen und dachte das finde ich schon. Ist aber nicht. Ich finde leider gar nichts.

Dann man am besten ein neues Thema mit passenden Titel auf.