Delphi-PRAXiS

Delphi-PRAXiS (https://www.delphipraxis.net/forum.php)
-   Object-Pascal / Delphi-Language (https://www.delphipraxis.net/32-object-pascal-delphi-language/)
-   -   Delphi Reaktion auf Positionsänderung nach Änderung der Bildschirmauflösung (https://www.delphipraxis.net/204295-reaktion-auf-positionsaenderung-nach-aenderung-der-bildschirmaufloesung.html)

Dalai 15. Mai 2020 21:51

Delphi-Version: 5

Reaktion auf Positionsänderung nach Änderung der Bildschirmauflösung
 
Hallo *.*

Simple Frage: Gibt es ein Event oder eine (Window) Message, auf das/die man reagieren kann, nachdem Delphi mit dem Verschieben von Formularen fertig ist, wenn sich die Bildschirmauflösung geändert hat?

Etwas Hintergrundinfo und Erklärung der Problematik:
Gegeben sei eine Bildschirmauflösung 800x600, sowie ein Formular, positioniert zentriert an der unteren Bildschirmkante. Bildschirmauflösung wird geändert auf 1280x960. Delphi repositioniert das Formular, aber nicht wieder an die untere Bildschirmkante und auch nicht zentriert sondern nach links und oben verschoben. Wie weit nach links & oben verschoben wird, hängt offenbar auch von der Größe des Formulars ab. Das soll mir aber letztlich egal sein, weil ich die Position sowieso korrieren muss. Eine Reaktion auf WM_DISPLAYCHANGE bringt nichts, weil Delphi das Formular danach nochmals verschiebt.

Hier ein Testprogramm:
Delphi-Quellcode:
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs;

const
  UM_SETPOS_RESOLUTIONCHANGE = WM_USER + 42;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDblClick(Sender: TObject);
  private
    procedure WMDisplayChange(var Msg: TWMDisplayChange); message WM_DISPLAYCHANGE;
    procedure UMResolutionChange(var Msg: TMsg); message UM_SETPOS_RESOLUTIONCHANGE;
    procedure SetPosition;
  public
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.WMDisplayChange(var Msg: TWMDisplayChange);
begin
    inherited;
    PostMessage(Self.Handle, UM_SETPOS_RESOLUTIONCHANGE, 0, 0);
end;

procedure TForm1.UMResolutionChange(var Msg: TMsg);
begin
    Sleep(400);
    Self.SetPosition;
    Sleep(400);
    Self.SetPosition;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
    SetPosition;
end;

procedure TForm1.SetPosition;
var
  Ltop, Lleft: integer;
begin
    Lleft:= (Screen.Width - Self.Width) div 2;
    Ltop:= Screen.Height - Self.Height;
//    Self.Caption:= Format('X: %d, Y:%d', [Lleft, Ltop]);
//    Self.SetBounds(Lleft - 1, Ltop - 1, Self.Width, Self.Height);
//    Self.SetBounds(Lleft, Ltop, Self.Width, Self.Height);
    MoveWindow(Self.Handle, Lleft, Ltop, Self.Width, Self.Height, True);
end;


procedure TForm1.FormDblClick(Sender: TObject);
begin
    SetPosition;
end;

end.
Mit diesem Testprogramm sieht man auch, dass der erste Ruf von SetPosition die korrekte Position setzt, danach "springt" die Form nach links & oben. Der zweite Ruf von SetPosition ist nur zum Test. Die errechneten Koordinaten stimmen immer, aber das Formular landet nicht dort bzw. nur mit dem ersten Ruf von SetPosition und natürlich beim Doppelklick auf das Formular.

Grüße
Dalai

jaenicke 15. Mai 2020 22:38

AW: Reaktion auf Positionsänderung nach Änderung der Bildschirmauflösung
 
Solche Probleme kenne ich nur von alten Delphiversionen. Damals ging da einiges schief bei der Rand- und Positionsberechnung und der Reaktion auf Konfiguratonsänderungen.

Im aktuellen Delphi 10.3 genügt ein SetPosition in WMDisplayChange vollkommen aus, ein PostMessage oder sogar Sleep oder ähnliches ist nicht notwendig.

Wenn du wie angegeben noch Delphi 5 hast, bleibt nur einen Haltepunkt auf eine überschriebene Methode SetBounds (wenn es das da schon gab) zu setzen und zu schauen wo die Anpassungen der Position ausgelöst werden, die du nicht möchtest.

Dalai 15. Mai 2020 23:37

AW: Reaktion auf Positionsänderung nach Änderung der Bildschirmauflösung
 
Zitat:

Zitat von jaenicke (Beitrag 1464664)
Solche Probleme kenne ich nur von alten Delphiversionen. Damals ging da einiges schief bei der Rand- und Positionsberechnung und der Reaktion auf Konfiguratonsänderungen.

Dann zählt wohl Delphi XE2 auch zu den alten, denn damit ist es gleichermaßen nachvollziehbar.

Zitat:

[...] ein PostMessage oder sogar Sleep oder ähnliches ist nicht notwendig.
Das war alles nur zum Test, damit ich sehe, was (wann) passiert. Bei PostMessage hatte ich die Hoffnung, dass die Nachricht ans Ende der Queue gepackt wird, und erst abgearbeitet wird, nachdem Delphi mit seinem Kram durch ist.

Zitat:

[...] bleibt nur einen Haltepunkt auf eine überschriebene Methode SetBounds (wenn es das da schon gab) zu setzen und zu schauen wo die Anpassungen der Position ausgelöst werden, die du nicht möchtest.
OK, schaue ich mir mal an. Im Prinzip kann Delphi schon die Anpassungen machen, wenn ich sie danach korrigieren oder überstimmen kann.

Grüße
Dalai

Dalai 16. Mai 2020 19:36

AW: Reaktion auf Positionsänderung nach Änderung der Bildschirmauflösung
 
Also ich komme da auf keinen grünen Zweig. Selbst mit Debug DCUs und Durchsteppen durch die Controls- und Forms-Units ist es mir nicht gelungen, die Ursache oder zumindest den Auslöser zu finden.

Daher gehe ich jetzt den pragmatischen Weg und benutze das Application.OnIdle-Ereignis:
Delphi-Quellcode:
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDblClick(Sender: TObject);
  private
    procedure WMDisplayChange(var Msg: TWMDisplayChange); message WM_DISPLAYCHANGE;
    procedure SetPosition;
    procedure OnIdle(Sender: TObject; var Done: Boolean);
  public
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.WMDisplayChange(var Msg: TWMDisplayChange);
begin
    inherited;
    Application.OnIdle:= Self.OnIdle;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
    SetPosition;
end;

procedure TForm1.OnIdle(Sender: TObject; var Done: Boolean);
begin
    Application.OnIdle:= nil;
    SetPosition;
end;

procedure TForm1.SetPosition;
var
  Ltop, Lleft: integer;
begin
    Lleft:= (Screen.Width - Self.Width) div 2;
    Ltop:= Screen.Height - Self.Height;
    Self.SetBounds(Lleft, Ltop, Self.Width, Self.Height);
end;

procedure TForm1.FormDblClick(Sender: TObject);
begin
    SetPosition;
end;

end.
Application.OnIdle ist offenbar eines, das erst ausgelöst wird, wenn Delphi alle durch die Auflösungsänderung verschickten/erzeugten Nachrichten bearbeitet hat. Jedenfalls besser, als einen Timer dafür zu missbrauchen...

Falls jemand noch (bessere) Ideen hat, bin ich dafür offen.

Grüße
Dalai

jaenicke 18. Mai 2020 05:50

AW: Reaktion auf Positionsänderung nach Änderung der Bildschirmauflösung
 
Zitat:

Zitat von Dalai (Beitrag 1464698)
Also ich komme da auf keinen grünen Zweig. Selbst mit Debug DCUs und Durchsteppen durch die Controls- und Forms-Units ist es mir nicht gelungen, die Ursache oder zumindest den Auslöser zu finden.

Wie sieht denn der Stacktrace zum SetBounds an der Stelle aus, an der nach deiner Änderung die Position wieder falsch gesetzt wird?

Dazu musst du ja nur das SetBounds überschreiben und dann vor deinem Aufruf von SetBounds den Haltepunkt im SetBounds (z.B. auch per Haltepunktgruppe automatisch) aktivieren. Dann wirst du einmal dein SetBounds bekommen und danach solltest du dort erneut ankommen.

Rollo62 18. Mai 2020 11:15

AW: Reaktion auf Positionsänderung nach Änderung der Bildschirmauflösung
 
Zitat:

Zitat von Dalai (Beitrag 1464698)
Selbst mit Debug DCUs und Durchsteppen durch die Controls- und Forms-Units ist es mir nicht gelungen, die Ursache oder zumindest den Auslöser zu finden.

Schon mit Remote-Debugging und/oder Logging versucht ?

Dalai 18. Mai 2020 20:57

AW: Reaktion auf Positionsänderung nach Änderung der Bildschirmauflösung
 
Zitat:

Zitat von jaenicke (Beitrag 1464755)
Wie sieht denn der Stacktrace zum SetBounds an der Stelle aus, an der nach deiner Änderung die Position wieder falsch gesetzt wird?

Stacktrace könnte ich zur Verfügung stellen, aber für den ersten Aufruf bringt das wohl kaum etwas, denn der ist soweit korrekt. Es gibt keinen weiteren Aufruf von SetBounds. Genau deshalb finde ich ja nicht heraus, was da los ist.

Delphi-Quellcode:
type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDblClick(Sender: TObject);
  private
    procedure WMDisplayChange(var Msg: TWMDisplayChange); message WM_DISPLAYCHANGE;
    procedure SetPosition;
  public
    procedure SetBounds(ALeft, ATop, AWidth, AHeight: integer); override;
  end;


procedure TForm1.WMDisplayChange(var Msg: TWMDisplayChange);
begin
    inherited;
    Self.SetPosition;
end;

procedure TForm1.SetPosition;
var
  Ltop, Lleft: integer;
begin
    Lleft:= (Screen.Width - Self.Width) div 2;
    Ltop:= Screen.Height - Self.Height;
    Self.SetBounds(Lleft, Ltop, Self.Width, Self.Height);
end;

procedure TForm1.SetBounds(ALeft, ATop, AWidth, AHeight: integer);
begin
    inherited;
end;
WMDisplayChange ruft SetPosition und dieses ruft (einmalig) SetBounds. Das war's.

Zitat:

Dazu musst du ja nur das SetBounds überschreiben und dann vor deinem Aufruf von SetBounds den Haltepunkt im SetBounds (z.B. auch per Haltepunktgruppe automatisch) aktivieren. Dann wirst du einmal dein SetBounds bekommen und danach solltest du dort erneut ankommen.
Das SetBounds wird nur einmalig gerufen, und unmittelbar danach ist die Position korrekt - jedenfalls wenn ich glauben kann, was ich auf dem Bildschirm sehe, denn ich weiß nicht, ob die Nachrichten wirklich synchron verarbeitet werden. Beim Durchsteppen fiel mir auf, dass WM_PAINT-Nachrichten verarbeitet wurden, obwohl das Fenster schon an der richtigen Position war. Vermutlich setzt Delphi die Position durch etwas anderes als SetBounds.

Grüße
Dalai


Alle Zeitangaben in WEZ +1. Es ist jetzt 05:43 Uhr.

Powered by vBulletin® Copyright ©2000 - 2020, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2020 by Daniel R. Wolf