Text (Strings) Zeilenumbrüche einfügen aufgrund von Satzzeichen.!?

[gee21]

Hallo alle zusammen.


Ich habe längere Texte wo ich automatisch Zeilen Umbrüche einfügen möchte.
Es funktioniert zwar schon +/- so wie ich das will aber ich weiss nicht wie ich es machen kann dass mehrere Zeichen (also nicht nur der "." sondern auch "!?" gleichzeitig beachtet werden.

Habe es so versucht aber das geht nicht:

Delphi-Quellcode:

Pos1 := Pos('.'or'!'or'?', stextformatierung);

Beispiel Text

1111111.
22222!
ERSTER UMBRUCH SOLL nach 2 "Sonderzeichen" HIER REIN <--
333333?
44444.
55555!
ZWEITER UMBRUCH SOLL nach weiteren 3 "Sonderzeichen" HIER REIN <--
6666.
7777.
8888?
Dritter UMBRUCH SOLL nach weiteren 3 "Sonderzeichen" HIER REIN <--
usw
usw

Im Moment mache ich das so:

Delphi-Quellcode:

procedure TForm1.Timer1Timer(Sender: TObject);
var
s,ZahlResultat: string;
pos1, zahllänge, pos2, pos3, pos4, pos5, pos6, pos7,pos8,pos9, pos10, pos11, pos12,i: integer;
Anzahl  :  Integer;
begin
 memo1.Clear;
 memo1.PasteFromClipboard;

  if form1.Memo1.GetTextLen>250 then begin
     // Text formatierung abschnitt
      pos1:=-1;
      pos2:=-1;
      pos3:=-1;
      pos4:=-1;
      pos5:=-1;
      pos6:=-1;
      pos7:=-1;
      pos8:=-1;
      pos9:=-1;
      pos10:=-1;
      pos11:=-1;
      pos12:=-1;

      //Damit es nicht das resultat wieder und wieder formatiert.
      if memo1.Text=stextformatierung then abort;

      stextformatierung:=memo1.Text;

      //2 Sätze für den Anfang
      Pos1 := Pos('.', stextformatierung);
      if Pos1 <> 0 then begin
      Pos2 := PosEx('.', stextformatierung, Pos1 + 1);
      end;
      if Pos2 <> 0 then begin
      Insert(#13#10+#13#10, stextformatierung, pos2+2)
      end;

      //3 Sätze
      pos4 := PosEx('.', stextformatierung, Pos2 + 1);
      if Pos4 <> 0 then begin
      Pos5 := PosEx('.', stextformatierung, Pos4 + 1);
      end;
      pos5 := PosEx('.', stextformatierung, Pos4 + 1);
      if Pos5 <> 0 then begin
      Pos6 := PosEx('.', stextformatierung, Pos5 + 1);
      end;
      if Pos5 <> 0 then begin
      Insert(#13#10+#13#10, stextformatierung, pos6+2)
      end;

      //3 Sätze
      pos7 := PosEx('.', stextformatierung, Pos6 + 1);
      if Pos7 <> 0 then begin
      Pos8 := PosEx('.', stextformatierung, Pos7 + 1);
      end;
      pos8 := PosEx('.', stextformatierung, Pos7 + 1);
      if Pos8 <> 0 then begin
      Pos9 := PosEx('.', stextformatierung, Pos8 + 1);
      end;
      if Pos8 <> 0 then begin
      Insert(#13#10+#13#10, stextformatierung, pos9+2)
      end;

      //3 Sätze
      pos10 := PosEx('.', stextformatierung, Pos9 + 1);
      if Pos10 <> 0 then begin
      Pos11 := PosEx('.', stextformatierung, Pos10 + 1);
      end;
      pos11 := PosEx('.', stextformatierung, Pos10 + 1);
      if Pos11 <> 0 then begin
      Pos12 := PosEx('.', stextformatierung, Pos11 + 1);
      end;
      if Pos11 <> 0 then begin
      Insert(#13#10+#13#10, stextformatierung, pos12+2)
      end;

     Clipboard.AsText := stextformatierung;
     TrayIcon1.BalloonHint := 'TEXT Formatierung';
     TrayIcon1.ShowBalloonHint;

  end;
end;

Gruss Robert

[Jumpy]

Warum gehst du nicht einfach den Text von vorne bis hinten durch und zählst mit einem Counter die anzahl sonderzeichen:

Delphi-Quellcode:

var i,cnt,max:integer;
    s:string;
//
cnt:=0;
max:=2;
s:='';
for i:=1 to length(text)
  begin
  s:=s+text[i]; 
  if (text[i]='.') or (text[i]='!') or (text[i]='?') then
    begin
    Inc(cnt);
    if cnt=max then
      begin
      s:=s+CHR(13)+CHR(10);
      if (max=2) then max:=3;
      cnt:=0;
      end;
    end
  end
//
  Result:=s;

[gee21]

:-)

Vielen Dank. Genau sowas habe ich versucht zu machen. :-D

[Neutral General]

Kleine Verbesserungsvorschläge für Jumpys Code, aber grundsätzlich ist sein Ansatz die beste Variante (die mir grad einfällt)

Delphi-Quellcode:

function SplitText(AText: String): TStrings;
var i: Integer;
    line: String;
    specialCharCount: Integer;
begin
  Result := TStringList.Create;

  line := '';
  specialCharCount := 2;
  for i:= 1 to Length(AText) do
  begin
    line := line + AText[i];
    if CharInSet(AText[i], ['!', '.', '?']) then
      dec(specialCharCount);
    
    if (specialCharCount = 0) then
    begin
      Result.Add(line);
      line := '';
      specialCharCount := 3; 
    end;
  end;

  // Rest als eine Zeile hinzufügen
  if (line <> '') then
    Result.Add(line);
end;

Edit: Runterzählen von "specialCharCount" erspart einem eine Max Variable. Danke an Blup :thumb:

[Blup]

Ein Objekt sollte möglichst immer auf der Ebene freigegeben werden, auf der es auch erzeugt wurde.
Deshalb halte ich das Erzeugen einer TStringList als Rückgabewert hier nicht für sinnvoll.

Man kann den Zähler auch gegen Null zählen lassen und spart so eine Variable.

Delphi-Quellcode:

function SplitText(AText: string): string;
const
  CRLF = #13#10;
var
  C: Char;
  Counter: Integer;
begin
  Result := '';
  Counter := 2;
  for C in AText do
  begin
    Result := Result + C;
    if CharInSet(C, ['!', '.', '?']) then
      Dec(Counter);
    
    if Counter = 0 then
    begin
      Result := Result + CRLF;
      Counter := 3;
    end;
  end;
end;

[Neutral General]

Mit dem Runterzählen hast du Recht. Das ist auf jeden Fall besser/einfacher.
Das Erzeugen einer Stringlist finde ich nicht problematisch. Bei jedem .Create ist es quasi das gleiche.
Es ist halt eine Art überladener constructor für TStringList. Aber ist Geschmackssache.

Ein Hinweis aber: Es gibt die Konstante sLinebreak, die sogar platformunabhängig ist und da brauchst du keine eigene CRLF-Konstante.