Delphi-PRAXiS

Delphi-PRAXiS (https://www.delphipraxis.net/forum.php)
-   GUI-Design mit VCL / FireMonkey / Common Controls (https://www.delphipraxis.net/18-gui-design-mit-vcl-firemonkey-common-controls/)
-   -   TEdit beim überschreiten von MaxLength etwas auslösen (https://www.delphipraxis.net/208312-tedit-beim-ueberschreiten-von-maxlength-etwas-ausloesen.html)

Marco Steinebach 13. Jul 2021 14:25

TEdit beim überschreiten von MaxLength etwas auslösen
 
Hallo zusammen,
Setzt man maxLength für ein TEdit kann man, bekanntermaßen ;-), nur maxLength Zeichen eingeben. Versucht man eines mehr einzugeben, ertönt, sofern aktiviert, der passende Windows Beep.
Soweit, so schön.
Was kann ich tun, damit nicht der Windows Beep ausgelöst wird, sondern eine andere Methode?
Das onChanged-Event wird, überschreitet man maxLength, gar nicht erst ausgelöst, sonst hätte ich es dort machen können.

Für Hilfe wäre ich sehr dankbar.
Herzliche Grüße
Wandogau (Moo)

himitsu 13. Jul 2021 14:48

AW: TEdit beim überschreiten von MaxLength etwas auslösen
 
OnKeyUp/OnKeyDown/OnKeyPress?

Und wenn das Char nicht "weitergereicht" werden soll, damit die DefaultProc von Windows nicht piept, dann einfach Key auf 0 setzen.

Uwe Raabe 13. Jul 2021 14:59

AW: TEdit beim überschreiten von MaxLength etwas auslösen
 
Das verhindert zwar nicht den Beep, aber man bekommt es wenigstens mit:
Delphi-Quellcode:
type
  TEdit = class(Vcl.StdCtrls.TEdit)
  private
    procedure CNCommand(var Message: TWMCommand); message CN_COMMAND;
  end;
...
procedure TEdit.CNCommand(var Message: TWMCommand);
begin
  if (Message.NotifyCode = EN_MAXTEXT) then
    ShowMessage('Nee, nee, nee!')
  else
    inherited;
end;

Marco Steinebach 13. Jul 2021 17:14

AW: TEdit beim überschreiten von MaxLength etwas auslösen
 
Hallo,
und ganz herzlichen Dank für eure Antworten.
Wer's mal braucht, bei mir läuft es so:
Code:
constructor TMSEdit.create (aOwner: TComponent);
begin
  inherited create (aOwner);
  fToMuchCharacters := false; // private variable
end;

procedure TMSEdit.keyDown (var key: word; shift: TShiftState);
begin
  // erhält das Edit den Focus, und ist etwas selektiert, muss das, vorher, gelöscht werden...
  if self.selLength > 0 then
  begin
    inherited keyDown (key, shift);
    exit;
  end;
  if (self.maxLength > 0) and
     (shift = []) and
     (not (key in [vk_back, vk_delete, vk_return, vk_left, vk_right, vk_home, vk_end, vk_tab])) and
     (length (self.text) = self.maxLength) and
     assigned (onReachMaxLength) then
  begin
    onReachMaxLength (self, 's_Stop');
    fToMuchCharacters := true;
  end;
  inherited keyDown (key, shift);
end;

procedure TMSEdit.keyPress (var key: char);
// die wird gebraucht, damit es nicht piept. ;-)
begin
  if fToMuchCharacters then
  begin
    fToMuchCharacters := false;
    key := #0;
  end;
  inherited keyPress (key);
end;
Herzlich grüßt
Wandogau

himitsu 13. Jul 2021 17:22

AW: TEdit beim überschreiten von MaxLength etwas auslösen
 
Ableiten ist garnicht nötig.

OK, in der grauenhaft automatisch übersetzen deutschen MSDN-Variante, kann man es nicht wirklich lesen, aber
Zitat:

The parent window of the edit control receives this notification code through a WM_COMMAND message.
Delphi-Quellcode:
type
  TForm2 = class(TForm)
  protected
    procedure WndProc(var Message: TMessage); override;

    // oder eben auch via WM_COMMAND bzw. CN_COMMAND
    //procedure WMCommand(var Message: TWMCommand); message WM_COMMAND;
  end;

procedure TForm2.WndProc(var Message: TMessage);
begin
  if (Message.Msg = WM_COMMAND) and (TWMCommand(Message).NotifyCode = EN_MAXTEXT) then
    Beep; // TEdit(LParam)
  inherited;
end;
Da der BEEP erst nach der Notification kommt, hätte man vielleicht denken können, dass es doch eine Möglichkeit zum Unterdrücken gäbe.

Allerdings hilft das Result leider nicht, wie z.B.
Delphi-Quellcode:
Message.Result := 1;
,
und auch ein Delphi-Referenz durchsuchenAbort kann nicht helfen, da die VCL es vorher mit einem try-except abfängt, bevor der DefaultCode der Komponente es anschließend piepsen lässt.

Bei NonVCL könnte man vielleicht das DefWindowProc bzw. DispatchMessage einfach weglassen (ungetestet),
aber sowas ist in der VCL leider nicht möglich, also hier gäbe es nur Msg.Result, um mit Windows zu reden,
und ein
Delphi-Quellcode:
Message.Msg := WM_NULL;
geht sowieso nicht.



Fazit: Es bleibt bloß noch den Tastendruck abzubrechen, bevor es zu lang wird. (Copy&Paste oder WM_SETTEXT erstmal ignoriert)


Alle Zeitangaben in WEZ +1. Es ist jetzt 22:11 Uhr.

Powered by vBulletin® Copyright ©2000 - 2022, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf