String aus Anwendung in Dll übergeben und zurück

[Armageddon]

Hallo,

ich habe folgendes vor. Schreibe gerade ein Programm und möchte nun einige functionen und proceduren in eine Dll auslagern. Das klappt soweit auch ganz gut nur steh ich jetzt wieder einmal vor einem Problem.

In der Anwendung direkt würde es so aussehen:

Delphi-Quellcode:

function test(Woher: TForm; Zeichen: String):String;
begin;
//Mach hier was und so wenn nicht kommt Fehler
  Application.MessageBox(Woher, 'blablalba', usw. usw.);
//Mach was mit Zeichen;
  Result := Zeichen;
end;

procedure TForm1.BitBtn2Click(Sender: TObject);
begin
  Edit2.Text := test(self, Edit1.Text);
end;

so mal aus dem Kopf heraus. Jetzt versuche ich schon seit Stunden das gleiche Ergebnis mit ner Dll hinzubekommen. Mein Problem liegt darin das ich es einfach nicht fertig bringe den Text vom Programm in die Dll zu übergeben und von dort wieder zurück an das Programm.

Weiß jemand ne einfache Möglichkeit ohne viel Code die einwandfrei funktioniert und verständlich nach zuvollziehen ist?

Bisher sehen meine Aufrufe bei den Dll's so aus:

Delphi-Quellcode:

type
  TEditKommaAusgang = procedure(Woher: TForm; Von: TEdit); stdcall;

procedure Fehler(Woher: TForm; Text: String);
begin
  MessageBox(Woher.Handle, PChar(Text), 'Fehler', MB_OK OR MB_ICONERROR);
  Application.Terminate;
end;

procedure EditKommaAusgang(Woher: TForm; Von: TEdit);
var
  EditKommaAusgang: TEditKommaAusgang;
  DllHandle: THandle;
begin
  if not FileExists('mtrcnc32.dll') then
  begin
    Fehler(Woher, 'Die Datei "mtrcnc32.dll" wurde nicht gefunden!');
  end;
  DllHandle := LoadLibrary(PChar(ExtractFilePath(ParamStr(0))+'mtrcnc32.dll'));
  if DllHandle <> 0 then
  begin
    @EditKommaAusgang := GetProcAddress(DllHandle, 'EditKommaAusgang');
    if @EditKommaAusgang <> nil then
    begin
      EditKommaAusgang(Woher, Von);
    end;
    FreeLibrary(DllHandle);
  end;
end;

Funktioniert alles wunderprächtig nur das mit dem String an Dll und wieder zurück will nicht klappen. Irgendwas mach ich wohl falsch. Und ja ich hab mir schon Tutorials angesehen und gegoogelt wie ein wilder aber ich komme auf keinen grünen Zweig. :wall:

Gruß Arma

[SirThornberry]

ganz oben im DLL-Quelltext steht ein Kommentar den du dir mal durchlesen solltest. Du musst die sharemem benutzen wenn du mit Strings arbeitest.

Die einfachere Variante wäre mit PChars zu arbeiten und anstelle der Funktion den PChar als Referenz übergeben. Dann kannst du ihn in der DLL bearbeiten und da er als Referenz übergeben wurde ist es im Hauptprog mit geändert. Aber wie schon geschrieben müsstest du dann pchar verwenden oder eben die sharemem (texte ganz oben im dll-quelltext)

[Armageddon]

Hi SirThornberry,

sharemem will ich wegen der mitgabe der borland.dll oda wie imma die wieder heisst nicht verwenden. Das mit den PChar hört sich da schon besser an. Könntest mir da mal ein kleines Beispiel geben? Bin für jede Hilfe dankbar. Glotz jetzt schon seit 8 Stunden auf den Monitor nur wegen der kleinen Lapalie. :spin2:

[SirThornberry]

weißt du schon vor funktionsaufruf wie groß der (Rückgabe)-"String" maximal werden kann?

[Armageddon]

Hmmm nicht genau. Da ich das was ich hier lerne, hoffe ich jedenfalls, auch später mal in anderer From einsetzen möchte kann es sein das der String mal länger oder mal kürzer werden kann als der Ausgangsstring. Das sollte man dann schon im Vorfeld mit berücksichtigen. Wird die ganze Sache jetzt schwieriger?

[SirThornberry]

wenn du nicht weiß wie groß der String werden soll solltest du das ganze so machen
Funktionen In Dll

Delphi-Quellcode:

function TestProc(SourceStr: PChar; var DestStr: PChar): Integer;
begin
  DestStr := StrAlloc(length(SourceStr) + 1);  //speicher für DestStr anfordern
  Move(SourceStr^, DestStr^, length(SourceStr) + 1); //inhalt von SourceStr nach DestStr kopieren
  //fals es keine binärdaten sind dann die abschließende #0 (Stringende)  
  DestStr[length(SourceStr)] := #0; //bei DestStr noch ein #0 anhängen
  //falls es doch binärdaten sind ist es besser die Länge zurück zu geben
  result := length(SourceStr);
end;

procedure FreeMemFromTestProc(AChars: PChar);
begin
  StrDispose(AChars);
end;

Hauptprogramm

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
var LDestStr: PChar;
begin
  TestProc('abcdef', LDestStr);
  //do something with LDestStr
  FreeMemFromTestProc(LDestStr);
end;

[Armageddon]

Hmmm, jo sieht kurz aus und erfüllt sicher auch den Zweck nur steig ich da noch nicht ganz durch. Muss ich mir mal nochmal anschauen wenn ich ausgeschlafen bin. Mit einem MemoryStream hab ich auch schon experimentiert aber das hat auch nicht so hingehauen wie ich gern wollte. Aber irgendwie muss es ja schliesslich gehen.

Könntest mir mit dem hier ein kleines Beispiel mit Datei machen und zum runterladen anhängen?

Das sollte in die Dll und bei bedarf dynamisch geladen werden:

Delphi-Quellcode:

procedure EditKommaAusgang(Zeichen:String; var Ergebnis: String); stdcall;
var
  T, VKT, HKT, B: String;
  MP, KP: Integer;
  VKTL, HKTL: Boolean;
begin
  VKTL := False;
  HKTL := False;
  T := Zeichen;
  if T = '.' then  T := '0.0';
  if T = '-' then T := '0.0';
  if T = '-.' then T := '0.0';
  if Pos('.', T) = 0 then T := T + '.';
  MP := Pos('-', T);
  KP := Pos('.', T);
  if KP > 0 then
  begin
    VKT := Copy(T, 1, KP - 1);
    if MP > 0 then VKT := Copy(VKT, 2, Length(VKT) - 1);
    HKT := Copy(T, KP + 1, Length(T) - KP);
//Vorkommatext Nullen kürzen
    B := Copy(VKT, 1, 1);
    while B = '0' do
    begin
      VKT := Copy(VKT, 2, Length(VKT) - 1);
      B := Copy(VKT, 1, 1);
      if Length(VKT) = 0 then VKTL := True;
    end;
//Hinterkommatext Nullen kürzen
    B := Copy(HKT, Length(HKT), 1);
    while B = '0' do
    begin
      HKT := Copy(HKT, 1, Length(HKT) - 1);
      B := Copy(HKT, Length(HKT), 1);
      if Length(HKT) = 0 then HKTL := True;
    end;
    T := '';
    if MP > 0 then T := '-';
    T := T + VKT + '.' + HKT;
  end;
  if T = '.' then if (VKTL = True) or (HKTL = True) then T := '0.0' else T := '';
  if T = '-.' then if (VKTL = True) or (HKTL = True) then T := '0.0' else T := '';
  Ergebnis := T;
end;

Und das hier ist im Programm:

Delphi-Quellcode:

procedure TForm1.Vorschau();
var
  V510: String;
begin
  EditKommaAusgang('00123.6329000', V510);
end;

wobei es auch eine function sein kann und keine procedure. In dem Fall wäre es egal. Im idealfall müßte als String ja 123.6329 zurück kommen da ich ja alle nullen davor und danach wegkill. Nur wie stell ich das jetzt am besten an. Wenn mir dazu mit dem Beispiel hier eine Datei machen könntest wär das supi. Hab Delphi 7 Enterprise.

Tausend Dank.

[SirThornberry]

Delphi-Quellcode:

procedure EditKommaAusgang(Zeichen:PChar; var Ergebnis: PChar); stdcall;
var 
  T, VKT, HKT, B: String;
  MP, KP: Integer; 
  VKTL, HKTL: Boolean; 
begin 
  VKTL := False; 
  HKTL := False; 
  T := Zeichen; 
  if T = '.' then  T := '0.0';
  if T = '-' then T := '0.0'; 
  if T = '-.' then T := '0.0'; 
  if Pos('.', T) = 0 then T := T + '.'; 
  MP := Pos('-', T); 
  KP := Pos('.', T); 
  if KP > 0 then
  begin 
    VKT := Copy(T, 1, KP - 1);
    if MP > 0 then VKT := Copy(VKT, 2, Length(VKT) - 1); 
    HKT := Copy(T, KP + 1, Length(T) - KP); 
//Vorkommatext Nullen kürzen
    B := Copy(VKT, 1, 1); 
    while B = '0' do
    begin 
      VKT := Copy(VKT, 2, Length(VKT) - 1);
      B := Copy(VKT, 1, 1); 
      if Length(VKT) = 0 then VKTL := True; 
    end; 
//Hinterkommatext Nullen kürzen
    B := Copy(HKT, Length(HKT), 1); 
    while B = '0' do 
    begin
      HKT := Copy(HKT, 1, Length(HKT) - 1); 
      B := Copy(HKT, Length(HKT), 1);
      if Length(HKT) = 0 then HKTL := True;
    end;
    T := ''; 
    if MP > 0 then T := '-';
    T := T + VKT + '.' + HKT;
  end;
  if T = '.' then if (VKTL = True) or (HKTL = True) then T := '0.0' else T := ''; 
  if T = '-.' then if (VKTL = True) or (HKTL = True) then T := '0.0' else T := '';
  Ergebnis := StrAlloc(length(T) + 1);
  move(T[1], Ergebnis^, length(T));
  Ergebnis[length(T)] := #0;
end;

procedure FreeDLLMem(AChars: PChar);
begin
  StrDispose(AChars);
end;

procedure TForm1.Vorschau();
var V510: PChar;
begin
  EditKommaAusgang('00123.6329000', V510);
  ShowMessage(V510);
  FreeDLLMem(V510);
end;

[Armageddon]

Wowi man geht das schnell, so jetzt geh ich aber erst mal in die heia. Danke nochmals werds morgen gleich mal testen. wünsch ne gute nacht bzw. nen guten morgen. naja wie mans nimmt. *g* bis dann.

[Sprint]

Zitat:

Zitat von Armageddon

wobei es auch eine function sein kann und keine procedure.

Delphi-Quellcode:

function EditKommaAusgang(Zeichen: PChar): WideString; stdcall;
var
  T, VKT, HKT, B: String;
  MP, KP: Integer;
  VKTL, HKTL: Boolean;
begin
  VKTL := False;
  HKTL := False;
  T := Zeichen;
  if T = '.' then  T := '0.0';
  if T = '-' then T := '0.0';
  if T = '-.' then T := '0.0';
  if Pos('.', T) = 0 then T := T + '.';
  MP := Pos('-', T);
  KP := Pos('.', T);
  if KP > 0 then
  begin
    VKT := Copy(T, 1, KP - 1);
    if MP > 0 then VKT := Copy(VKT, 2, Length(VKT) - 1);
    HKT := Copy(T, KP + 1, Length(T) - KP);
//Vorkommatext Nullen kürzen
    B := Copy(VKT, 1, 1);
    while B = '0' do
    begin
      VKT := Copy(VKT, 2, Length(VKT) - 1);
      B := Copy(VKT, 1, 1);
      if Length(VKT) = 0 then VKTL := True;
    end;
//Hinterkommatext Nullen kürzen
    B := Copy(HKT, Length(HKT), 1);
    while B = '0' do
    begin
      HKT := Copy(HKT, 1, Length(HKT) - 1);
      B := Copy(HKT, Length(HKT), 1);
      if Length(HKT) = 0 then HKTL := True;
    end;
    T := '';
    if MP > 0 then T := '-';
    T := T + VKT + '.' + HKT;
  end;
  if T = '.' then if (VKTL = True) or (HKTL = True) then T := '0.0' else T := '';
  if T = '-.' then if (VKTL = True) or (HKTL = True) then T := '0.0' else T := '';
  Result := T;
end;

Delphi-Quellcode:

procedure TForm1.Vorschau;
var
  V510: String;
begin
  V510 := EditKommaAusgang('00123.6329000');
  ShowMessage(V510);
end;

Zitat:

Das sollte in die Dll und bei bedarf dynamisch geladen werden

Warum dynamisch und nicht statisch?

Statisch:

Delphi-Quellcode:

function EditKommaAusgang(Zeichen: PChar): WideString; stdcall; external 'mtrcnc32.dll';

Dynamisch:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  EditKommaAusgang: function(Zeichen: PChar): WideString; stdcall;
  LibMod: HMODULE;
  V510: String;
begin

  LibMod := LoadLibrary('mtrcnc32.dll');
  if LibMod <> 0 then
  begin
    EditKommaAusgang := GetProcAddress(LibMod, 'EditKommaAusgang');
    if Assigned(EditKommaAusgang) then
    begin
      V510 := EditKommaAusgang('00123.6329000');
      ShowMessage(V510);
    end;
    FreeLibrary(LibMod);
  end;

end;

[Armageddon]

Hi nochmal,

SirThornberry Dein Beispiel hab ich jetzt mal ausprobiert. Funktioniert auch bis zu StrDispose dann kackt es ab und bringt eine Fehlermeldung wegen Ungültiger Zeigeroperation.

Bis jetzt sieht es so aus:

Im Programm:

Delphi-Quellcode:

procedure TForm1.EditKommaExit(Sender: TObject);
var
  Test: String;
begin
  LabelLoeschen(self);
  KommaAusgang(self, (Sender as TEdit).Text, Test);
//  StellenPruefen(self, Sender as TEdit);
end;

Delphi-Quellcode:

procedure KommaAusgang(Woher: TForm; Eingabe: String; var Ausgabe:String);
var
  EditKommaAusgang: procedure(Zeichen:PChar; var Ergebnis: PChar); stdcall;
  LibMod: HMODULE;
  Rueckgabe: PChar;
begin
  if not FileExists('mtrcnc32.dll') then
  begin
    Fehler(Woher, 'Die Datei "mtrcnc32.dll" wurde nicht gefunden!');
  end;
  LibMod := LoadLibrary(PChar(ExtractFilePath(ParamStr(0))+'mtrcnc32.dll'));
  if LibMod <> 0 then
  begin
    EditKommaAusgang := GetProcAddress(LibMod, 'EditKommaAusgang');
    if Assigned(EditKommaAusgang) then
    begin
      EditKommaAusgang(PChar(Eingabe), Rueckgabe);
      Ausgabe := Rueckgabe;
      ShowMessage(Ausgabe);
      StrDispose(Rueckgabe); //<-- Hier kackts ab!
    end;
    FreeLibrary(LibMod);
  end;
end;

Und in der DLL:

Delphi-Quellcode:

procedure EditKommaAusgang(Zeichen:PChar; var Ergebnis: PChar); stdcall;
var
  T, VKT, HKT, B: String;
  MP, KP: Integer;
  VKTL, HKTL: Boolean;
begin
  VKTL := False;
  HKTL := False;
  T := Zeichen;
  if T = '.' then  T := '0.0';
  if T = '-' then T := '0.0';
  if T = '-.' then T := '0.0';
  if Pos('.', T) = 0 then T := T + '.';
  MP := Pos('-', T);
  KP := Pos('.', T);
  if KP > 0 then
  begin
    VKT := Copy(T, 1, KP - 1);
    if MP > 0 then VKT := Copy(VKT, 2, Length(VKT) - 1);
    HKT := Copy(T, KP + 1, Length(T) - KP);
//Vorkommatext Nullen kürzen
    B := Copy(VKT, 1, 1);
    while B = '0' do
    begin
      VKT := Copy(VKT, 2, Length(VKT) - 1);
      B := Copy(VKT, 1, 1);
      if Length(VKT) = 0 then VKTL := True;
    end;
//Hinterkommatext Nullen kürzen
    B := Copy(HKT, Length(HKT), 1);
    while B = '0' do
    begin
      HKT := Copy(HKT, 1, Length(HKT) - 1);
      B := Copy(HKT, Length(HKT), 1);
      if Length(HKT) = 0 then HKTL := True;
    end;
    T := '';
    if MP > 0 then T := '-';
    T := T + VKT + '.' + HKT;
  end;
  if T = '.' then if (VKTL = True) or (HKTL = True) then T := '0.0' else T := '';
  if T = '-.' then if (VKTL = True) or (HKTL = True) then T := '0.0' else T := '';
  Ergebnis := StrAlloc(length(T) + 1);
  Move(T[1], Ergebnis^, length(T));
  Ergebnis[length(T)] := #0; 
end;

Was muß man hier noch verbessern? Bzw. was hab ich falsch gemacht? Please help me.

[Armageddon]

So hat sich erledigt,

hab nur vorher was übersehen. Könnte sich noch jemand anschauen ob das was ich programmiert habe keine Speicherlecks oder ähnliches hinterläßt? Wär mir sehr wichtig. Konstrukitve Ratschläge nehm ich gerne an und versuche sie auch umzusetzen.

Hier der fertige funktionierende Code:

Die procedure im Programm

Delphi-Quellcode:

procedure KommaAusgang(Woher: TForm; Eingabe: String; var Ausgabe:String);
var
  EditKommaAusgang: procedure(Zeichen:PChar; var Ergebnis: PChar); stdcall;
  DLLMemFreigeben: procedure(AChars: PChar); stdcall;
  LibMod: HMODULE;
  Rueckgabe: PChar;
begin
  if not FileExists('mtrcnc32.dll') then
  begin
    Fehler(Woher, 'Die Datei "mtrcnc32.dll" wurde nicht gefunden!');
  end;
  LibMod := LoadLibrary(PChar(ExtractFilePath(ParamStr(0))+'mtrcnc32.dll'));
  if LibMod <> 0 then
  begin
    EditKommaAusgang := GetProcAddress(LibMod, 'EditKommaAusgang');
    DLLMemFreigeben := GetProcAddress(LibMod, 'FreeDLLMem');
    if Assigned(EditKommaAusgang) and Assigned(DLLMemFreigeben) then
    begin
      EditKommaAusgang(PChar(Eingabe), Rueckgabe);
      Ausgabe := Rueckgabe;
      DLLMemFreigeben(Rueckgabe);
    end
    else Ausgabe := Eingabe;
    FreeLibrary(LibMod);
  end;
end;

Der Aufruf im Programm:

Delphi-Quellcode:

procedure TForm1.EditKommaExit(Sender: TObject);
var
  Zeichen: String;
begin
  LabelLoeschen(self);
  KommaAusgang(self, (Sender as TEdit).Text, Zeichen);
  (Sender as TEdit).Text := Zeichen;
  StellenPruefen(self, Sender as TEdit);
end;

Und das hier in der DLL:

Delphi-Quellcode:

procedure FreeDLLMem(AChars: PChar); stdcall
begin
  StrDispose(AChars);
end;

procedure EditKommaAusgang(Zeichen:PChar; var Ergebnis: PChar); stdcall;
var
  T, VKT, HKT, B: String;
  MP, KP: Integer;
  VKTL, HKTL: Boolean;
begin
  VKTL := False;
  HKTL := False;
  T := Zeichen;
  if T = '.' then  T := '0.0';
  if T = '-' then T := '0.0';
  if T = '-.' then T := '0.0';
  if Pos('.', T) = 0 then T := T + '.';
  MP := Pos('-', T);
  KP := Pos('.', T);
  if KP > 0 then
  begin
    VKT := Copy(T, 1, KP - 1);
    if MP > 0 then VKT := Copy(VKT, 2, Length(VKT) - 1);
    HKT := Copy(T, KP + 1, Length(T) - KP);
//Vorkommatext Nullen kürzen
    B := Copy(VKT, 1, 1);
    while B = '0' do
    begin
      VKT := Copy(VKT, 2, Length(VKT) - 1);
      B := Copy(VKT, 1, 1);
      if Length(VKT) = 0 then VKTL := True;
    end;
//Hinterkommatext Nullen kürzen
    B := Copy(HKT, Length(HKT), 1);
    while B = '0' do
    begin
      HKT := Copy(HKT, 1, Length(HKT) - 1);
      B := Copy(HKT, Length(HKT), 1);
      if Length(HKT) = 0 then HKTL := True;
    end;
    T := '';
    if MP > 0 then T := '-';
    T := T + VKT + '.' + HKT;
  end;
  if T = '.' then if (VKTL = True) or (HKTL = True) then T := '0.0' else T := '';
  if T = '-.' then if (VKTL = True) or (HKTL = True) then T := '0.0' else T := '';
  Ergebnis := StrAlloc(length(T) + 1);
  Move(T[1], Ergebnis^, length(T));
  Ergebnis[length(T)] := #0; 
end;

exports
  FreeDLLMem, EditKommaAusgang;

Danke schon mal im voraus, Arma

[Sprint]

Zitat:

Zitat von Armageddon

Könnte sich noch jemand anschauen ob das was ich programmiert habe keine Speicherlecks oder ähnliches hinterläßt? Wär mir sehr wichtig. Konstrukitve Ratschläge nehm ich gerne an und versuche sie auch umzusetzen.

Ein funktionierendes Beispiel habe ich hier gepostet.

[Armageddon]

Gibts mit WideString keine Probleme? ICh dachte man soll PChar zur Stringübergabe bei DLL's benutzen?

[Sprint]

Bei mir ist noch nie ein Fehler mit WideStrings aufgetreten.

[GuenterS]

Braucht man diese ShareMem Unit wenn man WideStrings verwendet?

[Meflin]

mann kann auch strings ohne die sharemem.dll verwenden. dazu gibts dieses nette teil ;)

[Muetze1]

Moin!

Zitat:

Zitat von GuenterS

Braucht man diese ShareMem Unit wenn man WideStrings verwendet?

Nein, eigentlich nicht.

MfG
Muetze1