Mehrere Listboxen zusammen scrollen

[DeddyH]

Ich habe einmal ein Minimalbeispiel erstellt (nur ein Formular mit 2 Listboxen, es wird auch nur das vertikale Scrollen ausgewertet):

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TListBox = class(StdCtrls.TListBox)
  private
    FChildListBox: TListBox;
    procedure WMVScroll(var Msg: TMessage); message WM_VSCROLL;
  public
    property ChildListBox: TListBox read FChildListBox write FChildListBox;
  end;

  TForm1 = class(TForm)
    ListBox1: TListBox;
    ListBox2: TListBox;
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TListBox }

procedure TListBox.WMVScroll(var Msg: TMessage);
begin
  inherited;
  if Assigned(FChildListBox) then
    SendMessage(FChildListBox.Handle,Msg.Msg,Msg.WParam,Msg.LParam);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ListBox1.ChildListBox := ListBox2;
end;

end.

[edit] Sollen die Listboxen allerdings wechselseitig scrollen, sind ein paar Verrenkungen nötig (siehe Beispiel bei den Schweizern). [/edit]