AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Zeilen in einem String zählen

Ein Thema von lbccaleb · begonnen am 8. Mai 2012 · letzter Beitrag vom 9. Mai 2012
Antwort Antwort
Seite 1 von 3  1 23   
Benutzerbild von lbccaleb
lbccaleb

Registriert seit: 25. Mai 2006
Ort: Rostock / Bremen
2.037 Beiträge
 
Delphi 7 Enterprise
 
#1

Zeilen in einem String zählen

  Alt 8. Mai 2012, 16:25
Gefunden habe ich erstmal das:

http://www.delphipraxis.net/51285-ze...trahieren.html

Das ist so schon ganz fein, allerdings Blick ich den Code noch nicht 100%ig.
Ich habe es so umgemodelt:

Delphi-Quellcode:
function CountStringLines(const S: AnsiString): Integer;
var i, i2, i3, i4: Integer;
  begin;
    Result := 0;
    i := 1; i2 := 1; i3 := 1;
    while i <= Length(S) do begin
      if i2 <= i then begin i2 := PosEx(#13, S, i); if i2 = 0 then i2 := Length(S) + 1; end;
      if i3 <= i then begin i3 := PosEx(#10, S, i); if i3 = 0 then i3 := Length(S) + 1; end;
      if i2 < i3 then i4 := i2 else i4 := i3;

      i := i4;
      if (i <= Length(S)) and (S[i] = #13) Then Inc(i);
      if (i <= Length(S)) and (S[i] = #10) Then Inc(i);
      Inc(Result);
    end;
  end;
Das scheint erstmal so zu funktionieren, wie es soll.
Nun ist mein Problem eigenltich nur, ob man es so machen kann wie ich es Umgebaut hab. Nicht das in bestimmten Fällen irgendwas unvorhergesehenes passiert, da ich nicht wirklich weis, was ich da getan hab muss ich zugeben

Vllt kann himitsu ja dazu was genaueres sagen
Martin
MFG Caleb
TheSmallOne (MediaPlayer)
Die Dinge werden berechenbar, wenn man die Natur einer Sache durchschaut hat (Blade)
  Mit Zitat antworten Zitat
Benutzerbild von p80286
p80286

Registriert seit: 28. Apr 2008
Ort: Stolberg (Rhl)
6.659 Beiträge
 
FreePascal / Lazarus
 
#2

AW: Zeilen in einem String zählen

  Alt 8. Mai 2012, 16:35
Wenn in Deinem String Kein CRLF vorhanden ist, dann bekommt i4 keinen Wert, und das könnte unangenehm werden.

Und ich würde die vielen Is mit etwas aussagekräftigeren Namen versehen.

Gruß
K-H
Programme gehorchen nicht Deinen Absichten sondern Deinen Anweisungen
R.E.D retired error detector
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.533 Beiträge
 
Delphi 11 Alexandria
 
#3

AW: Zeilen in einem String zählen

  Alt 8. Mai 2012, 16:37
Mehrere Befehle in einer Zeile sind ja auch nicht der Hit im Bezug auf Lesbarkeit.
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Benutzerbild von p80286
p80286

Registriert seit: 28. Apr 2008
Ort: Stolberg (Rhl)
6.659 Beiträge
 
FreePascal / Lazarus
 
#4

AW: Zeilen in einem String zählen

  Alt 8. Mai 2012, 16:41
[OT]
Du kennst doch bestimmt noch die Zeitungen, die ein komplettes TP-Programm als 4 Zeiler abgedruckt haben? [/OT]

Gruß
K-H
Programme gehorchen nicht Deinen Absichten sondern Deinen Anweisungen
R.E.D retired error detector
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.533 Beiträge
 
Delphi 11 Alexandria
 
#5

AW: Zeilen in einem String zählen

  Alt 8. Mai 2012, 16:44
[OT] 1 Kilo Byte? Kenn ich noch [/OT]
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Klaus01

Registriert seit: 30. Nov 2005
Ort: München
5.752 Beiträge
 
Delphi 10.4 Sydney
 
#6

AW: Zeilen in einem String zählen

  Alt 8. Mai 2012, 16:47
.. sollte das Problem denn nicht auch mit einer TStringList zu erschlagen sein.

Delphi-Quellcode:
function CountStringLines(const S: AnsiString): Integer;
var
  sl: TStringList; // nachträglich eingefügt
begin
  result := 0;
  sl := TStringList.create;
  try
    sl.Text := s;
    result := sl.count;
  finally
    sl.free;
  end;
end;
Klaus

Geändert von Klaus01 ( 8. Mai 2012 um 17:24 Uhr)
  Mit Zitat antworten Zitat
Iwo Asnet

Registriert seit: 11. Jun 2011
313 Beiträge
 
#7

AW: Zeilen in einem String zählen

  Alt 8. Mai 2012, 17:13
Oder den hier
Delphi-Quellcode:
Function CountCRLF (Const aString : String) : Integer;
Var
  i : Integer;
Begin
  Result := 0;
  For i:=1 to Length(aString)-1 do
    if (aString[i]=#13) and (aString[i+1]=#10) then
      inc(Result);
End;
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.014 Beiträge
 
Delphi 12 Athens
 
#8

AW: Zeilen in einem String zählen

  Alt 8. Mai 2012, 17:22
Du hast deine Variablendeklaration vergessen, aber notfalls kann man auch die Variable einfach weglassen.
Delphi-Quellcode:
function CountStringLines(const S: String): Integer;
begin
  with TStringList.Create do
    try
      Text := S;
      Result := Count;
    finally
      Free;
    end;
end;

function CountStringLines(const S: String): Integer;
begin with TStringList.Create do try Text:=S; Result:=Count; finally Free; end; end;
Aber wenn es auf Geschwindigkeit und Speicherverbraucht drauf ankommt, dann geht der Trick mit der Stringliste nicht wirklich,
denn da mußt du mit einigen Speicheroperationen (speicher für die Liste und vorallem die Strings reservieren + Freigeben) und dazu ist mit mindestens nochmals 100% des Stringsspeichers zu rechnen. (bei einem TStream als Quelle anstatt einem String, sogar mit locker zusätzlichen 300%)

Delphi-Quellcode:
function CountLines(const S: string): Integer;
var
  P: PChar;
begin
  if S <> 'then begin
    Result := 1;
    P := PChar(S);
    while P^ <> #0 do begin
      if P^ = #13 then begin
        Inc(Result);
        if (P + 1)^ = #10 then
          Inc(P);
      end else if P^ = #10 then
        Inc(Result);
      Inc(P);
    end;
  end else
    Result := 0;
end;
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests

Geändert von himitsu ( 8. Mai 2012 um 17:30 Uhr)
  Mit Zitat antworten Zitat
Klaus01

Registriert seit: 30. Nov 2005
Ort: München
5.752 Beiträge
 
Delphi 10.4 Sydney
 
#9

AW: Zeilen in einem String zählen

  Alt 8. Mai 2012, 17:27
Du hast deine Variable vergessen.
habe ich eingefügt, danke.

Aber wenn es auf Geschwindigkeit und Speicherverbraucht drauf ankommt, dann geht der Trick mit der Stringliste nicht wirklich,
denn da mußt du mit einigen Speicheroperationen (speicher für die Liste und vorallem die Strings reservieren + Freigeben) und dazu ist mit mindestens nochmals 100% des Stringsspeichers zu rechnen. (bei einem TStream als Quelle anstatt einem String, sogar mit locker zusätzlichen 300%)
stimme ich Dir zu, aber schön lesbar ist es mit der StringList schon.

Grüße
Klaus
Klaus
  Mit Zitat antworten Zitat
Benutzerbild von Aphton
Aphton

Registriert seit: 31. Mai 2009
1.198 Beiträge
 
Turbo Delphi für Win32
 
#10

AW: Zeilen in einem String zählen

  Alt 8. Mai 2012, 17:31
Ich persönlich finde es absolut hässlich, auch wenn es unheimlich gut lesbar ist! Es ist, so wie Himitsu es beschrieben hat, zu ressourcenlästig!
das Erkennen beginnt, wenn der Erkennende vom zu Erkennenden Abstand nimmt
MfG
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 3  1 23   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 15:13 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz