TIdFTPServer: Meldung, wenn Datei übertragen ist???

[romber]

Hallo!

Ich habe mithilfe von TIdFTPServer einen kleinen FTP-Server für meine Zwecke programmiert. Alles funktioniert soweit gut. Ich möchte nun eine Zeile in meine Log-Datei hinzufügen, wenn eine Datei komplett übertragen wurde. Sobald die zu übertragene Datei komplett auf meinem FTP ist, soll eine entsprechende Meldung in der Log-Datei landen. Wie mache ich das?

[SirThornberry]

wie übermittelst du die Datei? Per FileStream? Wenn dem so ist dann wird bei Beendigung der Übertragung der Stream frei gegeben. Und hier musst du ansetzen. Eine StreamKlasse schreiben mit einem OnDestroy so das du mitbekommst wenn dein Stream frei gegeben wird.

Wenn du das nicht verstanden hast oder dir der Anhaltspunkt fehlt wie das zu realisieren ist melde dich nochmal dann poste ich ein Beispiel. Die obige Methode funktioniert auf jeden fall, hab das in meinem FTP-Server so realisiert.

Poste gegebenfalls mal dein OnStoreFile und dein OnRetrieveFile (bzw. das Ereignis worum es dir geht)

[romber]

Vielen Dank für schnelle Antwort!

Zitat:

Zitat von SirThornberry

Wenn du das nicht verstanden hast oder dir der Anhaltspunkt fehlt wie das zu realisieren ist melde dich nochmal dann poste ich ein Beispiel. Die obige Methode funktioniert auf jeden fall, hab das in meinem FTP-Server so realisiert.

Poste gegebenfalls mal dein OnStoreFile und dein OnRetrieveFile (bzw. das Ereignis worum es dir geht)

Ich habe schon vertanden, nur ich weiss wirklich nicht, wie das zu realisieren ist. Poste bitte einen Beispiel.

Delphi-Quellcode:

procedure TForm1.IdFTPServer1StoreFile(ASender: TIdFTPServerThread; const AFileName: String; AAppend: Boolean; var VStream: TStream);
begin
  if FileExists(translatepath(AFilename, ASender.HomeDir)) and AAppend then
  begin
    VStream := TFileStream.create(translatepath(AFilename, ASender.HomeDir), fmOpenWrite or fmShareExclusive);
    VStream.Seek(0, soFromEnd);
    Log.Lines.Add('Datei wird überschrieben: '+ AFileName);
  end
  else
  begin
    VStream := TFileStream.create(translatepath(AFilename, ASender.HomeDir), fmCreate or fmShareExclusive);
    Log.Lines.Add('Datei wird übertragen: ' + AFileName);
  end;
end;

procedure TForm1.IdFTPServer1RetrieveFile(ASender: TIdFTPServerThread; const AFileName: String; var VStream: TStream);
begin
  VStream := TFileStream.create(translatepath(AFilename, ASender.HomeDir), fmopenread or fmShareDenyWrite)
end;

Danke im Vorraus!

[romber]

Habe immer noch keine Lösung :( Kann mir jemand einen Beispiel posten?

[SirThornberry]

so ginge es zum Beispiel -

Anstelle von TFileStream nutze TMyFileStream (selbst schreiben)

Delphi-Quellcode:

type
  TMyFileStream = class(TFileStream)
  private
    fOnDestroy: TNotifyEvent;
  public
    destructor Destroy; override;

    property OnDestroy: TNotifyEvent read fOnDestroy write fOnDestroy;
  end;
[...]
destructor TMyFileStream.Destroy;
begin
  if Assigned(fOnDestroy) then
    fOnDestroy(Self);
  inherited Destroy;
end;

anschließend könnte dein Ereignis so aussehen:

Delphi-Quellcode:

procedure TForm1.FileStreamClosed(Sender: TObject)
begin
  //In Log schreiben: DateiStream wurde freigegeben=> Vorgang beendet
end;

procedure TForm1.IdFTPServer1RetrieveFile(ASender: TIdFTPServerThread; const AFileName: String; var VStream: TStream); 
begin 
  VStream := TMyFileStream.create(translatepath(AFilename, ASender.HomeDir), fmopenread or fmShareDenyWrite) 
  TMyFileStream(VStream).OnDestroy := FileStreamClosed;
end;

[romber]

Ich probier's mal. Dankeschön! :)