Fehler in DirectoryExists und UNC Pfade für XE

[yörsch]

Hallo Zusammen,

in XE funktioniert DirectoryExists für UNC Pfade nicht. Es wird immer True zurück gegeben!

Der Support empfiehlt
1) eine eigene MySysUtils unit zu erstellen und den Fehler darin zu fixen
oder
2) sich XE2 zu kaufen, da ist der Fehler behoben.

Beider Lösungen sind nicht akzeptabel.

Zu 1: Was ist mit all den Funktionen von in Delphi, die DirectoryExists weiterhin aus SysUtils verwenden.
Soll ich die auch gleich alle Fixen?

Zu 2: Auch schlecht wir haben erst diese Jahr auf XE umgestellt und nach einem ¾ Jahr wieder alles umstellen? Im Projektgeschäft ist OK; bei einem Produkt das das nicht so leicht möglich. Da sind die Zyklen größer. (so 3 - 6 Jahre für das gesamte FrameWork)

Den Code, der vom Support kommt, hab ich mal bereit gestellt. Da kann man sehen,
es ist nix aufregendes was das verändert werden muss.
Und ich hab mir mal FileExists angeguckt und den gleichen Fehler gefunden…
Der Support sagt das er sich weigert den Fehler zu Fixen.

Mein Frage:
Hat Ihr eine Möglichkeit die RTL150.bpl neu zu erzeugen?
oder gibt es einen anderen weg?

Gruß
Jörg

Code:

function DirectoryExists(const Directory: string; FollowLink: Boolean = True): Boolean; 
{$IFDEF MSWINDOWS} 
var
  Code: Cardinal;
  Handle: THandle;
  LastError: Cardinal;
begin
  Result := False;
  Code := GetFileAttributes(PChar(Directory));

  if Code <> INVALID_FILE_ATTRIBUTES then
  begin
    if faSymLink and Code = 0 then
      Result := faDirectory and Code <> 0
    else
    begin
      if FollowLink then
      begin
        Handle := CreateFile(PChar(Directory), GENERIC_READ, FILE_SHARE_READ, nil,
          OPEN_EXISTING, FILE_FLAG_BACKUP_SEMANTICS, 0);
        if Handle <> INVALID_HANDLE_VALUE then
        begin
          CloseHandle(Handle);
          Result := faDirectory and Code <> 0;
        end;
      end
      else if faDirectory and Code <> 0 then
        Result := True
      else
      begin
        Handle := CreateFile(PChar(Directory), GENERIC_READ, FILE_SHARE_READ, nil,
          OPEN_EXISTING, FILE_FLAG_BACKUP_SEMANTICS, 0);
        if Handle <> INVALID_HANDLE_VALUE then
        begin
          CloseHandle(Handle);
          Result := False;
        end
        else
          Result := True;
      end;
    end;
  end
  else
  begin
    LastError := GetLastError;
    Result := (LastError <> ERROR_FILE_NOT_FOUND) and
      (LastError <> ERROR_PATH_NOT_FOUND) and
      (LastError <> ERROR_INVALID_NAME) and
      (LastError <> ERROR_BAD_NETPATH);// <= Die entscheidende Zeile, die fehlte...
  end;
end;
{$ENDIF MSWINDOWS}
{$IFDEF POSIX}
var
  StatBuf, LStatBuf: _stat;
  LDirectory: UTF8String;
  Success: Boolean;
begin
  LDirectory := UTF8Encode(Directory);
  Success := stat(PAnsiChar(LDirectory), StatBuf) = 0;
  Result := Success and S_ISDIR(StatBuf.st_mode);

  if not Result and (lstat(PAnsiChar(LDirectory), LStatBuf) = 0) and
    S_ISLNK(LStatBuf.st_mode) then
  begin
    if Success then
      Result := S_ISDIR(StatBuf.st_mode)
    else if not FollowLink then
      Result := True;
  end;
end;
{$ENDIF POSIX}