Form immer innerhalb vom bildschirm rand

[ArmyMan]

Wie kann ich machen dass mein programm immer im bildschirm rand bleibt. Sowie Pinnacle PCTV falls jemand dass kennt.

Thx ArmyMan

[DP-Maintenance]

Dieses Thema wurde von "Sharky" von "Neuen Beitrag zur Code-Library hinzufügen" nach "VCL-Komponenten und Controls" verschoben.
Ist kein Beitrag zur CodeLib sondern eine Frage ;-)

[ArmyMan]

Kann mir jemand helfen? Ich habe gesucht aber nichts gefunden. Wäre froh wenn jemand helfen kann.

Thx ArmyMan

[Chris1986]

Hi.
vergleich doch einfach die Größe deiner Form mit der Größe des "Screens"

Gruß
Christian

[nailor]

das form kann ja auch kleiner sein, es soll nur nicht rausgucken. eventuell kannst du ja schaun ob

left < 0
left + widht > screen.widht
top < 0
top + height > screen.height

[NicoDE]

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TWmMoving = record
    uMsg  : UINT;
    wParam: WPARAM;
    lParam: ^TRect;
    Result: HRESULT;
  end;

type
  TForm1 = class(TForm)
  private
    { Private declarations }
  public
    { Public declarations }
    procedure WmMoving(var Message: TWmMoving); message WM_MOVING;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.WmMoving(var Message: TWmMoving);
var
  WorkArea: TRect;
begin
  inherited;
  if SystemParametersInfo(SPI_GETWORKAREA, 0, @WorkArea, 0) then
    with Message do
    begin
      if lParam.Right > WorkArea.Right then
        OffsetRect(lParam^, WorkArea.Right - lParam.Right, 0);
      if lParam.Left < WorkArea.Left then
        OffsetRect(lParam^, WorkArea.Left - lParam.Left, 0);
      if lParam.Bottom > WorkArea.Bottom then
        OffsetRect(lParam^, 0, WorkArea.Bottom - lParam.Bottom);
      if lParam.Top < WorkArea.Top then
        OffsetRect(lParam^, 0, WorkArea.Top - lParam.Top);
      Result := HRESULT(True);
    end;
end;

end.

[ArmyMan]

Perfect! Super!

Genau das ist was ich brauchte.

Thx a lot :-)

ArmyMan