Rätsel über Rätsel... AV, wo es keine geben *kann*

[Meflin]

Aloha!

Ich habe ein Problem, das sich eigentlich niemand den ich bis jetzt fragte erklären kann: im constructor meiner Komponente erstelle ich u.a. eine TStringList, aber diese wird nicht erzeugt, der Debugger sagt mir dass sie nil ist.

Delphi-Quellcode:

  
private
  fPasswords: TStringList;
...
public
  constructor Create(AOwner: TComponent); reintroduce;
...
constructor TPasswordList.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  fPasswords := TStringList.Create;
  fCount := fPasswords.Count;
  fCS := TCriticalSection.Create;  
end;

wenn ich dann versuche z.b. die addmethode meiner kompo aufzurufen, die so aussieht:

Delphi-Quellcode:

function TPasswordList.Add(const s: string): Integer;
begin
  if ThreadSave then CS.Enter;
  Result := fPasswords.Add(s);
  if ThreadSave then CS.Leave;
  fCount := fPasswords.Count;
end;

und ich da einen Breakpoint setze, zeigt der Debugger an dass fPasswords nil ist und folglich endet das ganze in einer AV.

Aber wieso?

[fkerber]

Hi!

Und Zeile 11 des ersten Blocks gibt keine AV?


Ciao Frederic

[Jens Schumann]

Hallo,
die Sourceausschnitt sieht natürlich Ok aus. Schieb doch mal den kompletten Quelltext rüber.

[Keldorn]

ist die Stringliste eine property? wenn ja, dann brauchst du dort eine Set-methode, wo du assign verwendest, eine einfache Zuweisung reicht hier nicht.

Delphi-Quellcode:

procedure Set...
  fpasswords.assign(value);

Mfg Frank

[xaromz]

Hallo,

Zitat:

Zitat von Meflin

Delphi-Quellcode:

constructor Create(AOwner: TComponent); reintroduce;
...

was für einen Vorfahrtyp hat denn dein Objekt? normalerweise braucht man kein reintroduce für den Konstruktor. Wird dieser denn überhaupt aufgerufen?

Gruß
xaromz

[SirThornberry]

wenn ich mir das so anschaue sieht es aus als ob der constructor die gleichen parameter hat wie der vorgänger. Dementsprechend solltest du anstelle von reintroduce lieber override nehmen und schon sollte das ganze funktionieren. Allerdings würde ich dann auch vermuten das der constructor bisher nie aufgerufen wurde sondern immer der des vorfahren

[Meflin]

Merci, mit override funktioniert das ganze wunderbarst :)

[sakura]

Zitat:

Zitat von Keldorn

ist die Stringliste eine property? wenn ja, dann brauchst du dort eine Set-methode, wo du assign verwendest, eine einfache Zuweisung reicht hier nicht.

Der von Dir vorgeschlagene Weg ist zwar der korrekte, aber der andere ist auch eine theoretische Möglichkeit, auch wenn einen OOP-Freak das Grausen bei solch einem Anblick bekommt :zwinker:

...:cat:...

[SirThornberry]

falls man doch mal den Constructor von einer Componente neu definieren will dann geht das so (in dem Beispiel soll dem Constructor noch ein String übergeben bekommen)

Delphi-Quellcode:

  TTestcomp = class(TComponent)
  private
    fCaption: String;
  public
    constructor Create(AOwner: TComponent); overload; override;
    constructor Create(AOwner: TComponent; ACaption: String); overload;
  end;

constructor TTestcomp.Create(AOwner: TComponent);
begin
  Create(AOwner, 'StandardString');
end;

constructor TTestcomp.Create(AOwner: TComponent; ACaption: String);
begin
  fCaption := ACaption;
  inherited Create(AOwner);
end;

Wird also der ursprungsconstructor aufgerufen (zum Beispiel weil auf TComponent gecastet wurde so wie delphi es beim automatischen creieren macht, so ruft der überschriebene Constructor den neuen Constructor mit einem Standardwert auf welcher dann die eignetliche Aufgaben erledigt.

[Sidorion]

Ich will nicht pedantisch erscheinen, aber es muss heissen:

Delphi-Quellcode:

    constructor Create(AOwner: TComponent); overload; override;
    constructor Create(AOwner: TComponent; ACaption: String); reintroduce; overload;

Fragt mich bitte nicht warum die Reihenfolge bei den direktiven andersrum ist, aber da steckt man nicht drin :wink:
Wenn du das reintroduce weglasst meckert wegen der Überschreiberei rum