Callbackfunktion in Klasse

[Eichhoernchen]

Hey,
ich bin gerade dabei etwas mit Klassen rumzuexperimentieren, nun hab ich aber ein Problem:
Eine MMSystem Funktion will ne Callbackfunktion haben, soweit ist das ja nicht schwer, dass alles klappt wenn
ich die Callbackfunktion aus der Klasse auslager, wenn ich die Funktion z.B. als protected in die Klasse aufnehme, kann ich sie
nicht als Callbackfunktion nutzen.

Ich zeig euch mal was ich meine:

So klappt es:

Delphi-Quellcode:

procedure midiInCallback(aMidiInHandle: PHMIDIIN; aMsg: Cardinal; aData, aMidiData, aTimeStamp: integer);
begin
{...}
end;

function TSysEx.Open(const device: integer): integer;
begin
  Result := midiInOpen(@fHandle, device, Cardinal(@midiInCallback), device, CALLBACK_FUNCTION);
  {...}
end;

Da das ganze aber eine Klasse werden soll, denke ich sollte die Callbackfunktion auch in die Klasse rein, von daher hab ich das hier versucht:

Delphi-Quellcode:

  TSysEx = class(TObject)
  private
    fHandle: THandle;
    {...}
  protected
    procedure midiInCallback(aMidiInHandle: PHMIDIIN; aMsg: cardinal; aData, aMidiData, aTimeStamp: integer);
  public
    {...}
    function Open(const device: integer): integer;
    {...}
  published
    {...}
  end;


 {...}
procedure TSysEx.midiInCallback(aMidiInHandle: PHMIDIIN; aMsg: cardinal; aData, aMidiData, aTimeStamp: integer);
begin
  {...}
end;


function TSysEx.Open(const device: integer): integer;
begin
  Result := midiInOpen(@fHandle, device, Cardinal(@Self.midiInCallback), device, CALLBACK_FUNCTION);
  {...}
end;

Jetzt gibt der Compiler aber einen Fehler aus:

Delphi-Quellcode:

[Pascal Fehler] midi.pas(103): E2036 Variable erforderlich

Aber ich versteh nicht, warum das nicht klappt... gibt es da einen Trick?
Die SuFu hab ich schon bemüht, hab auch nen paar Ergebnisse gehabt, da wurde was von asm Tricks gesagt...
aber verstanden hab ich das nicht so ganz, wo genau das Problem bei der Sache liegt und wie es genau zu lösen ist.


Danke für die Antworten

Eichhoernchen

[Luckie]

Methoden einer Klasse, und das ist deine Callback-Funktion in diesem Fall, haben immer noch den unsichtbaren Self-Parameter in der Parameterliste, deswegen kann eine Methode nicht als Callback-Funktion für eine API-Funktion dienen, weil die Aufrufparameter nicht zusammenpassen.

[Eichhoernchen]

Das ist doch irgendwie blöd...
Dann würden ja alle Instanzen der Klasse die selbe Funktion aufrufen oder?

Wie soll man denn dort dann die Werte an die Klasse weitergeben?

Ich fang gerade erst mit dem Klassen Zeug an, von daher habt Einsicht für eine vielleicht dumme Frage!

[Phoenix]

Es geht, ist aber extrem Tricky.

In diesem Thread hier hatte ich damals das gleiche Problem, nämlich ein Callback auf eine Klassenmethode zu setzen. Es ging hier um Service. Unten ist meine Lösung, schau mal nach MakeProcInstance. Das ist das was Du suchst.

[Schrammel]

Der Weg ist relativ einfach, wenn die aufgerufene API-Funktion die möglichkeit bietet, einen Benutzer-definierten 32Bit-Wert zu übergeben,der an die Callback-Fukntion weitergerecht wird. Dann kannst Du folgendes machen:

- Auslagern der Callback-Funktion aus der Klasse
- Aufruf der API-Funktion mit der Adresse der zu verwendenden Klasse als Benutzer-definierter Parameter
- In der Callback-Funktion muss dann der übergebene 32-Wert auf einen Zeiger auf den Klassentyp gecastet werden und schon hast Du die die Adresse der Klasseninstanz, mit der Du arbeiten möchtest!

Achtung: Du must ggf. sicherstellen, dass die Callback-Funktion im gleichen Thread aufgerufen wird, in dem auch der Aufruf der API-Funktion erfolgte, ansonsten kann's zu blöden Fehlern kommen. Aber das ist ein anderes Thema.

Gruß

Stefan Schramm

[Luckie]

Zitat:

Zitat von Eichhoernchen

Das ist doch irgendwie blöd...
Dann würden ja alle Instanzen der Klasse die selbe Funktion aufrufen oder?

Wie soll man denn dort dann die Werte an die Klasse weitergeben?

Nein. Beispiel:

Deine Methode:

Delphi-Quellcode:

foo(bar: Integer);

Sieht für Delphi so aus:

Delphi-Quellcode:

foo(Self: TObject; bar: Integer);

Der Paramter Self enthält einen Zeiger auf die Klasse, so dass du mit

Delphi-Quellcode:

Self.DoSomething;

eine andere Methode der Klasse explizit aufrufen kannst.

[Phoenix]

In meinem Link oben wird genau dieser Self-Parameter dem Funktionsaufruf untergejubelt. Mit MakeProcInstance wird ein ausführbarer Speicherbereich erzeugt, der fest die Methode auf der betreffenden Instanz aufruft indem er diesen Self-Parameter noch zusätzlich in den Stack packt.

Anstelle der Methode selber übergibst Du als Callback-Adresse nun diesen Speicherbereich der den Rest für Dich übernimmt. Wie gesagt sehr tricky, und funktioniert getestet ab D5 bis zur Zeit einschliesslich D2006, aber immerhin tut es da ;-)

[NicoDE]

Die Frage ist nicht neu :)
Hier Hilfsfunktionen für cdecl-Callbacks (inklusive Beispiel):
http://www.delphipraxis.net/internal...=387139#387139
Zwei Beiträge weiter die entsprechenden Funktionen für stdcall.

[Eichhoernchen]

Zitat:

Zitat von Schrammel

Der Weg ist relativ einfach, wenn die aufgerufene API-Funktion die möglichkeit bietet, einen Benutzer-definierten 32Bit-Wert zu übergeben,der an die Callback-Fukntion weitergerecht wird. Dann kannst Du folgendes machen:

- Auslagern der Callback-Funktion aus der Klasse
- Aufruf der API-Funktion mit der Adresse der zu verwendenden Klasse als Benutzer-definierter Parameter
- In der Callback-Funktion muss dann der übergebene 32-Wert auf einen Zeiger auf den Klassentyp gecastet werden und schon hast Du die die Adresse der Klasseninstanz, mit der Du arbeiten möchtest!

Achtung: Du must ggf. sicherstellen, dass die Callback-Funktion im gleichen Thread aufgerufen wird, in dem auch der Aufruf der API-Funktion erfolgte, ansonsten kann's zu blöden Fehlern kommen. Aber das ist ein anderes Thema.

Gruß

Stefan Schramm

Die Methode sieht mir am einfachsten aus und ist auch möglich, ich kann nen Parameter mitsenden.
Also ruf ich dann die API-Funktion mit Cardinal(@self) auf als 32Bit wert.
Diesen bekomme ich dann in der Funktion und muss mir die klasse an der Adresse holen, geht das so?:

Delphi-Quellcode:

procedure midiInCallback(aMidiInHandle: PHMIDIIN; aMsg: uint; aData, aMidiData, aTimeStamp: integer); stdcall;
var
  klasse: ^TSysEx;
begin
  klasse := Pointer(aData); //aData ist der Parameter mit der Adresse!
  klasse^.variable := wert;
{...}
end;

//Aufruf:

midiInOpen(@fHandle, device, Cardinal(@midiInCallback), Cardinal(@self), CALLBACK_FUNCTION);

[NicoDE]

Zitat:

Zitat von Eichhoernchen

geht das so?

Ja.

Du kannst es etwas vereinfachen, da Klassenvariablen ohnehin schon Zeiger sind.

Delphi-Quellcode:

//...
var
  Klasse: TSysEx;
begin
  Klasse := TSysEx(aData);
  Klasse.Variable := Wert;
//...

midiInOpen(..., Integer(Self), ...);

Oder eine Zeile weniger

Delphi-Quellcode:

//...
var
  Klasse: TSysEx absolute aData;
begin
  Klasse.Variable := Wert;
//...

midiInOpen(..., Integer(Self), ...);