Dateiendung mit anderem Icon registrieren

[Nils_13]

Hi,

ist es möglich mit diesem Code einer Dateiendung ein anderes Icon, als dem Icon der Applikation selbst, zuzuweisen ?
Wenn nicht vlt. mit einem anderen Code ?

[SirThornberry]

wenn du den quelltext verstanden hast solltest du die Antwort kennen! Zudem ist es nicht gerade eine Musterlösung weil zum Beispiel der Erfolg von OpenKey gar nicht geprüft wird.
Der sinn von anderen Quelltexten ist es diese zu verstehen um etwas zu lernen. Einfach nur kopieren bringt nix.

[Nils_13]

1. Sogar der "Autor" oder eher Poster des Codes konnte mir keine Auskunft geben. Der Code ist eigentlich simpel, aber diese Sache habe ich noch nicht verstanden. Wie bitte schön soll denn ein Index was anderes, außer einen ImageListen-Eintrag angeben ?
2. Willst du das OpenKey etwas mit try..execpt absichern ?
3. Mir hilft so eine Antwort auch gerade weiter -.-

[SirThornberry]

2.) Nein, OpenKey gibt aber einen Boolean zurück. Und nur wenn dieser True ist sollte man die Folgeanweisungen ausführen.

1.)
so sieht der aktuelle source aus.

Delphi-Quellcode:

RootKey := HKEY_CLASSES_ROOT; 
OpenKey(Extension, True); 
WriteString('', ExtDescription); 
CloseKey; 
OpenKey('\' + ExtDescription, True); 
WriteString('', FileDescription); 
CloseKey; 
OpenKey('DefaultIcon', True); 
WriteString('', OpenWith + ','+IntToStr(IconIndex)); 
CloseKey; 
OpenKey('\' + ExtDescription + '\Shell\Open\Command', True); 
WriteString('', '"' + OpenWith + '" "' + ParamString + '"'); 
CloseKey;

und so wärs besser

Delphi-Quellcode:

//Root zweit auf HKEY_CLASSES_ROOT setzen
RootKey := HKEY_CLASSES_ROOT; 
//Versuche den Zweig Extension zu öffnen, notfalls vorher erstellen
if OpenKey(Extension, True) then
begin
  //Standardwert des Zweiges den Wert ExtDescription zuweisen
  WriteString('', ExtDescription); 
  //Zweig schließen
  CloseKey; 
  //Versuche den Zweig ExtDescription zu öffnen, notfalls vorher erstellen
  if OpenKey('\' + ExtDescription, True) then
  begin
    //Standardwert des Zweiges auf den Wert FileDescription setzen
    WriteString('', FileDescription); 
    //Zweig schließen
    CloseKey; 
    //Versuche den Unterzweig 'DefaultIcon' zu öffnen, notfalls vorher anlegen
    if OpenKey('DefaultIcon', True) then //besser wäre: if OpenKey('\' + ExtDescription + '\DefaultIcon', True) then
    begin
      //Standardwert von DefaultIcon auf: OpenWidth + ',' + IconIndex setzen
      WriteString('', OpenWith + ','+IntToStr(IconIndex)); 
      //Zweig schließen
      CloseKey; 
      //Wieder einen Zweig öffnen und gegebenfalls erstellen
      if OpenKey('\' + ExtDescription + '\Shell\Open\Command', True) then
      begin
        //Standardwert des geöffneten Zweigs schreiben
        WriteString('', '"' + OpenWith + '" "' + ParamString + '"'); 
        //geöffneten Zweig schließen
        CloseKey;
      end;
    end;
  end;
end;

Zudem sind die Variablennamen (vor allem IconIndex) selbsterklärend benannt so das du da den Ansatz finden solltest.

hier gibts die Funktion nochmal richtig wie sie sein sollte (abgesehen von dem relativen Pfad von DefaultIcon):
http://www.delphipraxis.net/internal...=701965#701965

[Nils_13]

Ich habe mir den Code von dir angeschaut, verstanden und schließlich übernommen.

Zitat:

"IconIndex"
Dem Parameter kann ein entsprechender Index übergeben werden, der angibt, welches Icon für die Anzeige im Explorer verwendet werden soll. Der Index bezieht sich auf die Icons der verknüpften Anwendung.

Ist es etwa möglich mehrere Icons in eine Exe zu kompilieren, ich wüsste nur Ressource ? :gruebel:

[SirThornberry]

Genau, in einer Exe können mehrere Icons vorkommen. Das Icon welches du deiner Anwendung über die Projektoptionen zuordnest landet auch in den Ressourcen.

[Nils_13]

Ok und wie füge ich noch weitere Icons hinzu ? Austauschen der Ressourcedatei ?

[MrKnogge]

Du kannst entweder die Ressource-Datei mit dem mitgelieferten Res-Editor bearbeiten und weitere Icons einbinden, oder eine zusätzliche Ressourcen-Datei erzeugen.

Gruß

[bitsetter]

Hi,

ich habe den Code etwas abgeändert, dass er auch mit Icon Dateien umgehen kann.

Delphi-Quellcode:

uses Registry;

function InstallExt(Extension, ExtDescription, FileDescription,
OpenWith, ParamString, IconPfad: string; IconIndex: Integer = 0): Boolean;
var
  Reg: TRegistry;
begin
  Result := False;
  if Extension <> '' then
  begin
    if Extension[1] <> '.' then
      Extension := '.' + Extension;

    Reg := TRegistry.Create;
    try
      Reg.RootKey := HKEY_CLASSES_ROOT;
      if Reg.OpenKey(Extension, True) then
      begin
       Reg.WriteString('', ExtDescription);
       if Reg.OpenKey('\' + ExtDescription, True) then
       begin
         Reg.WriteString('', FileDescription);
         if Reg.OpenKey('DefaultIcon', True) then
         begin
           Reg.WriteString('', Format('%s,%d', [IconPfad, IconIndex]));
           if Reg.OpenKey('\' + ExtDescription + '\Shell\Open\Command', True) then
           begin
             Reg.WriteString('', Format('"%s" "%s"', [OpenWith, ParamString]));
             Result:=True;
           end;
         end;
       end;
     end;
  finally
    Reg.Free;
  end;
  end;
end;

function UnInstallExt(Extension: String): Boolean;
var
  Reg: TRegistry;
  Description: String;
begin
  Result := False;
  if Extension <> '' then
    begin
    if Extension[1] <> '.' then
      Extension := '.' + Extension;
    Reg := TRegistry.Create;
    try
      Reg.RootKey := HKEY_CLASSES_ROOT;
      if Reg.KeyExists(Extension) then
        begin
        Reg.OpenKey(Extension, false);
        Description:=Reg.ReadString('');
        Reg.CloseKey;
        if Reg.KeyExists('\'+Description) then
          Result:=Reg.DeleteKey(Extension) and Reg.DeleteKey('\' + Description);
        end;
    finally
      Reg.Free;
    end;
  end;
end;


procedure TForm1.Button1Click(Sender: TObject);
begin
if InstallExt('.aaa', 'AAADatei', 'Tolles Programm', ParamStr(0), '"%1"','c:\2.ico',0) then
   Showmessage('Dateiendung konnte erfolgreich registriert werden.');
end;

EDIT: Oder du trägst anstatt des Icones, den Pfad zu einer anderen EXE Datei ein.
Der Code arbeitet zwar mit OpenKey, aber nicht mit CloseKey.

[Nils_13]

Danke, jetzt müsste alles hinhauen.