Quicksort logik Problem

[firespawn]

Hallo,
also ich habe ein Problem mit Quicksort, ich habe in meinem Delphibuch einen Quellcode doch der macht einfach keinen Sinn.

Also ich habe ein Array, dieses wird nun mit Zufallszahlen erschaffen (1.Button)

Der zweite Button soll nun das globale Array was zuvor gefüllt wurde sortieren. Doch in meinem Buch wird dafür extra eine Procedure geschrieben obwohl das nicht wirklich notwenig ist. Also ich möchte quicksort in einen Button einbauen. Leider komme ich nicht damit klar wie das mit der "Mitte" funktioniert denn hier steht in meinem Buch etwas von i:=l; und j:=r; eigentlich nicht notwenig also ich bin etwas verwirrt vielleicht kann das etwas besser erklärt werden. ich habe zwar schon einige tuts gelesen doch ohne erfolg da ich gern das verstehen möchte was ich schreibe.

Vielen Dank
Fire

[Matze]

Ich denke, die zufällige Zuweisung ist einfach ein Beispiel für ein gefülltes Array, das sortiert werden soll.

So könnte das am Ende aussehen, vielleicht verstehst du den Code, ansonsten frag nochmal nach:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Buttons;

type
  TArray = array[1..20] of integer;

type
  TForm1 = class(TForm)
    SpeedButton1: TSpeedButton;
    procedure FormCreate(Sender: TObject);
    procedure SpeedButton1Click(Sender: TObject);
  private
    { Private-Deklarationen }
    procedure FillArray(var Tab: TArray);

    procedure Swap(var Zahl1, Zahl2: integer);
    procedure QuickSort(var Tab: TArray; HighIndex: integer);
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;
  Tab: TArray;

implementation

{$R *.dfm}

procedure TForm1.FillArray(var Tab: TArray);
var i: integer;
begin
  for i := 1 to Length(Tab) do
    Tab[i] := random(101);  //0 - 100
end;

procedure TForm1.Swap(var Zahl1, Zahl2: integer);
var h: integer;
begin
  h := Zahl1;
  Zahl1 := Zahl2;
  Zahl2 := h;
end;

procedure TForm1.QuickSort(var Tab: TArray; HighIndex: integer);
  procedure Sort(links, rechts: integer);
  var i, j, x: integer;
  begin
    i := links;
    j := rechts;
    x := Tab[(links + rechts) div 2];
    repeat
      while Tab[i] < x do inc(i);
      while Tab[j] > x do dec(j);
      if i <= j then
      begin
        Swap(Tab[i], Tab[j]);
        inc(i);
        dec(j);
      end;
    until i > j;
    if links < j  then Sort(links, j);
    if i < rechts then Sort(i, rechts);
  end;
begin
  Sort(1, HighIndex);
end;

procedure TForm1.FormCreate(Sender: TObject);
var i: integer;
begin
  randomize;
  FillArray(Tab);;
end;

procedure TForm1.SpeedButton1Click(Sender: TObject);
var i: integer;
begin
  QuickSort(Tab, Length(Tab));
end;

end.

[czapie]

Quicksort ist ein rekursiver Algortihmus, das heißt der Algortihmus "startet" sich solange immer wieder selbst, bis das Ziel erreicht wurde. Und das macht sich beim Umsetzen nuneinmal in einer eigenen Funktion ganz gut.
Czapie.

[Sec]

Ich weiß ja nich was ich sagen soll, aber was ist ein Array´???

ich komm da grad voll nich klar mit^^

[r2c2]

Hallo :hi:
guck dir mal die Grundlagen an. Auch die Tutorials könnten dir helfen.

Und... ähm... warum gräbst du eigentlich n 2 1/2 Jahre alten Thread aus? Mach nächstes mal bitte einen eigenen auf. Dies gilt auch, wenn du jetzt noch Fragen zum Array hast. Zumal der Thread mit deinem Problem nu wirklich nix zu tun hat...

mfg

Christian