Form kann nicht angezeigt werden?

[alcaeus]

Hallo allerseits,

ich erzeuge ein Form, und setze dieses dann ueber die Parent-Eigenschaft auf dein TTBXAlignmentPanel:

Delphi-Quellcode:

frmAbout := TfrmAbout.Create(Self);
frmAbout.Parent := bxapMain;

Wenn ich nun versuche, das Form mit Show oder mit .Visible := True anzuzeigen, bekomme ich immer die Fehlermeldung "Cannot focus an invisible or disabled window". Wenn ich die Form hingegen nicht auf das AlignmentPanel setze funktionierts. Dasselbe passiert uebrigens bei eine normalen Panel. Sowohl das AlignmentPanel, das normale Panel und die Form sind Enabled, und ausser der Form sind auch alle Visible. Ich habe wirklich keine Ahnung woran das liegen kann, das entzieht sich irgendwie meiner Logik. Kann mir jemand vielleicht weiterhelfen?

Greetz
alcaeus

[mirage228]

Also ich habs mit nem normalen Panel versucht:

Delphi-Quellcode:

procedure TForm2.Button1Click(Sender: TObject);
var
  frmAbout : TForm2;
begin
  frmAbout := TForm2.Create(Self);
  frmAbout.Parent := Panel1;
  frmAbout.Show;
end;

ging bei mir ohne Probleme :gruebel:

mfG
mirage228

[CalganX]

Hi Andreas,
ich vermute mal sehr stark, dass du diesen Code innerhalb von OnCreate oder OnShow des Formulars aufgerufen hast. Zu dieser Zeit ist das Panel entweder noch nicht erzeugt oder noch nicht sichtbar. ;)

Chris

[alcaeus]

Hallo Chak,

ich setze den Parent zwar im OnCreate, aber das Show des zweiten Forms rufe ich in einem ButtonClick auf.
Ich habe jetzt versucht, ein zweites Formular anzuzeigen, dort erhalte ich keine Fehlermeldung, aber es passiert auch nichts :roll:

Greetz
alcaeus

[alcaeus]

So, hab jetzt einen Teil davon geloest: Ich muss zuerst den Parent setzen, dann BorderStyle auf bsNone, sonst geht da gar nichts, obwohl das normalerweise nicht der Fall ist. Aber egal, mir machts nichts aus.
However, zweites Problem: das Form das ich aus der DLL hole, wird nie angezeigt, wenn ich im Anfang Visible auf False setze. Visible wird geaendert, das erfrage ich mit einem ShowMessage. Setze ich am Anfang hingegen Visible auf True, so wird es immer angezeigt, egal wie ich Visible veraendere. Hat da jemand evtl. eine Loesung fuer mich?

Greetz
alcaeus

[add]Solange kein Parent gesetzt ist, wird auch das Form aus der DLL angezeigt. Ich kann mir das nur anhand der TBX-Kompos erklaeren, aber glauben will ich es nicht :gruebel:[/add]

[Bernhard Geyer]

Zitat:

Zitat von alcaeus

So, hab jetzt einen Teil davon geloest: Ich muss zuerst den Parent setzen, dann BorderStyle auf bsNone, sonst geht da gar nichts, obwohl das normalerweise nicht der Fall ist. Aber egal, mir machts nichts aus.
However, zweites Problem: das Form das ich aus der DLL hole, wird nie angezeigt, wenn ich im Anfang Visible auf False setze. Visible wird geaendert, das erfrage ich mit einem ShowMessage. Setze ich am Anfang hingegen Visible auf True, so wird es immer angezeigt, egal wie ich Visible veraendere. Hat da jemand evtl. eine Loesung fuer mich

Verwendest Du Laufzeitpackages für DLL und Exe?
Falls nein wird es Probleme geben da ja TForm aus der Exe <> TForm aus der DLL ist!

[marabu]

Hallo alcaeus,

wenn du deinem Fenster einen Parent verpasst, dann solltest du nicht vergessen ihm vorher den Style WS_CHILD zu geben (CreateParams).

Grüße vom marabu

[alcaeus]

Hallo allerseits,

neue Woche, neues Glueck: ich habs geschafft. Damit nicht nur ich profitiere, stelle ich die Loesung mal hier rein:

Die Loesung verwendet die oben erwaehnten CreateParams. Die Funktion die das Form erstellt (in der DLL) wird so deklariert:

Delphi-Quellcode:

function GetMainForm(ParentHandle: HWND): TForm; stdcall;
begin
   if ParentHandle > 0 then
      Result := TfrmDLL.CreateParented(ParentHandle)
   else
      Application.CreateForm(TfrmDLL, Result);
end;

Das Form muss die CreateParams-Methode im public-Bereich ueberschreiben:

Delphi-Quellcode:

procedure CreateParams(var Params: TCreateParams); override;

Die Implementation sieht dann so aus:

Delphi-Quellcode:

procedure TfrmDLL.CreateParams(var Params: TCreateParams);
begin
   inherited CreateParams(Params);
   if Self.ParentWindow > 0 then
      Params.Style := Params.Style or WS_CHILD;
end;

Bei der Verwendung wird zuerst der Funktionstyp deklariert:

Delphi-Quellcode:

TGetDLLFrm = function(ParentHandle: HWND): TForm; stdcall;

Nun kann man sich den Pointer auf die Funktion holen:

Delphi-Quellcode:

DLLFormProc := GetProcAddress(DLLHandle, PChar('GetMainForm'));

Und anschliessend kann man sich auch das Form holen:

Delphi-Quellcode:

ModuleForm := TGetDLLFrm(DLLFormProc)(Panel1.Handle);
with ModuleForm do
begin
   BorderStyle := bsNone;
   Align := alClient;
   Visible := True;
end;

Bei mir funktioniert das, vielen Dank an alle die geholfen haben :)

Greetz
alcaeus