Delphi-PRAXiS
Seite 1 von 2  1 2      

Delphi-PRAXiS (https://www.delphipraxis.net/forum.php)
-   Algorithmen, Datenstrukturen und Klassendesign (https://www.delphipraxis.net/78-algorithmen-datenstrukturen-und-klassendesign/)
-   -   Generisch Maximum bestimmen (https://www.delphipraxis.net/212807-generisch-maximum-bestimmen.html)

freimatz 4. Apr 2023 16:00

Generisch Maximum bestimmen
 
Hallo,
wir haben immer wieder die Aufgabe ein Minimum oder Maximum zu bestimmen von einer Menge von Elementen in einem Container (TList<>, IList<>, TArray<>, etc.). Das ist keine grosse Sache - Schleife darüber, vorher Grenzwert festlegen und vergleichen.

Allerdings kam hier die Frage auf, ob man das nicht generisch lösen könnte.
Gefunden habe ich
etwas, das hilft aber nicht weiter.
Jemand meinte mit C# würde das gehen. Dort gäbe es eine Max function. Die Klasse müsste IEnumerable implementieren.

Die IList<T> von Spring4D hat eine Max function. Hat mir jemand ein Beispiel dazu?
Oder sonst irgendwelche Ideen oder Meinungen?

dummzeuch 4. Apr 2023 16:21

AW: Generisch Maximum bestimmen
 
Zitat:

Zitat von freimatz (Beitrag 1520665)
Jemand meinte mit C# würde das gehen. Dort gäbe es eine Max function. Die Klasse müsste IEnumerable implementieren.

Muss die Klasse dazu nicht auch irgendwie einen Wert liefern?

Aber sonst: Klar sollte das per Generics gehen.

for-Schleife via IEnumerable, für jedes Objekt den Wert ermitteln und dann vergleichen.

Das geht sogar ohne Compiler-Unterstützung für Generics, es reicht eine TInterfaceList und darin gespeicherte Interfaces, die den Wert liefern.

Uwe Raabe 4. Apr 2023 17:05

AW: Generisch Maximum bestimmen
 
Meinst du in etwa so? (Müsste man aber noch ausbauen)
Delphi-Quellcode:
type
  TGeneric = record
  public
    class function Max<T>(List: TEnumerable<T>): T; static;
  end;

class function TGeneric.Max<T>(List: TEnumerable<T>): T;
begin
  var comparer := IComparer<T>(TComparer<T>._Default);
  Result := Default(T);
  for var item in List do
    if comparer.Compare(Result, item) < 0 then
      Result := item;
end;

mytbo 4. Apr 2023 18:30

AW: Generisch Maximum bestimmen
 
Zitat:

Zitat von freimatz (Beitrag 1520665)
Die IList<T> von Spring4D hat eine Max function. Hat mir jemand ein Beispiel dazu?

Delphi-Quellcode:
uses
  Spring.Collections;

var
  list: IList<Integer>;
begin
  list := TCollections.CreateList<Integer>;
  list.Add(1);
  list.Add(5);
  list.Add(3);
  ShowMessage(Format('%d, %d, %d, Max: %d',[list[0], list[1], list[2], list.Max]));
oder so:
Delphi-Quellcode:
var
  list: IList<Integer>;
begin
  list := TCollections.CreateList<Integer>([1, 5, 3]);
  ShowMessage(Format('%d, %d, %d, Max: %d',[list[0], list[1], list[2], list.Max]));
Bis bald...
Thomas

Stevie 4. Apr 2023 22:41

AW: Generisch Maximum bestimmen
 
Zitat:

Zitat von Uwe Raabe (Beitrag 1520667)
Meinst du in etwa so? (Müsste man aber noch ausbauen)
Delphi-Quellcode:
type
  TGeneric = record
  public
    class function Max<T>(List: TEnumerable<T>): T; static;
  end;

class function TGeneric.Max<T>(List: TEnumerable<T>): T;
begin
  var comparer := IComparer<T>(TComparer<T>._Default);
  Result := Default(T);
  for var item in List do
    if comparer.Compare(Result, item) < 0 then
      Result := item;
end;

Da ist nen kleiner aber subtiler Bug drin: wenn dein TEnumerable<T> die Zahlen -1, -3 und -7 enthält, dann würde es inkorrekterweise 0 als Max ausgeben und nicht -1.
Result muss mit dem ersten Wert aus der Sequenz initialisiert werden und ab da muss verglichen werden. Außerdem brauchts ein Verhalten, wenn die Sequenz leer ist (in Spring gibt's genau wie in .NET ne Exception)

Uwe Raabe 5. Apr 2023 00:23

AW: Generisch Maximum bestimmen
 
Zitat:

Zitat von Stevie (Beitrag 1520680)
Da ist nen kleiner aber subtiler Bug drin:

Ich weiß - deswegen mein Hinweis mit dem ausbauen. Es ging mir im Wesentlichen erstmal um die Syntax.

Eine andere Tretmine: was wenn für <T> kein Default-Comparer existiert?

freimatz 5. Apr 2023 07:08

AW: Generisch Maximum bestimmen
 
Sorry, das ist keine Tretmine, sondern der Normalfall bei uns.
Tut mir leid hätte ich vielleicht gleich am Anfang noch dazu schreiben sollen. Bei "Menge von Elementen" handelt es sich nicht nur um Integer sondern Records, Klassen, etc. z.B. einem record von einem Abstand: Double und einem vector.
Müsste dann der Record einen IComparer implementerien? Oder die Liste. Habt ihr mir da auch ein Beispiel dazu? Basierend auf Spring4D reicht mir mal vorläufig.

Uwe Raabe 5. Apr 2023 08:29

AW: Generisch Maximum bestimmen
 
Wie bei anderen Lösungen auch, muss der Comparer dann in irgendeiner Form bereitgestellt werden. Das kann durch einen zusätzlichen Parameter geschehen oder durch eine Art Registrierung zu den verschiedenen Typen.

Stevie 5. Apr 2023 09:33

AW: Generisch Maximum bestimmen
 
Zitat:

Zitat von Uwe Raabe (Beitrag 1520682)
was wenn für <T> kein Default-Comparer existiert?

Es existiert immer einer (bzw wird erstellt) - ob ein binary compare eines records Sinn ergibt, ist dann eine andere Geschichte.

In Spring 2.0 bin ich einen Schritt (oder mehrere) weiter gegangen als die RTL, indem ich die Möglichkeit gegeben habe, einen Default Comparer zu registrieren (siehe unit Spring.Comparers).

Übrigens bieten alle Methoden der Spring Collections, die irgendwas mit comparern machen, immer einen Overload an, in den man einen comparer oder eine comparison übergeben kann, sollte man das nicht bei der Erstellung der Liste z.B. schon getan haben.

Delphi-Quellcode:
function CompareMyRecord(const left, right: TMyRecord): Integer;
begin
  // Vergleichslogik
end;

var
  list: IList<TMyRecord>;
  maxRec: TMyRecord;
begin
  ...
  maxRec := list.Max(CompareMyRecord);

mytbo 5. Apr 2023 17:44

AW: Generisch Maximum bestimmen
 
Zitat:

Zitat von freimatz (Beitrag 1520683)
Müsste dann der Record einen IComparer implementerien? Oder die Liste. Habt ihr mir da auch ein Beispiel dazu? Basierend auf Spring4D reicht mir mal vorläufig.

Zur Veranschaulichung der Fälle. Kombination ist möglich. Beispiel für TComparison<T>:
Delphi-Quellcode:
type
  TRec = record
    x, y: Integer;
  end;

function CompareRecY(const pmcLeft, pmcRight: TRec): Integer;
begin
  Result := (pmcLeft.y - pmcRight.y);
end;

const
  RECS: array[0..2] of TRec = ((x: 1; y: 4), (x: 5; y: 6), (x: 3; y: 2));
var
  list: IList<TRec>;
begin
  list := TCollections.CreateList<TRec>(RECS);
  list.Sort(CompareRecY);
  ShowMessage(Format('First Y: %d, Max Y: %d',[list[0].y, list.Max(CompareRecY).y]));
end;
Beispiel für IComparer<T>:
Delphi-Quellcode:
type
  TData = class
  private
    FX, FY: Integer;
  public
    constructor Create(pmX, pmY: Integer);
    property X: Integer
      read FX;
    property Y: Integer
      read FY;
  end;

  TDataYComparer<T: TData> = class(TComparer<T>)
  public
    function Compare(const pmcLeft, pmcRight: T): Integer; override;
  end;

constructor TData.Create(pmX, pmY: Integer);
begin
  inherited Create;
  FX := pmX;
  FY := pmY;
end;

function TDataYComparer<T>.Compare(const pmcLeft, pmcRight: T): Integer;
begin
  Result := (T(pmcLeft).Y - T(pmcRight).Y);
end;

var
  list: IList<TData>;
  comp: IComparer<TData>;
begin
  comp := TDataYComparer<TData>.Create;
  list := TCollections.CreateObjectList<TData>(comp, True);
  list.Add(TData.Create(1, 4));
  list.Add(TData.Create(5, 6));
  list.Add(TData.Create(3, 2));
  list.Sort;
  ShowMessage(Format('First Y: %d, Max Y: %d',[list[0].Y, list.Max.Y]));
end;
Bis bald...
Thomas


Alle Zeitangaben in WEZ +1. Es ist jetzt 00:37 Uhr.
Seite 1 von 2  1 2      

Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz