Hi,

wenn man mit der rechten Maustaste auf einen Title in einem DBGrid klickt, soll zum angeklickten Titel ein Popup-Menü erscheinen.
Das Problem ist, das im onTitleBtnClick die rechte maustaste überhaupt nicht abgefragt wird, und im onTitleClick der TMouseButton nicht übergeben wird.

Ich hab dann probiert, im onMouseDown bzw. onMouseUp zu prüfen, welche Mousebutton geddrückt wurde und das in einer Variablen zu speichern, funktioniert aber auch nicht wirklich, da die nicht gefeuert werden, wenn man auf nen Title klickt.. :/

Kann mir da einer weiterhelfen?
Danke,
gruß ben

Moin moin,
wirklich weiter helfen vielleicht nicht, aber einen Ansatz geben?!

zusammenfalten · markieren

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Grids, DBGrids;

type
  TMyDBGrid = class(TDBGrid)
  private
    FOnTitleRightClick: TDBGridClickEvent;
  protected
    procedure TitleRightClick(Column: TColumn); dynamic;
    procedure MouseUp(Button: TMouseButton; Shift: TShiftState;
      X, Y: Integer); override;
    property OnTitleRightClick: TDBGridClickEvent read FOnTitleRightClick write FOnTitleRightClick;
  end;

  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
    MyDBGrid1: TMyDBGrid;
    procedure MyTitleClick(Column: TColumn);
    procedure MyTitleRightClick(Column: TColumn);
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TMyDBGrid.MouseUp(Button: TMouseButton; Shift: TShiftState;
      X, Y: Integer);
var
  Cell: TGridCoord;
begin
  inherited MouseUp(Button, Shift, X, Y);
  Cell := MouseCoord(X,Y);
  if (Button = mbright) and (Cell.X >= IndicatorOffset) and (Cell.Y = 0) then
    TitleRightClick(Columns[RawToDataColumn(Cell.X)]);
end;

procedure TMyDBGrid.TitleRightClick(Column: TColumn);
begin
  if Assigned(FOnTitleRightClick) then FOnTitleRightClick(Column);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  MyDBGrid1 := TMyDBGrid.Create(Self);
  MyDBGrid1.Parent := Self;
  with MyDBGrid1.Columns.Add do
    Title.Caption := 'Test1';
  with MyDBGrid1.Columns.Add do
    Title.Caption := 'Test2';
  MyDBGrid1.OnTitleClick := MyTitleClick;
  MyDBGrid1.OnTitleRightClick := MyTitleRightClick;
end;

procedure TForm1.MyTitleClick(Column: TColumn);
begin
  ShowMessage('Links - ' + Column.Title.Caption);
end;

procedure TForm1.MyTitleRightClick(Column: TColumn);
begin
  ShowMessage('Rechts - ' + Column.Title.Caption);
end;

end.

Moin!

1000 dank für deine ausführliche Antwort - hat mir sogar SEHR weitergeholfen
Hab mit deinem Code jetzt ein erweiteres DBGrid erstellt, das mir das TitleRightClick-event zu verfügung stellt.

zusammenfalten · markieren

Delphi-Quellcode:

unit JvDbGridTitleClick;

interface

uses
  SysUtils, Classes, Controls, Grids, DBGrids, JvExDBGrids, JvDBGrid;

type
  TJvDbGridTitleClick = class(TJvDBGrid)
  private
    { Private declarations }
    FOnTitleRightClick: TDBGridClickEvent;
  protected
    { Protected declarations }
  public
    { Public declarations }
    procedure TitleRightClick(Column: TColumn); dynamic;
    procedure MouseUp(Button: TMouseButton; Shift: TShiftState;
      X, Y: Integer); override;
  published
    { Published declarations }
    property OnTitleRightClick: TDBGridClickEvent read FOnTitleRightClick write FOnTitleRightClick;
  end;

procedure Register;

implementation

procedure TJvDbGridTitleClick.MouseUp(Button: TMouseButton; Shift: TShiftState;
      X, Y: Integer);
var
  Cell: TGridCoord;
begin
  inherited MouseUp(Button, Shift, X, Y);
  Cell := MouseCoord(X,Y);
  if (Button = mbright) and (Cell.X >= IndicatorOffset) and (Cell.Y = 0) then
    TitleRightClick(Columns[RawToDataColumn(Cell.X)]);
end;

procedure TJvDbGridTitleClick.TitleRightClick(Column: TColumn);
begin
  if Assigned(FOnTitleRightClick) then FOnTitleRightClick(Column);
end;

procedure Register;
begin
  RegisterComponents('Samples', [TJvDbGridTitleClick]);
end;

end.