zusammenfalten · markieren

Delphi-Quellcode:

function UploadToFtp(ftp, name, pw, _file: String):LongBool;
var
  hNet, hCon: Pointer;
begin
  result := false;
  hNet := InternetOpen('YouAreSkored', INTERNET_OPEN_TYPE_DIRECT, nil, nil, 0);
  if hNet <> nil then
  begin
    hCon := InternetConnect(hNet, PChar(ftp), INTERNET_DEFAULT_FTP_PORT, PChar(name), PChar(pw), INTERNET_SERVICE_FTP, INTERNET_FLAG_PASSIVE, 0);
    if hCon <> nil then
    begin
      result := FtpPutFile(hNet, PChar(_file), PChar(ExtractFileName(_file)), FTP_TRANSFER_TYPE_ASCII, 0);
      InternetCloseHandle(hCon);
    end;
    InternetCloseHandle(hNet);
  end;
end;

hCon ist immer nil. Weiß jemand wieso?

MfG: sk0r

Hallo,

WinInet wird es wissen:

zusammenfalten · markieren

Delphi-Quellcode:

const
  S_AGENT = 'YouAreSkored';

function UploadToFtp(serverName, userid, password, fileName: string): LongBool;
var
  hNet, hCon: HINTERNET;
begin
  Result := False;
  hNet := InternetOpen(S_AGENT, INTERNET_OPEN_TYPE_DIRECT, nil, nil, 0);
  if Assigned(hNet) then
  begin
    hCon := InternetConnect(hNet, PChar(servername),
        INTERNET_DEFAULT_FTP_PORT, PChar(userid), PChar(password),
        INTERNET_SERVICE_FTP, INTERNET_FLAG_PASSIVE, 0
    );
    if Assigned(hCon) then
    begin
      Result := FtpPutFile(hNet, PChar(fileName),
          PChar(ExtractFileName(fileName)), FTP_TRANSFER_TYPE_ASCII, 0
      );
      InternetCloseHandle(hCon);
    end else ShowMessage(SysErrorMessage(GetLastError));
    InternetCloseHandle(hNet);
  end else ShowMessage(SysErrorMessage(GetLastError));
end;

Grüße vom marabu

Da zeigt er bei mir keine Nachricht an.

So aus der Ferne sieht es dann sehr gut aus: Ohne Nachricht auch kein Fehler.
Bist du mal schrittweise durch den Code gegangen?

Klar, aber ich sehe ja auch nicht den geringsten Fehler.

Hallo,

FtpPutFile muss der Rückgabewert von InternetConnect übergeben werden. D.h hCon anstatt hNet.

markieren

Delphi-Quellcode:

Result := FtpPutFile(hCon, PChar(fileName),
          PChar(ExtractFileName(fileName)), FTP_TRANSFER_TYPE_ASCII, 0
      );

Ich komme ja nicht mal bis zu FTPPutFile.

Wie hast du den "serverName" angegeben? Muss ohne "ftp://" sein.

Hallo,

nach Korrektur des von Tom gefundenen Fehlers funktioniert der Code einwandfrei.

zusammenfalten · markieren

Delphi-Quellcode:

const
  S_AGENT = 'YouAreSkored';

function UploadToFtp(serverName, userid, password, fileName: string): LongBool;
var
  hNet, hCon: HINTERNET;
begin
  Result := False;
  hNet := InternetOpen(S_AGENT, INTERNET_OPEN_TYPE_DIRECT, nil, nil, 0);
  if Assigned(hNet) then
  begin
    hCon := InternetConnect(hNet, PChar(servername),
        INTERNET_DEFAULT_FTP_PORT, PChar(userid), PChar(password),
        INTERNET_SERVICE_FTP, INTERNET_FLAG_PASSIVE, 0
    );
    if Assigned(hCon) then
    begin
      Result := FtpPutFile(hCon, PChar(fileName),
          PChar(ExtractFileName(fileName)), FTP_TRANSFER_TYPE_ASCII, 0
      );
      InternetCloseHandle(hCon);
    end else ShowMessage(SysErrorMessage(GetLastError));
    InternetCloseHandle(hNet);
  end else ShowMessage(SysErrorMessage(GetLastError));
end;

procedure TDemoForm.TestClick(Sender: TObject);
begin
  if UploadToFtp('localhost', 'achim', '', ExtractFileName(ParamStr(0)))
    then ShowMessage('alli swell')
    else ShowMessage(SysErrorMessage(GetLastError));
end;

Das Protokoll ist natürlich nicht Bestandteil des Server-Namens. Ich würde die Prozedur noch so abändern, dass die Datei nicht immer im Current Working Directory abgelegt wird.

Freundliche Grüße

Joa, es liegt gar nicht am Code, sondern an meinem FTP. Kennt ihr ohost.de?
Habe mich versucht zu name.na.ohost.de zu verbinden, aber das klappt nicht. Es liegt
also an ohost selbst.