Gauge OnKlick

[Van HelF]

Hallo,
ich habe dynamisch in einer listbox gauges erstellt (eins für jeden eintrag) , das funktioniert soweit auch ganz gut, mein problem ist jetzt, wenn ich auf das gauge klicke, wird der listbox eintrag nicht markiert.
Da es beim gauge kein OnKlick event gibt, bin nich leider etwas ratlos, wie ich es sonst anstellen könnte, ich bitte um rat.

MFG
Van HelF

[elundril]

per ItemsAtPos? is mal so ne idee.

lg el

[Van HelF]

wie funtioniert das?
hab bei der suche nichts dazu gefunden.

[elundril]

Delphi-Quellcode:

Listbox1.itemsatpos({Hier musst du eine Varible vom Typ TPoint übergeben also z.b: Mouse.CursorPos});

lg el

[Van HelF]

danke für den tipp, nur hilft mir leider nicht viel weiter.
ich müsste nur irg. herausfinden, ob jemand auf das gauge klickt, und dann noch auf welches.

[elundril]

aso ups. das du das on klick suchst hab ich übersehen! :oops: sry!! ähhm programmier dir eins. mit messages.

lg el

Ps: sry nochmal!

[Van HelF]

ich habe folgendes gefunden, jedoch wird es nur bei einem klick auf das form ausgeführt, nicht bei den komponenten darauf :(

Delphi-Quellcode:

procedure LeftMouseButtonDown(var Msg : TMouseInput); message WM_LBUTTONDOWN;

[Hawkeye219]

Hi,

wäre es nicht einfacher, auf die Gauge-Controls zu verzichten und die ListBox-Einträge selbst zu zeichnen? Dazu mußt du lediglich die Eigenschaft TListBox.Style auf den Wert lbOwnerDrawFixed setzen und einen geeigneten Wert für TListBox.ItemHeight eintragen. Das Zeichnen der Elemente übernimmt eine Behandlungsroutine für das Ereignis TListBox.OnDrawItem.

Delphi-Quellcode:

// Zeichnet eine Fortschrittanzeige
procedure DrawProgress (aCanvas: TCanvas; const aRect: TRect; aPercent: Integer; 
  aText: string = '');
var
  tx, ty : Integer;
  R      : TRect;
begin
  if (aText <> '') then
    aText := aText + ' ';
  aText := aText + Format('(%d%%)', [aPercent]);
  with aCanvas do
    begin
      tx := (aRect.Left + aRect.Right - TextWidth(aText)) div 2;
      ty := (aRect.Top + aRect.Bottom - TextHeight(aText)) div 2;
      // Hintergrund (linker Teil)
      R := aRect;
      R.Right := aRect.Left + MulDiv(aRect.Right - aRect.Left, aPercent, 100);
      Brush.Color := clNavy;
      FillRect (R);
      // Text (linker Teil)
      Font.Color := clWhite;
      TextRect (R, tx, ty, aText);
      // Hintergrund (rechter Teil)
      R.Left := R.Right;
      R.Right := aRect.Right;
      Brush.Color := RGB(240, 240, 240);
      FillRect (R);
      // Text (rechter Teil)
      Font.Color := clBlack;
      TextRect (R, tx, ty, aText);
    end;
end;

procedure TForm1.FormCreate (Sender: TObject);
begin
  ListBox1.Style := lbOwnerDrawFixed;  // kann auch im OI
  ListBox1.ItemHeight := 20;           // vorgenommen werden
end;

procedure TForm1.ListBox1DrawItem (Control: TWinControl; Index: Integer;
  Rect: TRect; State: TOwnerDrawState);
begin
  with ListBox1 do
    begin
      if (odSelected in State) then
        Canvas.Brush.Color := clRed
      else
        Canvas.Brush.Color := clWindow;
      Canvas.FillRect (Rect);
      InflateRect(Rect, -2, -2);
      DrawProgress (Canvas, Rect, Integer(Items.Objects[Index]), Items[Index]);
    end;
end;

// zum Testen:
procedure TForm1.Button1Click (Sender: TObject);
begin
  with ListBox1.Items do
    AddObject(Format('item #%d', [Count + 1]), TObject(Random(100)));
end;

Gruß Hawkeye

[Van HelF]

vielen dank :thumb: