Komponente mit Lines erstellen

[Nalincah]

wie muss ich den "type" deklarieren wenn ich sowas wie Lines haben will (Wie beim Memo). Damits verständlicher wird:

Delphi-Quellcode:

type
  TTreffpunkt = (tpBahnhof, tpBushalteStelle, tpZOB, tpTaxiStand);

Ergibt DropDownList mit den Einträgen

Delphi-Quellcode:

type
  TTreffpunkt = set of (tpBahnhof, tpBushalteStelle, tpZOB, tpTaxiStand);

Ergibt Untermenü mit den Einträgen (True/False) wie bei Font.

Wie geht das mit Lines????

[sakura]

Lines ist vom Typ TStrings oder TStringList. Damit geht es recht einfach ;-)

...:cat:...

[Nalincah]

Und wie binde ich das ein??? :freak:

[Nalincah]

Delphi-Quellcode:

type 
  FQuellFelderListe = set of TStringList;

Wenn ich das so mach sagt der:

Code:

Ordinaltyp erforderlich

[sakura]

Viel einfacher...

Delphi-Quellcode:

type
  TMeineKompo = class(TComponent)
  private
    FLines: TStringList;
    procedure SetLines(Value: TStringList);
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
    property Lines: TStringList read FLines write SetLines;
  end;

....

constructor TMeineKompo.Create(AOwner: TComponent); 
begin
  inherited;
  FLines := TStringList.Create;
end;

destructor TMeineKompo.Destroy; 
begin
  FLines.Free;
  inherited;
end;

procedure TMeineKompo.SetLines(Value: TStringList);
begin
  FLines.Assign(Value);
end;

Fertig :-)

...:cat:...