JSON - lesen eines JSON Elements

[wschrabi]

Liebe Leute,
leider habe ich in StackoverFlow keinen passenden Rat bekommen, nur eine demotivierende Bemerkung.
KAnn mir jemand sagen wie ich die Änderung meines Programms machen kann um zum Resultat zu kommen?
Vielleicht habe ich in diesem Forum mehr Glück.
Hier mein Posting.
https://stackoverflow.com/questions/...rray-in-delphi
DANKE

[Schokohase]

Wenn du die Frage hier stellen möchtest, dann stelle diese doch auch hier.

In der Zwischenzeit habe ich die verlinkte Frage bei SO durchgelesen aber dabei wurde mir nicht klar, was du eigentlich wirklich erreichen willst.

Es wäre auch nett, wenn du den JSON String mit Einrückungen (Indented) formatieren könntest, dann ist es einfacher sich in der Struktur zurechtzufinden (wenn du nicht weiß wie, dann klicke hier). Auch der Delphi-Code wäre formatiert besser zu verstehen (mehrere Statements in einer Zeile sind nicht hilfreich).

Es ist immer von Vorteil die Dinge so leserlich wie möglich zu präsentieren und eben nicht als Buchstabensuppe (so kommt das JSON daher).

Diese genannten Punkte werden auch der Grund für den sehr allgemein gehaltenen Ratschlag auf SO zu sein. Im Prinzip könnte ich - aus besagten Gründen - aber auch nicht mehr dazu beitragen.

[samso]

Code:

[
  {
    "total": "9",
    "page": "9",
    "records": "99",
    "rows": [
      {
        "id": "62316",
        "titleId": "47243",
        "subject": [
          "000607",
          "000607_",
          "001727"
        ],
        "keyFeatures": [
          "AI",
          "URL"
        ]
      },
      {
        "id": "66",
        "titleId": "47243",
        "subject": [
          "000607",
          "000607_",
          "001727"
        ],
        "keyFeatures": [
          "KK"
        ]
      }
    ],
    "suggestion": "90"
  }
]

Mir ist Dein Quelltext zu anstrengend. Ich halte mich da eher an das Beispiel aus Stackoverflow.

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  DataBase: String;
  JsonArray: TJSONArray;
  ArrayElement: TJSonValue;
  RowValue: TJSonValue;
  RowItem: TJSonValue;
  keyFeatures: TJSonValue;
  FeatureItem: TJSonValue;
  FeatureList: TStringlist;
  Id: Integer;
  Index: Integer;
begin
  Memo1.Clear;
  DataBase :=
    '[{"total":"9","page":"9","records":"99","rows":[{"id":"62316","titleId":"47243","subject":'
    + '["000607","000607_","001727"],"keyFeatures":["AI","URL"]},{"id":"66","titleId":"47243","subject":'
    + '["000607","000607_","001727"],"keyFeatures":["KK"]}],"suggestion":"90"}]';

  JsonArray := TJSonObject.ParseJSONValue(DataBase) as TJSONArray;
  try
    Index := 1;
    for ArrayElement in JsonArray do
    begin
      RowValue := (ArrayElement as TJSonObject).GetValue('rows');
      if RowValue is TJSONArray
      then
      begin
        for RowItem in TJSONArray(RowValue) do
        begin
          RowItem.TryGetValue('id', Id);
          keyFeatures := (RowItem as TJSonObject).GetValue('keyFeatures');
          if keyFeatures is TJSONArray
          then
          begin
            FeatureList := TStringlist.Create;
            try
              for FeatureItem in TJSONArray(keyFeatures) do
                FeatureList.Add(FeatureItem.Value);
              Memo1.Lines.Add(Format('%d: %d KeyFeatures: %s', [Index, Id, FeatureList.CommaText]));
            finally
              FeatureList.Free;
            end;
          end;
          inc(Index);
        end;
      end;
    end;
  finally
    JsonArray.Free;
  end;
end;

[wschrabi]

TAUSEND DANK; hab dadurch wieder viel gelernt. Mit RowItem ... cool.
DANKE herzlichst, ja die DelphiPraxis ist hat doch noch besser als SO.

Schönen GRUSs:P:thumb: