Delphi-PRAXiS
Seite 1 von 3  1 23   

Delphi-PRAXiS (https://www.delphipraxis.net/forum.php)
-   Algorithmen, Datenstrukturen und Klassendesign (https://www.delphipraxis.net/78-algorithmen-datenstrukturen-und-klassendesign/)
-   -   Delphi DEC6.0 Verständnisfrage AES Ver-/Entschlüsselung (https://www.delphipraxis.net/206940-dec6-0-verstaendnisfrage-aes-ver-entschluesselung.html)

Aviator 10. Feb 2021 17:18

DEC6.0 Verständnisfrage AES Ver-/Entschlüsselung
 
Hallo Delphianer,

ich nutze zum ersten Mal DEC in der Version 6.0. Zuvor habe ich noch nicht mit dem DEC gearbeitet und daher auch keine Vorkenntnisse darüber. Besonders viel findet man darüber aktuell auch (noch) nicht im Netz, da die Version ja recht frisch ist. Oder ich hab falsch gesucht.

Konkret geht es mir darum, dass ich eine Verschlüsselung (und logischerweise auch Entschlüsselung) per AES machen möchte. Ich bin auch mittlerweile so weit, dass das Ver- und Entschlüsseln funktioniert, habe aber den Verdacht, dass das einfacher funktionieren muss und ich nur auf dem Schlauch stehe. Vor allem dieses dauerhafte Umwandeln von
Delphi-Quellcode:
TArray<Byte>
in
Delphi-Quellcode:
string
und umgekehrt kommt mir recht aufwendig vor. Ich vermute ich kenne einfach nur die Kniffe noch nicht die man anwenden kann.

Speichern wollte ich den verschlüsselten String nachher im Base64 Format in einer JSON Datei. Der IV für die Verschlüsselung wird einfach als Byte Array vor den eigentlichen verschlüsselten Text gehängt. Das funktioniert auch schon.

Beim Entschlüsseln bekomme ich allerdings immer den String mit #0 nach den einzelnen Chars zurück. Ich tippe hier nur auf ein Problem mit den Encoding, konnte aber mit meinen Versuchen keine Lösung erzielen.

Kann mal jemand über meine Klasse und auch die Aufrufe der Methoden drüber schauen und mir ggf. einen Tipp geben was ich besser machen kann?

Delphi-Quellcode:
unit Common.Encryption.AES;

interface

uses
  Common.Interfaces.Aes, Common.Interfaces.AesKeyReader, DECCiphers, DECRandom, System.SysUtils, Logger.Interfaces,
  Logger.Enumerations, Logger.Helpers, DECCipherBase, System.Classes, System.Generics.Collections;

type
  TAes = class(TInterfacedObject, IAes)
  private
    FAesKeyReader: IAesKeyReader;
    FLogger: ILogger;
  public
    constructor Create(Logger: ILogger; AesKeyReader: IAesKeyReader);
    function Decrypt(Cipher: TArray<Byte>): string;
    function Encrypt(PlainText: string): TArray<Byte>; overload;
    function Encrypt(PlainText: string; IV: TArray<Byte>): TArray<Byte>; overload;
  end;

implementation

{ TAes }

constructor TAes.Create(Logger: ILogger; AesKeyReader: IAesKeyReader);
begin
  inherited Create;

  FLogger := Logger;
  FAesKeyReader := AesKeyReader;
end;

function TAes.Decrypt(Cipher: TArray<Byte>): string;
const
  IV_LEN = $10;
var
  AES: TCipher_AES;
  iv, data: TBytes;
  ms: TBytesStream;
  decrypted: TArray<Byte>;
begin
  try
    AES := TCipher_AES.Create;
    try
      ms := TBytesStream.Create(Cipher);
      try
        SetLength(iv, IV_LEN);
        if (ms.Read(iv, IV_LEN) = IV_LEN) then begin
          AES.Mode := cmCBCx;
          AES.Init(FAesKeyReader.GetAesKey, iv);

          SetLength(data, ms.Size - IV_LEN);
          if (ms.Read(data, ms.Size - IV_LEN) = ms.Size - IV_LEN) then begin
            decrypted := AES.DecodeBytes(data);
            Result := TEncoding.Default.GetString(decrypted);
          end;
        end;
      finally
        ms.Free;
      end;
    finally
      AES.Free;
    end;
  except
    on e: Exception do begin
      Result := EmptyStr;
      TLogHelper.LogMessage('Error decrypting given cipher: %s', [e.Message], lcError, FLogger);
    end;
  end;
end;

function TAes.Encrypt(PlainText: string): TArray<Byte>;
var
  IV: TArray<Byte>;
begin
  IV := RandomBytes($10);
  Result := Encrypt(PlainText, IV);
end;

function TAes.Encrypt(PlainText: string; IV: TArray<Byte>): TArray<Byte>;
var
  AES: TCipher_AES;
  Res: TArray<Byte>;
begin
  try
    AES := TCipher_AES.Create;
    try
      AES.Mode := cmCBCx;
      AES.Init(FAesKeyReader.GetAesKey, IV);
      Res := AES.EncodeStringToBytes(PlainText);
      SetLength(Result, Length(Res) + Length(IV));
      TArray.Copy<Byte>(IV, Result, 0, 0, Length(IV));
      TArray.Copy<Byte>(Res, Result, 0, Length(IV), Length(Res));
    finally
      AES.Free;
    end;
  except
    on e: Exception do begin
      Result := nil;
      TLogHelper.LogMessage('Error encrypting given string: %s', [e.Message], lcError, FLogger);
    end;
  end;
end;

end.
Die Funktion
Delphi-Quellcode:
FAesKeyReader.GetAesKey()
ruft nur den AES Key ab und lädt diesen von der Festplatte. Rückgabe ist in dem Fall auch ein
Delphi-Quellcode:
TArray<Byte>
.

Der aktuelle Testschlüssel mit dem ich verschlüssele sieht so aus (Byte Folge):
Delphi-Quellcode:
C9 58 F5 C6 26 1C A9 C6 3D 55 AE 1F AE A5 03 39 07 06 2E 8F 90 FF AA 13 2C 56 5E 32 3C 83 B3 48
.
Input ist das Wort
Delphi-Quellcode:
TestString
welches im Zwischenschritt vor dem Base64Encode Aufruf (also nur mit der AES Verschlüsselung) die folgende Byte-Folge zurückgibt:
Delphi-Quellcode:
F3 CA 54 23 0C DF 17 72 C1 94 5D 17 07 4F 8D 14 8A DF 7B 8C 71 D1 92 BD 4B 69 54 75 F1 A9 BF 2E 5B F0 66 E9
.
Der verwendete InitVector sieht so aus:
Delphi-Quellcode:
F3 CA 54 23 0C DF 17 72 C1 94 5D 17 07 4F 8D 14
.
Base64Encoded sieht das dann so aus:
Delphi-Quellcode:
88pUIwzfF3LBlF0XB0+NFIrfe4xx0ZK9S2lUdfGpvy5b8Gbp
.

Wenn ich den Base64 String nun wieder zurückwandele und das Ergebnis von
Delphi-Quellcode:
FAes.Decode()
zurück kommt, dann erhalte ich dieses Ergebnis:
Delphi-Quellcode:
'T'#0'e'#0's'#0't'#0'S'#0't'#0'r'#0'i'#0'n'#0'g'#0
.
Also den korrekten String nur eben mit #0 nach jedem einzelnen Char.

Der Aufruf der Methoden geschieht damit. Und hier vermute ich mein Problem und denke auch, dass das einfacher gehen müsste.
Delphi-Quellcode:
FAes
ist eine Instanz vom Typ
Delphi-Quellcode:
IAes
.

Delphi-Quellcode:
var
  s: string;
  Base64Decoded: TArray<Byte>;
  Result: string;

begin
  s := TEncoding.Default.GetString(TNetEncoding.Base64.Encode(FAes.Encrypt('TestString')));
  Base64Decoded := TNetEncoding.Base64.Decode(TEncoding.Default.GetBytes(s));
  Result := FAes.Decrypt(Base64Decoded);
end;

EdAdvokat 10. Feb 2021 17:40

AW: DEC6.0 Verständnisfrage AES Ver-/Entschlüsselung
 
Hallo Aviator,
nachdem TurboMagic einige Fehlerkorrekturen am DEC 6.0 vorgenommen hat, habe ich gleich mal mit dem letzten Stand des DEC (09.02.2021) etwas herumprobiert.
Damit ist es möglich, eine Klartextdatei mit AES zu verschlüsseln/entschlüsseln. Zugleich habe ich die verschiedenen Betriebsmodi integriert und auch einige Hash-Tools mit
gegeben. Einfach mal darüberschauen. Da Markus (TurobMagic) eine ähnliche Demo bereits erstellt hat, gehe ich davon aus, dass es auch im Sinne des "Schöpfers" ist.
Seine Intension für die Demo war zwar eher die Verwendung des Progress-Balkens.

EdAdvokat 10. Feb 2021 17:54

AW: DEC6.0 Verständnisfrage AES Ver-/Entschlüsselung
 
Liste der Anhänge anzeigen (Anzahl: 1)
irgendwas mit dem Hochladen der Datei hat nicht geklappt. Hier nochmals ein Versuch.

DieDolly 10. Feb 2021 18:06

AW: DEC6.0 Verständnisfrage AES Ver-/Entschlüsselung
 
Irgendwie sehr kompliziert diese Demo.
Ich verschlüssle gerade eine 25 GB große Datei und der visuelle Progress ist halt "nicht da".

EdAdvokat 10. Feb 2021 19:25

AW: DEC6.0 Verständnisfrage AES Ver-/Entschlüsselung
 
25 GB ist ja fast das gepackte deutsche Internet:)
Da wirft das Programm klar die Hufe hoch. Ich habe es ebenfalls probiert. Doch mit einer Datei 407 MB läuft die Sache wie die Polizei in die Häuser...:)
Was ist denn so kompliziert an dem Programm?

DieDolly 10. Feb 2021 20:31

AW: DEC6.0 Verständnisfrage AES Ver-/Entschlüsselung
 
Ich verstehe, wie man eine Datei reinlädt, sie ver- und entschlüsselt. Der Rest ist ein Geheimnis für mich.

TurboMagic 10. Feb 2021 20:41

AW: DEC6.0 Verständnisfrage AES Ver-/Entschlüsselung
 
Habe mir den Anhang noch nicht anschauen können, empfehle aber aus verschiedenen Gründen den Development Zweig zu nutzen.

Dort ist das mit dem Progress schon so umgebaut wie es mit V6.1 veröffentlicht werden wird. Sollte einfacher als das aus DEC 6.0 sein. Und ja ein einfaches Demo Programm ist da auch dabei.

Zu Base64: in der Format.pas ist da was passendes für drin...
Und Methoden die auf RawByte Strings arbeiten sind auch vorhanden, da sollte es auch keine Unicode String #0 Probleme geben.

EdAdvokat 10. Feb 2021 21:55

AW: DEC6.0 Verständnisfrage AES Ver-/Entschlüsselung
 
die in #3 hochgeladene Demo ist auf Basis der Version 6.1 von DEC (Develelopment-Zweig) erstellt worden. Hinsichtlich der Progress-Funktion habe ich mich für die 3. Variante "anonymous method as progress event" entschieden. Auch die anderen in der Demo von TurboMagic aufgeführten Varianten wären möglich.
Die Demo ist also auf dem neusten Stand des DEC 6.1.

Aviator 10. Feb 2021 22:20

AW: DEC6.0 Verständnisfrage AES Ver-/Entschlüsselung
 
Ich schaue mir die Format.pas morgen mal genauer an sofern ich die Zeit dazu finde. Danke schonmal für den Hinweis. Um das Verschlüsseln einer Datei geht es hier nicht im Geringsten sondern um das Verschlüsseln eines einzelnen Strings.

Rollo62 12. Feb 2021 09:01

AW: DEC6.0 Verständnisfrage AES Ver-/Entschlüsselung
 
Zitat:

Zitat von DieDolly (Beitrag 1482720)
Der Rest ist ein Geheimnis für mich.

Genau das ist ja der Sinn der Sache :-D


Alle Zeitangaben in WEZ +1. Es ist jetzt 04:32 Uhr.
Seite 1 von 3  1 23   

Powered by vBulletin® Copyright ©2000 - 2022, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf