Kontrast von einem Bitmap erhöhen

[axelf98]

Hallo,

ich habe schon gesucht und leider nichts dazu gefunden: Ich würde gerne den Kontrastwert eines TBitmap erhöhen können, am besten mit einer Funktion (keine Komponente)..

Danke für eure Tipps!

[patti]

Zitat:

Um den Kontrast eines Bitmaps zu erhöhen bzw. verringern bringen wir erst einmal alle Farbwert auf den gleichen Wert, indem wir sie zunächst in Integer-Variablen umwandeln und dann 128 abziehen. Die Ergebnisse multiplizieren wir dann mit einem Konstanten Wert. Dieser wird als Parameter in unserer Prozedur angegeben. Nachfolgend wird die Nominierung der Farbwerte durch eine Addition von 128 wieder aufgehoben. Damit wir nicht jedes Pixel einzeln bearbeiten müssen, verwenden wir ein Array, in dem wir die Farbwerte vorberechnen.

Zuerst ist folgende Typenvereinbarung erforderlich:

Delphi-Quellcode:

type
  TRGBArray = array[0..0] of TRGBTriple;
  pRGBArray = ^TRGBArray;

Dies ist der Code:

Delphi-Quellcode:

procedure Kontrast(const Bitmap: TBitmap; value: byte);
var x,y,k: integer;
    Ziel,Quelle: ^TRGBTriple;
    Farbarray: array[0..255] of byte;
    faktor: single;
begin
  faktor := 1 + value /100;
  for x := 0 to 255 do
  begin
    k := Round((integer(x) - 128)*faktor) + 128;
    if k > 255 then Farbarray[x] := 255
    else
    if k < 0 then Farbarray[x] := 0
    else Farbarray[x] := k;
  end;
  for y := 0 to Bitmap.Height-1 do
  begin
    Ziel   := Bitmap.Scanline[y];
    Quelle := Bitmap.Scanline[y];
    for x := 0 to (Bitmap.Width-1) do
     begin
      Ziel^.rgbtred   := Farbarray[Quelle^.rgbtred];
      Ziel^.rgbtblue  := Farbarray[Quelle^.rgbtblue];
      Ziel^.rgbtgreen := Farbarray[Quelle^.rgbtgreen];
      inc(ziel);
      inc(quelle);
     end;
  end;
end;

Ein Aufruf sähe zum Beispiel aus:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
begin
  Kontrast(Image1.Picture.Bitmap,55);
  Image1.Repaint;
end;

Ist vom Easy Delphi Helper ;-)

P@Tti

[axelf98]

Danke schön klappt wunderbar!