AGB  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

TCollection & TCollectionitem Tutorial

Ein Thema von MrBrown90 · begonnen am 7. Nov 2017 · letzter Beitrag vom 16. Nov 2017
Antwort Antwort
Seite 2 von 9     12 34     Letzte » 
MrBrown90

Registriert seit: 7. Nov 2017
39 Beiträge
 
#11

AW: TCollection & TCollectionitem Tutorial

  Alt 8. Nov 2017, 11:25
Ok, ich hab hier ein Beispiel von embarcadero:
Delphi-Quellcode:
procedure TForm1.Button1Click(Sender: TObject);
var
  PanelIndex : Integer;
begin
  with StatusBar1 do
  begin
    Panels.BeginUpdate;
    PanelIndex := StatusBar1.Panels.Count - 1;
    try
      Panels.Add;
      Inc(PanelIndex);
      Panels.Items[PanelIndex].Text :=
         'Panel' + IntToStr(PanelIndex);
    finally
      Panels.EndUpdate;
    end;
  end;
end;
Was ich nicht verstehe, wenn ich Panels.Add Aufrufe...muss ich da kein Parameter übergeben?

Geändert von TBx ( 8. Nov 2017 um 11:27 Uhr) Grund: Delphi-Tags eingefügt, nächstes ;Mal bitte selber machen. MfG TBx
  Mit Zitat antworten Zitat
MrBrown90

Registriert seit: 7. Nov 2017
39 Beiträge
 
#12

AW: TCollection & TCollectionitem Tutorial

  Alt 8. Nov 2017, 11:28
@der schöne Günther...das ist die ganze aufgabenbeschreibung
  Mit Zitat antworten Zitat
TiGü

Registriert seit: 6. Apr 2011
Ort: Berlin
1.334 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#13

AW: TCollection & TCollectionitem Tutorial

  Alt 8. Nov 2017, 11:28
Was ich nicht verstehe, wenn ich Panels.Add Aufrufe...muss ich da kein Parameter übergeben?
Nein, das ist eine Methode, die ein Item erzeugt und in die Liste automatisch einträgt und wenn man lustig ist, kann man die entstandene Instanz auch nach als Rückgabewert haben.
Wie immer hilft ein Blick in den Quelltext:

Delphi-Quellcode:
function TCollection.Add: TCollectionItem;
begin
  Result := FItemClass.Create(Self);
  Added(Result);
end;
  Mit Zitat antworten Zitat
TiGü

Registriert seit: 6. Apr 2011
Ort: Berlin
1.334 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#14

AW: TCollection & TCollectionitem Tutorial

  Alt 8. Nov 2017, 11:30
Wenn du Unterklassen bilden sollst die von TCollection und TCollectionItem ableiten sollen dann macht das natürlich Sinn, ist aber ehrlich gesagt auch nicht ganz trivial (finde ich). Ist dem so? Ich finde das aus
Zitat:
Die konkrete Aufgabe lautet:
A component that organized Tür Threads ans their outputs
a:Use TCollection with its methods "Changed" and "Update ".


Ich habe bereits eine Class von TCollection und Tcollectionitem erstellt.
immer noch etwas schwer herauszulesen.
@der schöne Günther...das ist die ganze aufgabenbeschreibung
Was der Schöne meint ist wohl eher, das so Sachen wie "Tür Threads ans" und "a:Use" irgendwie ein bisschen kryptisch sind.
  Mit Zitat antworten Zitat
MrBrown90

Registriert seit: 7. Nov 2017
39 Beiträge
 
#15

AW: TCollection & TCollectionitem Tutorial

  Alt 8. Nov 2017, 11:36
Oh habe ich übersehen, muss leider mit dem Handy tippen.

A component that organized the Threads and their Output

a: Use TCollection with its methods "Changed" and "Update"
  Mit Zitat antworten Zitat
MrBrown90

Registriert seit: 7. Nov 2017
39 Beiträge
 
#16

AW: TCollection & TCollectionitem Tutorial

  Alt 8. Nov 2017, 11:42
Also wird mit der Update Methode einfach ein neues Item erzeugt und an die letzte Stelle der Liste eingefügt?
  Mit Zitat antworten Zitat
TiGü

Registriert seit: 6. Apr 2011
Ort: Berlin
1.334 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#17

AW: TCollection & TCollectionitem Tutorial

  Alt 8. Nov 2017, 11:44
Also wird mit der Update Methode einfach ein neues Item erzeugt und an die letzte Stelle der Liste eingefügt?
Mit der ADD-Methode...sonst quasi ja!
  Mit Zitat antworten Zitat
TiGü

Registriert seit: 6. Apr 2011
Ort: Berlin
1.334 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#18

AW: TCollection & TCollectionitem Tutorial

  Alt 8. Nov 2017, 11:47
Oh habe ich übersehen, muss leider mit dem Handy tippen.

A component that organized the Threads and their Output

a: Use TCollection with its methods "Changed" and "Update"
Was denn für Threads und wie ist der Output definiert?
  Mit Zitat antworten Zitat
TiGü

Registriert seit: 6. Apr 2011
Ort: Berlin
1.334 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#19

AW: TCollection & TCollectionitem Tutorial

  Alt 8. Nov 2017, 11:53
Probiere das folgende Konsolenprogramm mal aus, vielleicht hilft dir das weiter:

Delphi-Quellcode:
program Project3;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils, System.Classes;

type
  TMyCollectionItem = class(TCollectionItem)
  private
    // hier kannst du auch eigene Felder und Methoden definieren
  protected
    function GetDisplayName: string; override;
  end;

  TMyCollection = class(TCollection)
  protected
    procedure Update(Item: TCollectionItem); override;
    procedure SetItemName(Item: TCollectionItem); override;
    procedure Notify(Item: TCollectionItem; Action: TCollectionNotification); override;
  public
    procedure BeginUpdate; override;
    procedure EndUpdate; override;
  end;

procedure TMyCollection.BeginUpdate;
begin
  inherited;
  Writeln('BeginUpdate');
end;

procedure TMyCollection.EndUpdate;
begin
  inherited;
  Writeln('EndUpdate');
end;

procedure TMyCollection.Notify(Item: TCollectionItem; Action: TCollectionNotification);
begin
  inherited;
  case Action of
    cnAdded: Writeln(Item.DisplayName + ' added');
    cnExtracting:
      Writeln(Item.DisplayName + ' extracing');
    cnDeleting:
      Writeln(Item.DisplayName + ' deleting');
  end;
end;

procedure TMyCollection.SetItemName(Item: TCollectionItem);
begin
  inherited;
   Writeln(Item.DisplayName + ' ItemName');
end;

procedure TMyCollection.Update(Item: TCollectionItem);
begin
  inherited;
  if Assigned(Item) then
  begin
    // Ein einzelnes Item wurde befummelt
    Writeln(Item.DisplayName + ' updated');
  end else
    // wenn Item = nil, dann ist die ganze Collection betroffen

end;

function TMyCollectionItem.GetDisplayName: string;
begin
  Result := 'HuiBui: ' + IntToStr(Self.ID);
end;

procedure Main;
var
  MyCollection: TMyCollection;
  MyItem: TCollectionItem;
  I: Integer;
  Something: string;
begin
  MyCollection := TMyCollection.Create(TMyCollectionItem);
  try
    MyCollection.BeginUpdate;
    try
      for I := 0 to 10 - 1 do
      begin
        MyItem := MyCollection.Add;
      end;
    finally
      MyCollection.EndUpdate;
    end;

    Something := '';
    for I := 0 to MyCollection.Count - 1 do
    begin
      MyItem := MyCollection.Items[I];
      Something := Something + MyItem.DisplayName + ' ';
    end;

    Writeln(Something);

    MyCollection.Items[5].DisplayName := 'asdf';

    MyCollection.Delete(5);
  finally
    MyCollection.Free;
  end;
end;

begin
  try
    Main;
    Readln;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

end.
  Mit Zitat antworten Zitat
MrBrown90

Registriert seit: 7. Nov 2017
39 Beiträge
 
#20

AW: TCollection & TCollectionitem Tutorial

  Alt 8. Nov 2017, 11:58
Okay super, vielen danke ..das nehm ich mir jetzt mal genau unter die Lupe.


Create and destroy Threads
Start and Stop Threads
Configure the thread interval
Print the Output of the Threads


Aber mit Threads hatte ich echt noch nie etwas zu tun, deswegen hab ich das erstmal hinten angestellt
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 07:37 Uhr.
Powered by vBulletin® Copyright ©2000 - 2017, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2017 by Daniel R. Wolf