String nach einem bestimmten Format durchsuchen

[Aromanaut]

Hallo!

Ich bin absoluter Community und Delphi Neuling und bleibe schon bei den einfachsten Sachen hängen.
Ich habe einen String (1234-56-78 XXX XXX) der eine Art Datumsformat (4Ziffern-2Ziffern-2Ziffern) enthält und nach dem ich gerne suchen möchte.
Mit der Funktion ContainsText() sollte das wohl gehen aber ich brauch die Platzhalter für die Ziffern und kann sie in der Hilfe nicht finden.
Bitte helft mir!

Danke!

[Der schöne Günther]

Hallo und Willkommen in den Heiligen Hallen des Wissens und des Wahnsinns :love:

Schau doch als erstes einmal in die Hilfe zu

Delphi-Quellcode:

ContainsText(..)

:
http://docwiki.embarcadero.com/Libra...s.ContainsText

Zitat:

Führt eine Suche ohne Berücksichtigung der Groß-/Kleinschreibung nach dem Substring ASubText im String AText durch. Gibt true zurück, wenn ein oder mehrere Vorkommen von ASubText in AText enthalten sind.

Die Funktion sagt dir nur "Ja" oder "Nein" ob ein Text in einem anderen vorkommt. Das hilft dir nicht wirklich weiter. Was du brauchst ist ein … Achtung …
https://de.wikipedia.org/wiki/String-Matching-Algorithmus


Bewährt haben sich hier die regulären Ausdrücke. Das ist in Delphi alles schon fertig drin.

Die Ultra-Kurzform sähe so aus:

Delphi-Quellcode:

uses System.RegularExpressions;

function passtAufMeinMuster(const input: String): Boolean;
const
   pattern = '\d{4}-\d{2}-\d{2}\s\d{3}\s\d{3}';
begin
   Result := TRegex.IsMatch(input, pattern);
end;

Wahrscheinlich willst du aber noch mehr. Beispielsweise alle solche Muster in deinem Text finden und die Zahlen hinter dem Datum (deine XXX XXX) herauslesen und ausgeben, oder?

Ich denke mal du kanntest reguläre Ausdrücke noch nicht. Experimentier mal ein bisschen damit herum, da kann man wirklich schon eine Menge mit anstellen.

Ganz gut im Browser spielen kann man auch unter
https://regexr.com/
oder
https://regex101.com/

[Andreas L.]

Folgende Funktion habe ich vor Jahren hier in der Delphi-Praxis gefunden. Sie arbeitet mit Wildcards (*). Funktioniert tadellos. Kannst du das brauchen?

Delphi-Quellcode:

// Like: Code by Michael Winter
function Like(AText: string; APattern: string): Boolean;
var
  StringPtr, PatternPtr: PChar;
  StringRes, PatternRes: PChar;
begin
  Result := False;
  StringPtr := PChar(AText);
  PatternPtr := PChar(APattern);
  StringRes := nil;
  PatternRes := nil;
  repeat
    repeat // ohne vorangegangenes "*"
      case PatternPtr^ of
        #0: begin
          Result := StringPtr^=#0;
          if Result or (StringRes = nil) or (PatternRes = nil) then
            Exit;
          StringPtr := StringRes;
          PatternPtr := PatternRes;
          Break;
        end;
        '*': begin
          inc(PatternPtr);
          PatternRes := PatternPtr;
          Break;
        end;
        '?': begin
          if StringPtr^=#0 then
            Exit;
          inc(StringPtr);
          inc(PatternPtr);
        end;
        else begin
          if StringPtr^=#0 then
            Exit;
          if StringPtr^<>PatternPtr^ then begin
            if (StringRes = nil) or (PatternRes = nil) then
              Exit;
            StringPtr := StringRes;
            PatternPtr := PatternRes;
            Break;
          end
          else begin
            inc(StringPtr);
            inc(PatternPtr);
          end;
        end;
      end;
    until False;
    repeat // mit vorangegangenem "*"
      case PatternPtr^ of
        #0: begin
          Result := True;
          Exit;
        end;
        '*': begin
          inc(PatternPtr);
          PatternRes := PatternPtr;
        end;
        '?': begin
          if StringPtr^=#0 then
            Exit;
          inc(StringPtr);
          inc(PatternPtr);
        end;
        else begin
          repeat
            if StringPtr^=#0 then
              Exit;
            if StringPtr^=PatternPtr^ then
              Break;
            inc(StringPtr);
          until False;
          inc(StringPtr);
          StringRes := StringPtr;
          inc(PatternPtr);
          Break;
        end;
      end;
    until false;
  until false;
end;

Aufruf:

Delphi-Quellcode:

  Text := 'Hallo Welt. Wie geht es dir?';
  Suche := '*Welt*';
  if Like(Text, Suche) then
    // ...

[Aromanaut]

Guten Morgen!

Vielen Dank für die Antworten und speziell an den schönen Günther, das ist so ziemlich genau das was ich gesucht habe.
Ich werde mich jetzt mal mit den Regular Expressions auseinandersetzen, vermute aber, dass das nicht meine letzte Frage gewesen sein wird?!

Danke noch mal...