Klon floppy

[MadMax]

Hallo,

Das „Verbinden“ mit dem Diskettenlaufwerk funtzt mit diesem Programm ganz gut, nur jetzt setzt mein Delphi wissen bisschen aus wie kann ich nun die Daten bit für bit auf eine andere Floppy Kopieren. Währe für paar Tipps sehr dankbar

Delphi-Quellcode:

type TDiskGeometry = packed record
     Cylinders: Int64;
     MediaType: Integer;
     TracksPerCylinder: DWORD;
     SectorsPerTrack: DWORD;
     BytesPerSector: Integer; // wichtig für die Reservierung des Buffer-Speichers
end;
     TRawDrive = record
     DiskGeometry: TDiskGeometry;
     Handle: THandle;
end;

var Raw: TRawDrive;

const
  IOCTL_DISK_GET_DRIVE_GEOMETRY = $00070000;
  FSCTL_LOCK_VOLUME = $00090018;
  FSCTL_UNLOCK_VOLUME = $0009001C;

function RawOpenDrive(DriveLetter: Char): TRawDrive;
 var num: Cardinal;
begin
  FillChar(Result, SizeOf(TRawDrive), 0);
  Result.Handle := CreateFile(PChar('\\.\' + DriveLetter + ':'),
                       GENERIC_READ or GENERIC_WRITE,
                       FILE_SHARE_READ or FILE_SHARE_WRITE,
                       nil,
                       OPEN_EXISTING,
                       0,
                       0);

if Result.Handle = INVALID_HANDLE_VALUE then  RaiseLastWin32Error;

// Laufwerk für andere sperren
if not DeviceIoControl(Result.Handle, FSCTL_LOCK_VOLUME, nil, 0, nil, 0, num, nil) then
    RaiseLastWin32Error;

{ Disk-Geometry ermitteln. Vor allem ist das Feld BytesPerSector wichtig, da nur vielfache Bytes gelesen werden können. Ist also BytesPerSector z.B: 512 und man will nur 1 Byte lesen, muss man 512 Bytes lesen. }
if not DeviceIoControl(result.Handle, IOCTL_DISK_GET_DRIVE_GEOMETRY, nil, 0, @Result.DiskGeometry,
                         SizeOf(TDiskGeometry), num, nil) then
    RaiseLastWin32Error;
end;

procedure RawCloseDrive(var RawDrive: TRawDrive);
var num: Cardinal;
begin
  DeviceIoControl(RawDrive.Handle, FSCTL_UNLOCK_VOLUME, nil, 0, nil, 0, num, nil);
  CloseHandle(RawDrive.Handle);
  RawDrive.Handle := 0;
end;

procedure RawReadSectors(RawDrive: TRawDrive; var Buf; Count: Integer);
var num: Cardinal;
begin
  if not ReadFile(RawDrive.Handle, Buf, Count * RawDrive.DiskGeometry.BytesPerSector, num, nil) then
    RaiseLastWin32Error;
end;

procedure RawWriteSectors(RawDrive: TRawDrive; var Buf; Count: Integer);
var num: Cardinal;
begin
  if not WriteFile(RawDrive.Handle, Buf, Count * RawDrive.DiskGeometry.BytesPerSector, num, nil) then
    RaiseLastWin32Error;
end;

procedure TForm1.Button1Click(Sender: TObject);
 var buf: Pchar;
begin
   RawOpenDrive('a');
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
 RawCloseDrive(Raw);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  RawCloseDrive(Raw);
end;

end.

[MadMax]

Wenn ich denn Befehl zum lesen so aufrufe.

Delphi-Quellcode:

RawReadSectors(RawOpenDrive('a'), buf, SizeOf(RawDrive.DiskGeometry.BytesPerSector));

Tritt ein access violation auf.

[jbg]

Zitat:

RawReadSectors(RawOpenDrive('a')...

1. Und wann gibst du das Diskettenlaufwerk wieder für andere Anwendungen frei?

2. OnFormCreate: "RawOpenDrive('a');" Und wo ist die Zuweisung an Raw?

3. Wie hast du buf deklariert?

4. Wie oft willst du das nicht an Raw zugewiesene Diskettenlaufwerk freigeben "RawCloseDrive(Raw);" ?

5. Willst du nur 4 Sektoren einlesen? SizeOf(Integer) = 4 = SizeOf(RawDrive.DiskGeometry.BytesPerSector) ?

[MadMax]

Zitat:

Zitat von jbg

Zitat:

RawReadSectors(RawOpenDrive('a')...

1. Und wann gibst du das Diskettenlaufwerk wieder für andere Anwendungen frei?

2. OnFormCreate: "RawOpenDrive('a');" Und wo ist die Zuweisung an Raw?


3. Wie hast du buf deklariert?

4. Wie oft willst du das nicht an Raw zugewiesene Diskettenlaufwerk freigeben "RawCloseDrive(Raw);" ?

5. Willst du nur 4 Sektoren einlesen? SizeOf(Integer) = 4 = SizeOf(RawDrive.DiskGeometry.BytesPerSector) ?

Hab jetzt das geändert;

Ich komm nur nicht ganz mit dem „buf“ klar. Kann es sein das bei win 200 der zugriff anderes als bei Win NT ist.

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
begin
  raw := RawOpenDrive('a');
end;

Delphi-Quellcode:

RawReadSectors(raw, buf, 20);
RawCloseDrive(raw);

[jbg]

Der Code ist für Win2000/XP und dürfte unter NT auch laufen.

Zitat:

ich komm nur nicht ganz mit dem „buf“ klar

var buf: array[0..(512 * 20{Sektoren}) - 1] of Byte; (512 ist der BytesPerSector Wert für 3 1/2'' Disketten).

[MadMax]

Vielen Dank jetzt funtzt das Teil auch. Nur leider hat diese Schlüssel Diskette noch einen Schutz aber es war trotzdem eine gute Übung. Ich Poste noch mal den Code.

Delphi-Quellcode:

type TDiskGeometry = packed record
     Cylinders: Int64;
     MediaType: Integer;
     TracksPerCylinder: DWORD;
     SectorsPerTrack: DWORD;
     BytesPerSector: Integer; // wichtig für die Reservierung des Buffer-Speichers
end;
     TRawDrive = record
     DiskGeometry: TDiskGeometry;
     Handle: THandle;
end;

var raw: TRawDrive;

const
  IOCTL_DISK_GET_DRIVE_GEOMETRY = $00070000;
  FSCTL_LOCK_VOLUME = $00090018;
  FSCTL_UNLOCK_VOLUME = $0009001C;

function RawOpenDrive(DriveLetter: Char): TRawDrive;
 var num: Cardinal;
begin
  FillChar(Result, SizeOf(TRawDrive), 0);
  Result.Handle := CreateFile(PChar('\\.\' + DriveLetter + ':'),
                       GENERIC_READ or GENERIC_WRITE,
                       FILE_SHARE_READ or FILE_SHARE_WRITE,
                       nil,
                       OPEN_EXISTING,
                       0,
                       0);

if Result.Handle = INVALID_HANDLE_VALUE then  RaiseLastWin32Error;
   if not DeviceIoControl(Result.Handle, FSCTL_LOCK_VOLUME, nil, 0, nil, 0, num, nil) then
      begin
       showmessage('Laufwerk wird gerade benützt!!!');// Laufwerk für andere sperren
       halt;
      end;
          {Disk-Geometry ermitteln. Vor allem ist das Feld BytesPerSector wichtig,
          da nur vielfache Bytes gelesen werden können. Ist also BytesPerSector z.B:
          512 und man will nur 1 Byte lesen, muss man 512 Bytes lesen. }
          if not DeviceIoControl(result.Handle, IOCTL_DISK_GET_DRIVE_GEOMETRY, nil, 0, @Result.DiskGeometry,
                       SizeOf(TDiskGeometry), num, nil) then
             begin
              ShowMessage('Keine Floppy im Laufwerk !!!');
              halt;
             end
end;

procedure RawCloseDrive(RawDrive: TRawDrive);
 var num: Cardinal;
begin
  DeviceIoControl(RawDrive.Handle, FSCTL_UNLOCK_VOLUME, nil, 0, nil, 0, num, nil);
  CloseHandle(RawDrive.Handle);
  RawDrive.Handle := 0;
end;

procedure RawReadSectors(RawDrive: TRawDrive; var Buf; Count: Integer);
 var num: Cardinal;
begin
  if not ReadFile(RawDrive.Handle, Buf, Count * RawDrive.DiskGeometry.BytesPerSector, num, nil) then
         RaiseLastWin32Error;
end;

procedure RawWriteSectors(RawDrive: TRawDrive; var Buf; Count: Integer);
 var num: Cardinal;
begin
  if not WriteFile(RawDrive.Handle, Buf, Count * RawDrive.DiskGeometry.BytesPerSector, num, nil) then
         RaiseLastWin32Error;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  raw := RawOpenDrive('a');
  timer1.Enabled := true;
end;

procedure TForm1.Button1Click(Sender: TObject);
 var buf: array[0..(512 * 20{Sektoren}) - 1] of Byte;
     MSG: Integer;
begin
    RawReadSectors(raw, buf, 20);
    Panel1.Color := clgreen;
    if Sizeof(buf) = 10240 then
      RawCloseDrive(raw);
       MSG := Application.MessageBox('Neue Floppy Einlegen','Meldungsfenster',49);
      if MSG = 1 then begin
         raw := RawOpenDrive('a');
         RawWriteSectors(raw,buf, 20) end
       else
       if MSG = 2 then
           halt;
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
 RawCloseDrive(raw);
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
 button1.Enabled := true;
end;

end.

[MadMax]

Doch noch ein Problem: :bouncing4:
Das Tool Kopiert (klont) die Diskette aber ich finde (irgendwie) zu schnell. Teilweiße sind die geklonten Disketten sehr fehlerhaft. Gibt es vielleicht eine Möglichkeit denn Kopiervorgang etwas sicherer zu machen.

[jbg]

Der andere Schutz besteht dann wohl in den restlichen 2860 Sektoren, die du nicht kopierst. Ist dir nicht aufgefallen, dass das Kopieren nicht etwas zu schnell war?

Zudem: Ich hatte jetzt keine Lust mich durch die Windows.pas zu schlagen in der Hoffnung, dass ich herausbekomme was 49 bedeuten soll. Also habe ich es durch MB_OKCANCEL ersetzt. Neben dem, das es schlechter Programmierstil ist, wird es in der professionellen Softwareentwicklung (=Beruf) nicht gerade gern gesehen, wenn man die Konstanten über Bord wird und durch Zahlen ersetzt. Du musst immer damit rechnen, dass andere den Quellcode lesen wollen.

Delphi-Quellcode:

function CopyDisk: Boolean;
var
  raw: TRawDrive;
  Buf: Pointer;
  Sectors: Integer;
  BytesPerSector: Integer;
begin
  Result := False;
  Raw := RawOpenDrive('a');
  if Raw.Handle <> 0 then
  begin
   // wieviel Sektoren sind überhaupt auf der Diskette
    with Raw.DiskGeometry do
      Sectors := Cylinders * TracksPerCylinder * SectorsPerTrack;
    BytesPerSector := Raw.DiskGeometry.BytesPerSector;

    GetMem(Buf, Sectors * BytesPerSector); // genug Speicher reservieren
    try
      try
        RawReadSectors(Raw, Buf^, Sectors); // alle Sektoren einlesen, das dauert
      finally
        RawCloseDrive(Raw);
      end;
      if Application.MessageBox('Neue Floppy Einlegen','Meldungsfenster', MB_OKCANCEL) = IDYES then
      begin
        Raw := RawOpenDrive('a');
        try
          RawWriteSectors(Raw, Buf^, Sectors); // alle Sektoren schreiben, dauert noch länger
        finally
          RawCloseDrive(Raw);
        end;
        Result := True; // Kopieren war erfolgreich
      end;
    finally
      FreeMem(Buf);
    end;
  end;
end;

[MadMax]

Jetzt funktioniert es ausgezeichnet.
Nur bei der Schüssel Diskette tritt leider ein Code: 23 Datenfehler (crc-Prüfung) auf.

[Luckie]

Bei mir hat der Code irgendwie nicht funktioniert. Er hat zwar gelesen, aber er wollte die neue nicht schreiben. :roll: