problem beim übersetzen von funktionen

[ghost007]

Hallo,
ich hab aus einem forum folgende angaben für das benutzen einer dll datei:

Zitat:

BOOL GetProductString(OUT PVOID Buffer, IN ULONG BufferLength);
--- Should give: "G15 Keyboard"

BOOL SetBgLight(IN INT value);
--- value: 0=off 1=half 2=full

BOOL SetLCDLight(IN INT value);
--- value: 0=off 1=half 2=full

BOOL SetLCDContrast(IN INT value);
--- value: the higher, the more contrast; when value exceedes 43 it is set back to 18, which is the level, the LCDMon.exe sets it to low

BOOL SetMacroKeys(IN BOOL M1, IN BOOL M2, IN BOOL M3, IN BOOL MR);
--- multiple are really possible!

INT GetLight(IN INT value);
--- value: look at values.txt

DWORD SetCallback(IN DWORD lpProc);
--- lpProc: pointer to the callback function:
--- VOID WINAPI keyProc(INT pressedKeys);

ich hab auch schon ein paar in mein delphi einbauen(übersetzen können), aber wie übersetze ich den rest?
Hier das was ich bisher hab:

Delphi-Quellcode:

procedure SetBgLight(Value:Integer);stdcall;export;external 'lglight.dll';
procedure SetLCDLight(Value:Integer);stdcall;export;external 'lglight.dll';
procedure SetMacroKeys(M1,M2,M3,MR:Boolean);stdcall;export;external 'lglight.dll';

MfG - Ghost007

[Phoenix]

Das was Du hast ist schonmal falsch. Das sind alles functions die einen Boolean zurückgeben, keine Procedures.

GetLight ist auch eine, die einen Integer zurückgibt.

SetMacroKeys gibt auch einen Boolean zurück und nimmt 4 Booleans an.

[ghost007]

hm, die 3 funktionieren aber so wie se da sind :shock: und zwar wunderbar :gruebel:

wie müsste das denn für die anderen aussehen?

MfG - Ghost007

[g0rmed]

So wie ich das sehe machst du ne Delphi-übersetztung für die G15-Tastaturfunktionen. Kannst du die vllt. als unit ins open-source stellen wenn alles fertig ist :?:

[quantum]

Die G15 ist schon ein geiles Teil. Ich liebe sie :P

Apropos, versuch es mal damit:

Delphi-Quellcode:

unit lglight;

interface

uses
  Windows;

function GetProductString(pBuffer: PChar; iBufferLength: DWORD): DWORD; stdcall; external 'lglight.dll';

//--- value: 0=off 1=half 2=full
function SetBgLight(iValue: Integer): DWORD; stdcall; external 'lglight.dll';

//--- value: 0=off 1=half 2=full
function SetLCDLight(iValue: Integer): DWORD; stdcall; external 'lglight.dll';

// --- value: the higher, the more contrast; when value exceedes 43 it is set back to 18, which is the level, the LCDMon.exe sets it to low
function SetLCDContrast(iValue: Integer): DWORD; stdcall; external 'lglight.dll';

//--- multiple are really possible!
function SetMacroKeys(M1, M2, M3, MR: DWORD): DWORD; stdcall; external 'lglight.dll';

function GetLight(iValue: Integer): Integer; stdcall; external 'lglight.dll';

//--- lpProc: pointer to the callback function:
//--- VOID WINAPI keyProc(INT pressedKeys);
function SetCallback(pValue: Pointer): DWORD; stdcall; external 'lglight.dll';

implementation

end.

[ghost007]

hi,
sehr schön :) danke aber eins versteh ich nicht.
Was bringt die letzte funktion?

MfG - Ghost007

[ghost007]

*PUSHÜ

[shmia]

kleine Verbesserung:

Delphi-Quellcode:

uses 
  Windows; 
const LGLIGHT_DLL='lglight.dll';  // <==== hier kann man zentral den Namen der DLL angeben
function GetProductString(pBuffer: PChar; iBufferLength: DWORD): DWORD; stdcall; external LGLIGHT_DLL; 
...

Mit SetCallback kann dein Programm sich über Tastendrücke informieren lassen:

Delphi-Quellcode:

procedure KeyProc(pressedKeys:integer);stdcall;
begin
   if Assigned(Form1) then
      Form1.MemoPressedKeys.Add(intToStr(pressedKeys));
end;
....

   SetCallback(@KeyProc);  // hier müsste man noch den Returnwert von SetCallback auswerten

[ghost007]

danke :)
funktioniert wunderbar

MfG - Ghost007