Mal wieder probleme mit der registry

[glkgereon]

hi
also ich will per TRegistry werte aus der registry auslesen

doch irgendwie sind meine variablen leer, bzw der text im edit ist vergleichsweise leer (das os zieh ich mir vorher schon anders...)

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
var
reg: TRegistry;
begin
reg:=TRegistry.Create;
reg.OpenKeyReadOnly('HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion');
osname:=reg.ReadString('ProductName');
version:=reg.ReadString('CurrentVersion');
user:=reg.ReadString('RegisteredOwner');
org:=reg.ReadString('RegisteredOrganization');
Servicepack:=reg.ReadString('CSDVersion');
Edit1.Text:='OS: '+os+' - '+osname+' '+version+' +++ '+user+' - '+org+' +++ '+servicepack+' +++ ';
end;

is da ein denkfehler drin, oder falsch geproggt, oder warum funzt das nicht?

[Sharky]

Hai glkbkk,

Du musst noch den Root-Key angeben:

Delphi-Quellcode:

  .
  .
  reg.RootKey := HKEY_LOCAL_MACHINE;
  reg.OpenKeyReadOnly('SOFTWARE\Microsoft\Windows NT\CurrentVersion');
  .
  .

Dann sollte es eigentlich gehen.

[Christian Seehase]

Moin glkbkk,

da haben sich mehrere Fehler eingeschlichen. ;-)

1. Bei der Angabe des Keys gibt man nur den Subkey an, den Rootkey übergibt man in der Eigenschaft RootKey
2. Beim Öffnen des Keys fehlt die Abfrage, ob das erfolgreich war.
3. Das Registry Objekt wird nicht wieder freigegeben (try/finally)
4. Der Key wird nicht geschlossen (try/finally)

[MathiasSimmack]

Noch ein Problem. Unter 9x/ME stehen die Angaben nicht im "Windows NT"-Schlüssel. Sollte man, wie ich finde, erwähnen, auch wenn glkbkk das Programm erst mal nur für sein eigenes Betriebssystem schreibt.

[GuenterS]

Delphi-Quellcode:

procedure ReadInfoFromRegistry;
var
  lReg: TRegistry;
  lOSName, lVersion, lUser, lOrg, lServicePack: string;
begin
  lReg := TRegistry.Create(KEY_READ);
  try
    lReg.RootKey := HKEY_LOCAL_MACHINE;
    if (lReg.OpenKeyReadOnly('SOFTWARE\Microsoft\Windows NT\CurrentVersion')) then
    try
      lOSName := lReg.ReadString('ProductName');
      lVersion := lReg.ReadString('CurrentVersion');
      lUser := lReg.ReadString('RegisteredOwner');
      lOrg := lReg.ReadString('RegisteredOrganization');
      lServicepack := lReg.ReadString('CSDVersion');
    finally
      lReg.CloseKey;
    end;
  finally
    lReg.Free;
  end;
  Memo1.Lines.Add('OS: ' + lOSName + ' ' + lVersion + ' +++ ' + lUser + ' - ' + lOrg + ' +++ ' + lServicepack + ' +++ ');
end;

[Edit]Zu langsam[/Edit]

[glkgereon]

:wall: so vile fehler...

kann ich denn gucken wie der pfad nu heisst, ob Windows NT, oder ob stattdessen da ein Windows XP oder so hinmuss?
kann man das irgendwie nachgucken?

[GuenterS]

unter XP ist es ebenfalls Windows NT.

[glkgereon]

aba bei Windows 95/98 ja bestimmt nicht
wenns nur zwei versionen gibt, könnte man ja auch einfach das betriebssystem prüfen...
aber dann muss ichs fürn neues wieder umschreiben, falls denn ma wieda was kommt
und was is mit ME/2003?

[MathiasSimmack]

Unter 95/98/ME ist es nur "Windows" (logisch, oder? ;)). Der einfachste Weg wäre ein Bool-Array mit den beiden Strings. Abhängig von der ermittelten Plattform (Delphi-Bordmittel oder API) benutzt du einen davon und greifst automatisch auf den richtigen Schlüssel zu.

Schlecht erklärt, ich geb´s zu, aber so lässt es sich ohne viel Aufwand machen.

[glkgereon]

habs schon verstanden :-D

thx