Property eines TObjects setzen Frage

[KodeZwerg]

Hallo liebe Community,

kann man eine Property eines TObjects setzen ohne das die methode das TObject kennt?

Was ich vorhabe ist hoffentlich Verständlich und kurz genug erklärt, ohne das Ihr einschlaft beim Lesen ;)

Ich würde mir gerne eine Methode schreiben die eine TForm entgegen nimmt.

Delphi-Quellcode:

procedure SetProperties(const AForm: TForm);

Innerhalb der methode möchte ich alle vorhandenen Componenten durchiterieren um dann Properties zu wechseln.

Delphi-Quellcode:

var
  i: integer;
begin
  for i := 0 to Pred(AForm.ComponentCount) do
    if AForm.Components[i] is TPanel then
      TPanel(AForm.Components[i]).Caption := 'eine caption';
end;

Mein Problem ist, ich benötige für TPanel eine universelle TObject Lösung die testet ob es "Caption" gibt und sie dann setzt.
Gibt es dafür eine Lösung?

[DeddyH]

Meinst Du so etwas? https://www.delphipraxis.net/123356-...nsprechen.html

[KodeZwerg]

Danke DeddyH, ich denke das Dein letzter Post genau mein Ding ist um voran zu kommen!

Delphi-Quellcode:

function CompSetCaption(AClass : TObject; const Caption: string): Boolean;
const sProp = 'Caption';
var
  MyPropInfo: PPropInfo;
begin
  MyPropInfo := GetPropInfo(AClass.ClassInfo, sProp);
  Result := Assigned(MyPropInfo);
  if Result then
    SetPropValue(AClass, sProp, Caption);
end;

LG Kode

[stahli]

Generic hat gerade mal eine Anwendung mit den RTTI gezeigt: https://youtu.be/lpyo1TdPQZY

[KodeZwerg]

Zitat:

Zitat von stahli (Beitrag 1488961)

Generic hat gerade mal eine Anwendung mit den RTTI gezeigt: https://youtu.be/lpyo1TdPQZY

Hey stahli, vielen Dank für den Link, "coding BOTT" kannte ich noch nicht, wird sich nun ändern, super tutorials, echt empfehlenswert, mehr Werbung machen dafür :thumb:

[generic]

:thumb: Danke

Ihr könnt euch auch Themen wünschen. Mir fällt es manchmal schwer neue und interessante Themen zu finden.

[KodeZwerg]

@generic

Delphi-Quellcode:

procedure TfrmMain.SetObjectColors(AObject: TObject);
const
  sPropColor = 'Color';
  sPropFont = 'Font.Color';
var
  Context: TRttiContext;
  RType: TRttiType;
  Prop: TRttiProperty;
begin
  Context := TRttiContext.Create;
  RType := Context.GetType(AObject.ClassType);
  for Prop in RType.GetProperties do
    begin
      if Prop.Name = sPropColor then
          Prop.SetValue(AObject, FBackgroundColor);
      if Prop.Name = sPropFont then
          Prop.SetValue(AObject, FTextColor);
    end;
  Context.Free;
end;

Dank Deines Tutorials und weil es mir Spass macht rumzuprobieren, ist das entstanden, kA ob es Vorteile oder Nachteile gegenüber DeddyH sein code gibt, das war im Tutorial nicht erwähnt.

[Uwe Raabe]

Ich fürchte bei Font.Color wird es nicht funktionieren, denn das Property ist Font und der hat ein Property Color. Also sollte man nach Property Font suchen und sich die Font-Instanz holen, um dessen Color zu setzen.

[KodeZwerg]

Zitat:

Zitat von Uwe Raabe (Beitrag 1488988)

Ich fürchte bei Font.Color wird es nicht funktionieren, denn das Property ist Font und der hat ein Property Color. Also sollte man nach Property Font suchen und sich die Font-Instanz holen, um dessen Color zu setzen.

Es funktioniert bereits. Wenn mein Projekt fertig ist stelle ich es gerne vor.
Da Du der erfahrenere bist, werde ich meinen Code entsprechend ändern! Dankeschön für den Hinweis!!
Es handelt sich um OS-Theme integration.

[KodeZwerg]

Im Anhang ein paar Bilder vom jetzt-Zustanded des Projekts.

Das erste Bild verwendet von Windows das Dark/Light Theme.
Das zweite Bild verwendet die in Windows eingestellte Farbe.
Das dritte Bild verwendet einen durchschnittswert vom Wallpaper.
Das vierte Bild nutzt clBtnFace und clWindowText als Delphi-Vorgabe.

[TiGü]

Wenn du jetzt noch in denn Projektoptionen | Application | Manifest | Enable Runtime Themes aktivierst, sieht es nicht mehr so aus wie vor 15 Jahren.

[KodeZwerg]

Zitat:

Zitat von TiGü (Beitrag 1489011)

Wenn du jetzt noch in denn Projektoptionen | Application | Manifest | Enable Runtime Themes aktivierst, sieht es nicht mehr so aus wie vor 15 Jahren.

Da habe ich das Problem das dann die Font-Farbe bei manchen Objekten schwarz bleibt, siehe Anhang.

[venice2]

Zitat:

Zitat von KodeZwerg (Beitrag 1489015)

Zitat:

Zitat von TiGü (Beitrag 1489011)

Wenn du jetzt noch in denn Projektoptionen | Application | Manifest | Enable Runtime Themes aktivierst, sieht es nicht mehr so aus wie vor 15 Jahren.

Da habe ich das Problem das dann die Font-Farbe bei manchen Objekten schwarz bleibt, siehe Anhang.

Logisch!
Du hast im Thread (Windows 10+ Dark/Light in Application.)

Zitat:

Ich versuche gerade krampfhaft herauszufinden welchen TColor-Wert Windows für "Color" und "Font.Color" benutzt um diese in meine Anwendung zu übernehmen.

gefragt und machst den Fehler

Delphi-Quellcode:

Prop.SetValue(AObject, FTextColor);

Die Fontfarbe vom Control zu setzen.
Warum bitte schön verwendest du dann nicht auch GetImmersiveColorFromColorSetEx
Dafür ist es gedacht!

ImmersiveColor vom System für das jeweilige Control holen und diese Farbe setzen.
Siehe auch GetThemeSysColor und Konsorte.

tsss..

[KodeZwerg]

Zitat:

Zitat von venice2 (Beitrag 1489020)

Warum bitte schön verwendest du dann nicht auch GetImmersiveColorFromColorSetEx

Delphi-Quellcode:

procedure TfrmMain.ApplyThemedColors;
var
  i: Integer;
begin
  if IsDarkTheme then
    begin
      FBackgroundColor := FColorSet.Colors[ImmersiveApplicationBackgroundDarkTheme];
      FTextColor := FColorSet.Colors[ImmersiveApplicationTextDarkTheme];
    end
    else
    begin
      FBackgroundColor := FColorSet.Colors[ImmersiveApplicationBackgroundLightTheme];
      FTextColor := FColorSet.Colors[ImmersiveApplicationTextLightTheme];
    end;
  UpdateColors;
end;

Aber vielleicht verstehe ich Dich da gerade auch falsch, wäre nicht das erste mal ;)

[venice2]

Zitat:

procedure TfrmMain.ApplyThemedColors;

Hatte die nicht gesehen :)

Ok.. Habe das mal am Beispiel gescheckt da scheint noch einiges im argen zu sein mit der uImmersiveColors Unit.

EDIT:
Die Fontfarbe der RadioButton kann man nicht ändern ohne OwnerDrawn diese wird von Windows verwaltet.
Lösung: Kein Caption angeben und nen Label dahinter setzen. (Oder selber zeichnen)

[KodeZwerg]

Ich mach neuen Thread auf und poste mein schändliches werk, dann kann jeder mit rumspielen und liebend gerne Verbesserungen äußern. Klingt das fair?
Weil sobald ich das manifest theme aktiviere sind ja die externen api commoncontrols an der reihe und pfeifen auf alles was ich einstelle.

Warte bitte noch ein paar minuten, ich hab noch was hinzugefügt was den font betrifft.

[KodeZwerg]

Zitat:

Zitat von Uwe Raabe (Beitrag 1488988)

Ich fürchte bei Font.Color wird es nicht funktionieren, denn das Property ist Font und der hat ein Property Color. Also sollte man nach Property Font suchen und sich die Font-Instanz holen, um dessen Color zu setzen.

Guten Morgen!

Ich bin gerade am aufräumen meines Codes und wollte nun Deinen Vorschlag richtig umsetzen, zur Sicherheit Frage ich nochmal nach ob ich es so anwende wie Du es meintest.

Delphi-Quellcode:

procedure TfrmMain.SetObjectColors(AObject: TObject);
const
  sPropColor = 'Color';
  sPropFont = 'Font';
var
  Context: TRttiContext;
  RType: TRttiType;
  Prop: TRttiProperty;
  Fields: TRttiField;
begin
  Context := TRttiContext.Create;
  RType := Context.GetType(AObject.ClassType);
  for Prop in RType.GetProperties do
  begin
    if Prop.Name = sPropColor then
      Prop.SetValue(AObject, FColorBackground);
    if Prop.Name = sPropFont then
      for Fields in RType.GetFields do
        if Fields.Name = SPropColor then
          Fields.SetValue(AObject, FColorText);
  end;
  Context.Free;
end;

[Uwe Raabe]

Eventuell eher so:

Delphi-Quellcode:

  for Prop in RType.GetProperties do
  begin
    if Prop.Name = sPropColor then
      Prop.SetValue(AObject, FColorBackground);
    if Prop.PropertyType.IsInstance and Prop.PropertyType.AsInstance.MetaclassType.InheritsFrom(TFont) and (Prop.Name = sPropFont) then 
      TFont(prop.GetValue(AObject).AsObject).Color := FColorText;
  end;

[KodeZwerg]

Zitat:

Zitat von Uwe Raabe (Beitrag 1489368)

Eventuell eher so...

Das übernehme ich gerne so wie Du es geschrieben hast.
Vielen Dank Uwe! :thumb:

//edit
Noch eine Frage, wäre

Delphi-Quellcode:

    if (Prop.Name = sPropFont) and Prop.PropertyType.IsInstance and Prop.PropertyType.AsInstance.MetaclassType.InheritsFrom(TFont) then
      TFont(prop.GetValue(AObject).AsObject).Color := FColorText;

nicht sinnvoller um gleich am Anfang unnützes auszuschließen?

[Uwe Raabe]

Kann man machen, ja.

[himitsu]

Wenn man es nicht milliarden Mal ausführt, ist es praktisch egal.

Die meisten Property sind keine Klassen und die Typ-/Instanzprüfung (Enum vergleichen und dann Pointer) ist einen Hauch schneller, als einen String zu prüfen (nil-Test, Zeiger dereferenzieren und dann noch zeichenweise Prüfen oder Länge auslesen/vergleichen und eventuell noch byteweise wenn gleichlang).