Delphi-PRAXiS

Delphi-PRAXiS (https://www.delphipraxis.net/forum.php)
-   Cross-Platform-Entwicklung (https://www.delphipraxis.net/91-cross-platform-entwicklung/)
-   -   Delphi Android Kamerazugriff java.lang.NullPointerException error (https://www.delphipraxis.net/201272-android-kamerazugriff-java-lang-nullpointerexception-error.html)

lereis 6. Jul 2019 18:20

Android Kamerazugriff java.lang.NullPointerException error
 
Hallo,

ich habe mich jetzt endlich mal an die App Entwicklung mit Delphi 10.3 gewagt.
Das Ziel war eine einfach App die ein Bild mit der Kamera macht.
Dazu habe ich mir online etwas Hilfe geholt und bin nun so weit, dass
die App schonmal nach den benötigten Berechtigungen fragt.
Wenn ich jetzt aber das Bild machen will, bekomme ich folgende Fehlermeldung:

"java.lang.NullPointerException: Attempt to invoke virtual method 'android.content.res.XmlResourceParser
android.content.pm.ProviderInfo.loadXmlMetaData(an droid.content.pm.PacketManager,java.lang.String)' on a null object reference"

Online habe ich gelesen dass es villeicht an der AndroidManifest Datei liegt, aber die wird ja eigentlich automatisch erzeugt.

Delphi-Quellcode:
unit Camera;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.MediaLibrary, FMX.Platform, System.Messaging,
  FMX.Objects, FMX.StdCtrls, FMX.Controls.Presentation, System.Permissions,FMX.DialogService,
  {$IFDEF ANDROID}
  Androidapi.Jni.Os,
  Androidapi.Helpers
  {$ENDIF};

type
  TForm1 = class(TForm)
    ToolBar1: TToolBar;
    SpeedButton1: TSpeedButton;
    SpeedButton2: TSpeedButton;
    Image1: TImage;
    procedure SpeedButton1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }

    FPermissionCamera: string;
    FPermissionReadStorage: string;
    FPermissionWriteStorage: string;

     procedure DoDidFinish(Image: TBitmap);
     procedure DoMessageListener(const Sender: TObject; const M: TMessage);
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.fmx}

 procedure TForm1.DoDidFinish(Image: TBitmap);
begin
  Image1.Bitmap.Assign(Image);
end;

procedure TForm1.DoMessageListener(const Sender: TObject; const M: TMessage);
begin
  if M is TMessageDidFinishTakingImageFromLibrary then
    Image1.Bitmap.Assign(TMessageDidFinishTakingImageFromLibrary(M).Value);
end;


procedure TForm1.FormCreate(Sender: TObject);

begin

  FPermissionCamera := JStringToString(TJManifest_permission.JavaClass.CAMERA);
  FPermissionReadStorage := JStringToString(TJManifest_permission.JavaClass.READ_EXTERNAL_STORAGE);
  FPermissionWriteStorage := JStringToString(TJManifest_permission.JavaClass.WRITE_EXTERNAL_STORAGE);

  PermissionsService.RequestPermissions([FPermissionCamera,FPermissionReadStorage,FPermissionWriteStorage],
   procedure(const APermissions: TArray<string>; const AGrantResults: TArray<TPermissionStatus>)
   begin
        if (Length(AGrantResults) = 1) and (AGrantResults[0] = TPermissionStatus.Granted) then
          TDialogService.ShowMessage('permission granted')
        else
        begin
          TDialogService.ShowMessage('permission not granted');
        end;
      end
  );
end;


procedure TForm1.SpeedButton1Click(Sender: TObject);
var
  Service: IFMXCameraService;
  Params: TParamsPhotoQuery;
begin
  if TPlatformServices.Current.SupportsPlatformService(IFMXCameraService,
    Service) then
  begin
    Params.Editable := True;
    // Specifies whether to save a picture to device Photo Library
    Params.NeedSaveToAlbum := True;
    Params.RequiredResolution := TSize.Create(640, 640);
    Params.OnDidFinishTaking := DoDidFinish;
    Service.TakePhoto(SpeedButton1, Params);
  end
  else
    ShowMessage('This device does not support the camera service');
end;

end.

Wenn ich den Kamerabutton drücke, bekomme ich auch das ShowMessage 'permission not granted',
obwohl ich den Zugriff am Handy erlaube.

Villeicht hat ja von euch jemand eine Idee.

Vielen Dank schonmal,
lereis

zeras 6. Jul 2019 20:21

AW: Android Kamerazugriff java.lang.NullPointerException error
 
Du fragst an nach den Berechtigungen für

Kamera, Lesen und Schreiben externer Daten.

Delphi-Quellcode:
  FPermissionCamera := JStringToString(TJManifest_permission.JavaClass.CAMERA);
  FPermissionReadStorage := JStringToString(TJManifest_permission.JavaClass.READ_EXTERNAL_STORAGE);
  FPermissionWriteStorage := JStringToString(TJManifest_permission.JavaClass.WRITE_EXTERNAL_STORAGE);

Du musst auch die Berechtigung wegen des Standortes anfragen.

Bei den Beispielen gibt es auch eines mit einer Kamera dabei.

lereis 6. Jul 2019 20:32

AW: Android Kamerazugriff java.lang.NullPointerException error
 
Zitat:

Zitat von zeras (Beitrag 1436184)
Du fragst an nach den Berechtigungen für

Kamera, Lesen und Schreiben externer Daten.

Delphi-Quellcode:
  FPermissionCamera := JStringToString(TJManifest_permission.JavaClass.CAMERA);
  FPermissionReadStorage := JStringToString(TJManifest_permission.JavaClass.READ_EXTERNAL_STORAGE);
  FPermissionWriteStorage := JStringToString(TJManifest_permission.JavaClass.WRITE_EXTERNAL_STORAGE);

Du musst auch die Berechtigung wegen des Standortes anfragen.

Bei den Beispielen gibt es auch eines mit einer Kamera dabei.

Aber den brauche ich doch garnicht oder? Da habe ich nur das showmessage noch nicht angepasst.
Oder braucht man für ein Kamerafoto auch Loaction Zugriff?

Das Beispiel habe ich schon getestet, das öffnet sich nichtmal richtig und bleibt bei dem "Flammensymbol" hängen

zeras 6. Jul 2019 20:43

AW: Android Kamerazugriff java.lang.NullPointerException error
 
Zitat:

Zitat von lereis (Beitrag 1436186)

Aber den brauche ich doch garnicht oder? Da habe ich nur das showmessage noch nicht angepasst.
Oder braucht man für ein Kamerafoto auch Loaction Zugriff?

Nein, brauchst du nicht unbedingt, aber im ersten Beitrag von dir stand doch etwas vom "location sensor". Das ist jetzt aber weg.

Bitte prüfe all deine Berechtigungen, die du benötigst, ob diese auch unter Projekt -> Optionen -> Anwendung -> Berechtigungen gesetzt sind. Diese werden dann in dein Manifest mit eingetragen.

lereis 6. Jul 2019 20:51

AW: Android Kamerazugriff java.lang.NullPointerException error
 
Zitat:

Zitat von zeras (Beitrag 1436187)
Zitat:

Zitat von lereis (Beitrag 1436186)

Aber den brauche ich doch garnicht oder? Da habe ich nur das showmessage noch nicht angepasst.
Oder braucht man für ein Kamerafoto auch Loaction Zugriff?

Nein, brauchst du nicht unbedingt, aber im ersten Beitrag von dir stand doch etwas vom "location sensor". Das ist jetzt aber weg.

Bitte prüfe all deine Berechtigungen, die du benötigst, ob diese auch unter Projekt -> Optionen -> Anwendung -> Berechtigungen gesetzt sind. Diese werden dann in dein Manifest mit eingetragen.


Ja, das habe ich angepasst. Das war nurnoch im showmessage drin weil ich mir den code aus einem anderen Beispiel gezogen habe.

Ich habe die Berechtigungen meiner Meinung nach richtig gesetzt. Ich weiss nicht wie man hier Bilder einfügen kann, deswegen hab ich den screenshot mal auf meinen Server geladen:

http://brand-soft.de/Unbenannt.JPG

Rollo62 7. Jul 2019 08:29

AW: Android Kamerazugriff java.lang.NullPointerException error
 
Ich würde die Permissions-Abfrage nach FormShow verschieben, damit das Ganze nicht zu früh kommt, sollte aber trotzdem funktionieren.

Versuch mal die Entitlements Secure File Sharing zu setzen
Zitat:

Entitlement List for Android

Sets the entitlement options of the current Android project. Select Android platform in the Target combo box.

Examples of entitlements you can set in an Android application:

AdMob Service: To enable Google advertising service for an Android application.
Receive push notifications: To enable GCM support in an Android application and receive data from remote servers.
Maps Service: Adds 2 entries to the Android manifest file to allow Google Maps to work (i.e. a TMapView to function). As mentioned in the Configuring Android Applications to Use Google Maps page.
Secure File Sharing: To allow a TTakePhotoFromCameraAction to function, as well as anything else that needs to expose a file via a file:// URI from its application.

zeras 7. Jul 2019 09:12

AW: Android Kamerazugriff java.lang.NullPointerException error
 
Ich habe einmal dein Beispiel genutzt. Die Fehlermeldung kommt auch bei mir, aber ich kann ein Foto aufnehmen.
Geht das auch bei dir?

zeras 7. Jul 2019 09:26

AW: Android Kamerazugriff java.lang.NullPointerException error
 
Da du 3 Berechtigungen haben möchtest, musst du diese auch entsprechend abfragen, siehe weiter unten:
Delphi-Quellcode:
  FPermissionCamera := JStringToString(TJManifest_permission.JavaClass.CAMERA);
  FPermissionReadStorage := JStringToString(TJManifest_permission.JavaClass.READ_EXTERNAL_STORAGE);
  FPermissionWriteStorage := JStringToString(TJManifest_permission.JavaClass.WRITE_EXTERNAL_STORAGE);

  PermissionsService.RequestPermissions([FPermissionCamera,FPermissionReadStorage,FPermissionWriteStorage],
   procedure(const APermissions: TArray<string>; const AGrantResults: TArray<TPermissionStatus>)
   begin
//        if (Length(AGrantResults) = 1) and (AGrantResults[0] = TPermissionStatus.Granted) then
     if (Length(AGrantResults) = 3)
     and (AGrantResults[0] = TPermissionStatus.Granted)
     and (AGrantResults[1] = TPermissionStatus.Granted)
     and (AGrantResults[2] = TPermissionStatus.Granted) then

          TDialogService.ShowMessage('permission granted')
        else
        begin
          TDialogService.ShowMessage('permission not granted');
        end;
      end
  );
end;

lereis 7. Jul 2019 12:59

AW: Android Kamerazugriff java.lang.NullPointerException error
 
Zitat:

Zitat von zeras (Beitrag 1436205)
Da du 3 Berechtigungen haben möchtest, musst du diese auch entsprechend abfragen, siehe weiter unten:
Delphi-Quellcode:
  FPermissionCamera := JStringToString(TJManifest_permission.JavaClass.CAMERA);
  FPermissionReadStorage := JStringToString(TJManifest_permission.JavaClass.READ_EXTERNAL_STORAGE);
  FPermissionWriteStorage := JStringToString(TJManifest_permission.JavaClass.WRITE_EXTERNAL_STORAGE);

  PermissionsService.RequestPermissions([FPermissionCamera,FPermissionReadStorage,FPermissionWriteStorage],
   procedure(const APermissions: TArray<string>; const AGrantResults: TArray<TPermissionStatus>)
   begin
//        if (Length(AGrantResults) = 1) and (AGrantResults[0] = TPermissionStatus.Granted) then
     if (Length(AGrantResults) = 3)
     and (AGrantResults[0] = TPermissionStatus.Granted)
     and (AGrantResults[1] = TPermissionStatus.Granted)
     and (AGrantResults[2] = TPermissionStatus.Granted) then

          TDialogService.ShowMessage('permission granted')
        else
        begin
          TDialogService.ShowMessage('permission not granted');
        end;
      end
  );
end;

Das ist ein guter Einwand. Ich weiss nicht wie mir das nicht auffallen konnte. Habe es angepasst und jetzt prüft er zumindest schonmal die Berechtigungen richtig. Vielen Dank. :-D

lereis 7. Jul 2019 13:00

AW: Android Kamerazugriff java.lang.NullPointerException error
 
Zitat:

Zitat von Rollo62 (Beitrag 1436202)
Ich würde die Permissions-Abfrage nach FormShow verschieben, damit das Ganze nicht zu früh kommt, sollte aber trotzdem funktionieren.

Versuch mal die Entitlements Secure File Sharing zu setzen
Zitat:

Entitlement List for Android

Sets the entitlement options of the current Android project. Select Android platform in the Target combo box.

Examples of entitlements you can set in an Android application:

AdMob Service: To enable Google advertising service for an Android application.
Receive push notifications: To enable GCM support in an Android application and receive data from remote servers.
Maps Service: Adds 2 entries to the Android manifest file to allow Google Maps to work (i.e. a TMapView to function). As mentioned in the Configuring Android Applications to Use Google Maps page.
Secure File Sharing: To allow a TTakePhotoFromCameraAction to function, as well as anything else that needs to expose a file via a file:// URI from its application.

Das wars. Jetzt klappts.
Für alle die das Problem auch haben: Projekt->Anwendung->Berechtigungsliste->Sichere Dateifreigabe aktivieren.
Vielen Dank

zeras 7. Jul 2019 19:32

AW: Android Kamerazugriff java.lang.NullPointerException error
 
Ich habe noch ein Blog gefunden, wo das sehr gut beschrieben ist:

hier


Alle Zeitangaben in WEZ +1. Es ist jetzt 13:16 Uhr.

Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz