transparentes formular in D3

[hardcorehorst]

Guten Morgen ,

Wie ist es möglich ein formular von D3 transparent zu machen???
so das nur ein teiltransparentes Bild dann als Hintergrund zu sehen ist ???

hab schon versuch in oncreate vom desktop n foto zu machen aber hat nicht sehr gut geklappt
(spätestens beim verschieben)

Bin für eure Vorschläge offen !!! ;-)

[SirThornberry]

mit folgendem source

Delphi-Quellcode:

function SetFormTransparent(AFormHandle: HWnd; ATransparentVal: Byte): Boolean;
const
  WS_EX_LAYERED = $00080000;
  LWA_ALPHA = $00000002;
var LStyle: Integer;
    LDLLHandle: Cardinal;
    LSetLayerdProc: function (Hwnd: THandle; crKey: COLORREF; bAlpha: Byte; dwFlags: DWORD): Boolean; stdcall;
begin
  LDLLHandle := LoadLibrary('user32.dll');
  if LDLLHandle <> 0 then
  begin
    @LSetLayerdProc := GetProcAddress(LDLLHandle, 'SetLayeredWindowAttributes');
    if Assigned(LSetLayerdProc) then
    begin
      LStyle := GetWindowLong(AFormHandle, GWL_EXSTYLE);
      SetWindowLong(AFormHandle, GWL_EXSTYLE, LStyle or WS_EX_LAYERED);

      result := LSetLayerdProc(AFormHandle, 0, ATransparentVal, LWA_ALPHA);
    end else result := False;
    FreeLibrary(LDLLHandle);
  end else result := False;
end;

Beispielaufruf:

Delphi-Quellcode:

  SetFormTransparent(Handle, 255);

[hardcorehorst]

cool besten dank !!!!!!!!!!

[hardcorehorst]

das war aber nicht ganz das was ich meine

du setzt das komplette form transparent(inklusive hintergrund image)
ich will aber nur das form transparent und das image sichtbar

trotzdem danke

[SirThornberry]

willst du das Form vollständig durchsichtig oder nur zum teil? Wenn du es nur teilweise durchsichtig haben willst dann geht das was du vor hast nicht.

[hardcorehorst]

na gut :(
trotzdem danke

[SirThornberry]

es gäbe noch die variante das du ein zweites formular machst was du dann an der entsprechenden Stelle über dem ersten plazierst.

[hardcorehorst]

naja das maroone soll transparent sein

[derpepe]

War da nicht bei den JEDI-Komponenten eine dabei die genau das macht?!
Läuft das unter D3?
Guck doch mal nach!

[hardcorehorst]

ne die jedis laufen erst ab D4 wie es aussieht

[Sprint]

Zitat:

Zitat von hardcorehorst

Wie ist es möglich ein formular von D3 transparent zu machen?

http://www.delphi-fundgrube.de/faq07.htm#topic0704

[hardcorehorst]

Zitat:

Delphi-Quellcode:

Procedure MakeWindowTransparent (Form: TForm);
Var CurrentStyle : LongInt;
Begin
  Form.Visible := False;
  CurrentStyle := GetWindowLong(Form.Handle, GWL_EXSTYLE);
  SetWindowLong(Form.Handle, GWL_EXSTYLE, CurrentStyle Or WS_EX_TRANSPARENT);
  Form.Visible := True;
End; {Paul Röttgen}

Procedure MakeWindowOpaque (Form: TForm);
Var CurrentStyle : LongInt;
Begin
  Form.Visible := False;
  CurrentStyle := GetWindowLong (Form.Handle, GWL_EXSTYLE);
  SetWindowLong(Form.Handle, GWL_EXSTYLE, CurrentStyle And Not WS_EX_TRANSPARENT);
  Form.Visible := True;
End; {Paul Röttgen}

macht wieder das ganze form unsichtbar

Zitat:

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
begin
  Form1.Brush.Style := bsClear;
  Form1.BorderStyle := bsNone;
end;

sorgt nur dafür das es zu anfang transparent ist
beim verschieben stimmt es nicht mehr

[SirThornberry]

Zitat:

Zitat von hardcorehorst

Zitat:

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
begin
  Form1.Brush.Style := bsClear;
  Form1.BorderStyle := bsNone;
end;

sorgt nur dafür das es zu anfang transparent ist
beim verschieben stimmt es nicht mehr

Also willst du das Form vollständig transparenzt haben und nicht halbdurchsichtig? (Das das Bild gar nicht durchsichtig werden soll ist klar).

[hardcorehorst]

ja genau

[SirThornberry]

Dann gehts mit folgender Funktion

Delphi-Quellcode:

function SetFormTransparent(AFormHandle: HWnd; ATransparentColor: TColor): Boolean;
const
  WS_EX_LAYERED = $00080000;
  LWA_COLORKEY = $00000001;
var LStyle: Integer;
    LDLLHandle: Cardinal;
    LSetLayerdProc: function (Hwnd: THandle; crKey: COLORREF; bAlpha: Byte; dwFlags: DWORD): Boolean; stdcall;
begin
  LDLLHandle := LoadLibrary('user32.dll');
  if LDLLHandle <> 0 then
  begin
    @LSetLayerdProc := GetProcAddress(LDLLHandle, 'SetLayeredWindowAttributes');
    if Assigned(LSetLayerdProc) then
    begin
      LStyle := GetWindowLong(AFormHandle, GWL_EXSTYLE);
      SetWindowLong(AFormHandle, GWL_EXSTYLE, LStyle or WS_EX_LAYERED);

      result := LSetLayerdProc(AFormHandle, ColorToRGB(ATransparentColor), 0, LWA_COLORKEY);
    end else result := False;
    FreeLibrary(LDLLHandle);
  end else result := False;
end;

Du musst die Farbei deines Forms auf eine Farbe setzen die im Bild nicht vorkommt, und dann obige funktion mit dieser Farbe aufrufen.

Beispiel:

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
begin
  color := clFuchsia; //Farbe des Forms auf Rosa setzen (Rosa sollte also nicht im Bild vorkommen)
  SetFormTransparent(handle, Color); //Und dann Rosa als Transparenztsfarbe setzen
end;

[hardcorehorst]

AFormHandle durch Form1.Handle ersetzen
und....

es klappt !!!
:hello: :party: :thumb:

Besten Dank für alle antworten !!!