Alle Child-Komponenten deaktivieren

[barnti]

Hallo,
wie kann ich alle enthaltenen Komponenten einer GroupBox deaktivieren? So in der Art:

Delphi-Quellcode:

GroupBox.ChildControls.enable:= false;

oder so ähnlich!?

Danke!

[Luckie]

Das geht leider nicht:

Delphi-Quellcode:

Groupbox1.Enabled := False;

Also entweder einzeln oder über FindComponent.

[barnti]

Hallo Luckie,
das hatte ich vermutet. Schade! Dann einzeln. Danke dir!

[sakura]

Imho sind die automatisch mit der Groupbox deaktiviert, nur leider stellen die sich nicht als deaktiviert dar :?

...:cat:...

[Luckie]

Zitat:

Zitat von sakura

Imho sind die automatisch mit der Groupbox deaktiviert, nur leider stellen die sich nicht als deaktiviert dar :?

...:cat:...

Das habe ich jetzt nicht ausprobiert.

...

Jetzt habe ich es und es stimmt. Das ganze auf ein Panel legen bringt auch nichts.

[sakura]

Zitat:

Zitat von Luckie

Das ganze auf ein Panel legen bringt auch nichts.

Stimmt, aber auf D3K habe ich mal eine Lösung daüfr bereit gestellt.

Hier der Code

Delphi-Quellcode:

unit uRealPanel; 

interface 

uses 
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs, 
  ExtCtrls; 

type 
  TRealPanel = class(TPanel) 
  private 
  protected 
    procedure SetEnabled(Value: Boolean); override; 
  end; 

procedure Register; 

implementation 

procedure Register; 
begin 
  RegisterComponents('gate(n)etwork', [TRealPanel]); 
end; 

{ TRealPanel } 

procedure TRealPanel.SetEnabled(Value: Boolean); 
var 
  I: Integer; 
begin 
  inherited; 
  if csDesigning in ComponentState then 
    Exit; 
  for I := 0 to Pred(ControlCount) do 
    if Controls[I] is TWinControl then 
      (Controls[I] as TWinControl).Enabled := Value; 
end; 

end.

Alles weitere auf der Seite: http://www.delphi3000.com/articles/article_2962.asp

...:cat:...

[choose]

Hallo barnti,

bei der TGroupBox handelt es sich um einen Erben von TWinControl, der über die Eigenschaften Controls und ControlCount die ihm untergeordneten Elemente veröffentlicht.

Du könntest, um Dein Problem zu lösen, über alle untergeordneten Element iterieren und für diese jeweils die Eigenschaften setzen. Solltest Du jedoch mehrere solcher Boxen (zB auch Panels) inneinander verschachteln, könnte ein rekursiver Ansatz weiterhelfen.

Die folgende Prozedure demonstriert, was ich meine (und sollte ggf an Deine Bedürfnisse weiter angepasst werden):

Delphi-Quellcode:

procedure SetEnabledRecursivly(AControl: TControl; AEnabled: Boolean);
var
  iChild: Integer;
begin
  // set state of control
  AControl.Enabled := AEnabled;

  // if control contains further controls...
  if (AControl is TWinControl) then
    with TWinControl(AControl) do
    // ...set state for each child (recursive)
    for iChild := 0 to Pred(ControlCount) do
      SetEnabledRecursivly(Controls[iChild], AEnabled);
end;

mit einem Aufruf der Art:

Delphi-Quellcode:

SetEnabledRecursivly(GroupBox1, False);

EDIT: Ups, etwas zu langsam ;)

[barnti]

Hallo ihr alle,

ich habe die ganze Box deaktiviert. Wie schon erwähnt stellen sich die beinhalteten Komponenten aber nicht deaktiviert da.
Ich werde mir mal überlegen wie ich das löse oder ob das so ok ist...
Danke an alle!