Schnellerer Zugriff als Bitmap.Canvas.Pixels

[Alex_ITA01]

Hallo zusammen,
ich habe eine Frage zu der Eigenschaft Bitmap.Canvas.Pixels.

Ich erstelle mir zur Laufzeit ein Bitmap, welches ich durch ein übergebenes Array of Byte bearbeite (das heißt, ich setze Pixel für Pixel in dem Bitmap anhand des Array's).

Mein Code ist folgender:

Delphi-Quellcode:

  Bmp        := TBitmap.Create;
  Bmp.Width  := 1024;
  Bmp.Height := 768;
  Bmp.Pixelformat := pf32bit;

  for i := 0 to Bmp.Width-1 do
  begin
    for j := 0 to Bmp.Height-1 do
    begin
      Bmp.Canvas.Pixels[i,j] := clBlack; //<--- nur ein Test
    end;
  end;

  Bmp.SaveToFile('C:\Test.bmp');

Da ich erfahren habe, dass SaveToFile nicht Threadsicher ist, habe ich diese Funktion in einem Formular ausgelagert. Meine Frage ist jetzt, ob es eine schnellere Version gibt, um ein Bitmap Pixelweise zu füllen...
Eventuell non VCL?

MFG Alex

[SirThornberry]

mit Bitmap.Scanline kannst du dir einen Pointer auf die Bitmap-Daten holen

[Alex_ITA01]

Die Bitmap Daten nützen mir nichts. Ich "fülle" ja das Bitmap.
Es gibt nur die Daten in meinem Array und dieses muss ich dann auf das Bitmap umsetzen.

MFG Alex

[SirThornberry]

doch, genau das ist das was du brauchst. Wenn du einen Pointer auf die Bitmap-Daten (=Speicher des Bitmaps) hast kannst du dein Array an diese Stelle im Speicher kopieren.

[Alex_ITA01]

Achso, aber so wie ich mir ScanLine angeguckt habe, ist es immer für eine Zeile.
Ich habe doch aber mehrere verschiedene Farben (Pixel) in einer Zeile. Wie geht das dann?

MFG Alex

[SirThornberry]

Scanline gibt dir einen Pointer auf den Anfang der Zeile zurück. Wenn du den Pointer weiter rückst kommst du zum nächsten Pixel.
Eine Zeile sieht wie folgt aus:
Pixel1|Pixel2|Pixel3|...

Bei 32bit-Bitmaps ist ein Pixel 4 Byte groß.
Mit

Delphi-Quellcode:

ScanlineResult := Pointer(Cardinal(ScanlineResult) + 4);

setzt du den Pointer also auf das nächste Pixel.

es gibt auch einige gute Beispiele wo du nicht den Pointer weiterrücken musst sondern mit Arrays arbeitest.

[Alex_ITA01]

ok habe ich verstanden. werde es mir gleich mal angucken.
meinst du beispiele hier in der delphipraxis?

MFG Alex

[Muetze1]

Zitat:

Zitat von Alex_ITA01

Achso, aber so wie ich mir ScanLine angeguckt habe, ist es immer für eine Zeile.
Ich habe doch aber mehrere verschiedene Farben (Pixel) in einer Zeile. Wie geht das dann?

Du bekommst den Zeiger auf eine Zeile Pixeldaten. Die Pixeldaten sind dabei unterschiedlich aufgebaut, abhängig von dem eingestellten PixelFormat (siehe TBitmap.PixelFormat). Bei pf32bit zeigt der Zeiger auf TBitmap.Width mal eine Struktur vom Typ TRGBQuad (also R, G, B + Reserved). Bei pf24bit auf TBitmap.Width mal eine Struktur vom Typ TRGBTriple, etc.

Es ist zu empfehlen, das PixelFormat auf pf32bit zu setzen und mit einem PRGBQuad zu arbeiten. Dies ist deutlich performanter.

Beispiel:

Delphi-Quellcode:

var
  lPixel: PRGBQuad;
begin
  Bmp := TBitmap.Create;
  try
    Bmp.Width  := 1024;
    Bmp.Height := 768;
    Bmp.Pixelformat := pf32bit;

    for i := 0 to Bmp.Height-1 do
    begin
      lPixel := Bmp.ScanLine[i];    // Zeiger auf die Zeile holen

      for j := 0 to Bmp.Width-1 do
      begin
          // Pixel Farbwerte zuweisen.
        lPixel.rgbRed := $ff;
        lPixel.rgbGreen := $44;
        lPixel.rgbBlue := $77; 

        Inc(lPixel);    // auf zum nächsten Pixel 
      end;
    end;

    Bmp.SaveToFile('C:\Test.bmp');
  finally
    Bmp.Free;
  end;
end;

/EDIT: roter Kasten? Hätte ich mir ja klemmen können...

[Alex_ITA01]

Danke fürs Beispiel. Werde es gleich mal testen.
MFG Alex

[Alex_ITA01]

Achso, ist Scanline auch schneller als Pixels?

MFG Alex