INDY-FTP optimieren?

[Svenkan]

Folgendes: Jedes Mal, wenn ich etwas hochlade, ist das Programm für diese Zeit wie eingefroren. Gibt es eine Möglichkeit, dass der Upload in der Hinsicht irgendwie optimiert werden kann? Schließlich frieren FTP-Programme beim Upload ja auch nicht ein. *g*
Deswegen würde ich gerne für den Gesamtupload eine Art 'Ladebalken' einbauen. Doch bisher hab ich nur was gefunden, wo pro Datei der Status angezeigt wird. Hab das jetzt nicht mit drin.

Delphi-Quellcode:

procedure TForm1.BtFileUploadClick(Sender: TObject);
var Ini: TIniFile;
    dirname,password,s,url,username: String;
    nr: Integer;
begin
  if OpenDialog2.Execute then
 try
    Ini:=TIniFile.Create(ExtractFilePath(ParamStr(0))+'conf.ini');
   username:=Ini.ReadString('FTP-Daten','Username','');
   password:=Ini.ReadString('FTP-Daten','Password','');
   url:=Ini.ReadString('FTP-Daten','URL','');
   dirname:=Ini.ReadString('FTP-Daten','Ordner','');

  IdFTP1.Username := username;
  IdFTP1.Password := password;
  IdFTP1.Host := url;
  IdFTP1.Connect;
  IdFTP1.ChangeDir(dirname);
  FOR nr := 0 TO OpenDialog2.Files.Count-1 DO
  begin
   s := OpenDialog2.Files[nr]; // Zwischenvariable; vereinfacht das Debugging
   IdFTP1.Put(s, ExtractFileName(s));
  end;
  IdFTP1.Quit;
   finally
    Ini.Free;
end;
end;

[hsbc]

Schau dir dazu mal OnWork, OnWorkBegin, OnWorkEnd von IdFTP an...

mfg
Herbert

[Christian Seehase]

Moin Svenkan,

gemäss Dokumentation soll man sich ja mit TidAntiFreeze behelfen können, um ein Einfrieren zu verhindern, erfahrungsgemäss fährst Du aber besser damit, wenn Du die Zugriffe in einen eigenen Thread auslagerst.

[Svenkan]

Hättest du für das Auslagern ein kleines Beispiel?

[inherited]

Pack doch einfach ein Application.ProcessMessages ins OnWork der FTP-Komponente. Dann solltest du aber auch verhindern, dass man in dieser Zeit nochmal Dateien hochlädt.

[Christian Seehase]

Moin Svenkan,

ich habe hier mal ein, stark zusammengestrichenes, Beispiel für den Download per TidHTTP.
Das müsste jetzt noch auf den FTP-Upload angepasst werden, ausserdem habe ich hier auch nur ein Beispiel drin.

Delphi-Quellcode:

uses
  Classes,IdHTTP,IdComponent;

type
  TcsDownloadThread = class(TThread)
  private
    FsURL           : string;
    FsFilepath      : string;
    FHTTP           : TidHTTP;
    FWork           : TWorkEvent;
    FWorkSender     : TObject;
    FWorkMode       : TWorkMode;
    FWorkCount      : integer;
    function GetWorkEvent: TWorkEvent;
    procedure SetWorkEvent(const Value: TWorkEvent);
    {$IFDEF VER180}
      procedure DoWork(ASender: TIdBaseObject; AWorkMode: TWorkMode;AWorkCount: Integer);
    {$ELSE}
      procedure DoWork(Sender: TObject; AWorkMode: TWorkMode;const AWorkCount: Integer);
    {$ENDIF}
    procedure SyncWork;
  public
    constructor Create(const AsURL : string;const AsFilepath : string);
    destructor Destroy; override;
    procedure Execute; override;
    property OnWork : TWorkEvent read GetWorkEvent write SetWorkEvent;
  end;

implementation
uses SysUtils,windows,csfileutils,csspecial;

constructor TcsDownloadThread.Create(const AsURL, AsFilepath: string);
begin
  inherited Create(true);
  FreeOnTerminate := false;
  FsURL           := AsURL;
  FsFilepath      := AsFilepath;
  FWork           := nil;
  FHTTP           := TIdHTTP.Create(nil);
  FHTTP.OnWork    := DoWork;
end;

destructor TcsDownloadThread.Destroy;
begin
  if FHTTP.Connected then FHTTP.Disconnect;
  FreeAndNil(FHTTP);
  inherited;
end;

{$IFDEF VER180}
  procedure TcsDownloadThread.DoWork(ASender: TIdBaseObject; AWorkMode: TWorkMode;AWorkCount: Integer);
  begin
    FWorkSender := Sender;
    FWorkMode   := AWorkMode;
    FWorkCount  := AWorkCount;
    Synchronize(SyncWork);
  end;
{$ELSE}
  procedure TcsDownloadThread.DoWork(Sender: TObject; AWorkMode: TWorkMode; const AWorkCount: Integer);
  begin
    FWorkSender := Sender;
    FWorkMode   := AWorkMode;
    FWorkCount  := AWorkCount;
    Synchronize(SyncWork);
  end;
{$ENDIF}

procedure TcsDownloadThread.Execute;

var
  ms      : TMemoryStream;
  dwStart : DWORD;

begin
  try
    try
      FHTTP.Head(FsURL);
    except
      exit;
    end;
    ms := TMemoryStream.Create;
    try
      try
        FHTTP.Get(FsURL,ms);
      except
        exit;
      end;
      ms.SaveToFile(FsFilepath);
    finally
      FreeAndNil(ms);
    end;
  finally
    if FHTTP.Connected then FHTTP.Disconnect;
    dwStart := GetTickCount;
    while FHTTP.Connected and ((GetTickCount-dwStart) < 10000) do;
    Terminate;
  end;
end;

function TcsDownloadThread.GetWorkEvent: TWorkEvent;
begin
  Result := FWork;
end;

procedure TcsDownloadThread.SetWorkEvent(const Value: TWorkEvent);
begin
  FWork := Value;
end;

procedure TcsDownloadThread.SyncWork;
begin
  if Assigned(FWork) then FWork(FWorkSender,FWorkMode,FWorkCount);
end;

[Svenkan]

Zitat:

Zitat von inherited

Pack doch einfach ein Application.ProcessMessages ins OnWork der FTP-Komponente. Dann solltest du aber auch verhindern, dass man in dieser Zeit nochmal Dateien hochlädt.

Es geht ja nicht darum, parallel mehrere verschiedene Upload-Prozesse durchzuführen, sondern in einem Rutsch halt mehrere Dateien hochzuladen. ;)

@ Christian Seehase: Dankeschön! Ich werds mir mal anschauen und gucken, ob ich da auch wohl durchblicke. ^^

[inherited]

Zitat:

Zitat von Svenkan

Zitat:

Zitat von inherited

Pack doch einfach ein Application.ProcessMessages ins OnWork der FTP-Komponente. Dann solltest du aber auch verhindern, dass man in dieser Zeit nochmal Dateien hochlädt.

Es geht ja nicht darum, parallel mehrere verschiedene Upload-Prozesse durchzuführen, sondern in einem Rutsch halt mehrere Dateien hochzuladen. ;)

:gruebel: Dann ist meine Methode doch die geeignetste oder habe ich was verpasst?

[Svenkan]

Ich habe dich so verstanden, dass du meintest, immer nur einen Dateiupload zu ermöglichen. Und das man dann immer alle einzeln machen müsste.
Oder habe ich dich da falsch verstanden?

[inherited]

Ja. Meine Methode bewirkt, dass das Programm während eines Uploads nicht hängenbleibt, sondern der Benutzer weiterarbeiten kann. Das einzige worauf du achten solltest ist, dass der Benutzer, während du noch Sachen hochlädst, nicht erneut auf "Upload" klickt.
Ich hoffe diesmal war es verständlicher.