AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Sprachen und Entwicklungsumgebungen Sonstige Fragen zu Delphi Delphi Doppelte Zeichen in einem String finden/löschen

Doppelte Zeichen in einem String finden/löschen

Ein Thema von Liu · begonnen am 6. Nov 2009 · letzter Beitrag vom 6. Nov 2009
Antwort Antwort
Liu

Registriert seit: 6. Nov 2009
2 Beiträge
 
#1

Doppelte Zeichen in einem String finden/löschen

  Alt 6. Nov 2009, 20:22
Guten Abend
Ich habe versucht, eine Funktion zu entwerfen, die jedes Zeichen in einem String mit jedem anderen vergleicht und falls ein Zeichen mehrfach auftaucht, alle bis auf das vorne stehende Zeichen zu löschen. Als Beispiel: Aus REGENSCHIRMSTAENDER müsste REGNSCHIMTAD werden. Allerdings löscht er bei mir alle Zeichen die 3 mal oder öfter vorkommen komplett, so dass RGNSCHIMTAD entsteht.

Delphi-Quellcode:
function DeleteChar(s: string): string;
var i,j,n: integer;
begin
n:=length(s);
j:=n-1; i:=0;
for i:=0 to n do begin
  for j:=0 to n do begin
    if ((s[i] = s[j]) and (i <> j))
      then begin
        delete(s, j, 1);
        dec(n);
      end;
    end;
end;
Sieht jemand den Fehler?


Gruß

Liu
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.534 Beiträge
 
Delphi 11 Alexandria
 
#2

Re: Doppelte Zeichen in einem String finden/löschen

  Alt 6. Nov 2009, 20:30
Strings beginnen bei Index 1 und ich würde einmal überprüfen, ob das dec(n) wirklich Einfluss auf die Laufvariablen hat (Debugger).

P.S.: Willkommen in der DP
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.017 Beiträge
 
Delphi 12 Athens
 
#3

Re: Doppelte Zeichen in einem String finden/löschen

  Alt 6. Nov 2009, 20:35
Bei For-Schleifen merkt sich Delphi das Ende.
Also n wird zu Beginn zwischengespeichert und dann nicht nochmals neu ausgewertet.

Daraum macht man For-Schleifen rückwärst, wenn man darin was löscht.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.534 Beiträge
 
Delphi 11 Alexandria
 
#4

Re: Doppelte Zeichen in einem String finden/löschen

  Alt 6. Nov 2009, 20:40
Alternativvorschlag (nicht großartig getestet):
Delphi-Quellcode:
function DeleteDoubleChars(const s: string): string;
var iStart, iEnd: integer;
begin
  iStart := 1;
  Result := s;
  while iStart <= Length(Result) do
    begin
      iEnd := Length(Result);
      while iEnd > iStart do
        begin
          if Result[iEnd] = Result[iStart] then
            Delete(Result,iEnd,1);
          Dec(iEnd);
        end;
      Inc(iStart);
    end;
end;
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.017 Beiträge
 
Delphi 12 Athens
 
#5

Re: Doppelte Zeichen in einem String finden/löschen

  Alt 6. Nov 2009, 20:47
Delphi-Quellcode:
function DeleteChar(const s: AnsiString): AnsiString;
var
  u: set of AnsiChar;
  i: integer;
begin
  result := s;
  u := [];
  i := 1;
  while i <= Length(result) do
    if result[i] in u then
      delete(result, i, 1)
    else
    begin
      Include(u, result[i]);
      Inc(i);
    end;
end;
Delphi-Quellcode:
function DeleteChar(const s: AnsiString): AnsiString;
var
  u: set of AnsiChar;
  i: integer;
begin
  result := '';
  u := [];
  for i := 1 to Length(s) do
    if not (s[i] in u) then
    begin
      Include(u, s[i]);
      result := result + s[i];
    end;
end;
die Ersten sind schneller, gehen aber nur für AnsiStrings (also für String bis Delphi 2007)
Delphi-Quellcode:
function DeleteChar(const s: string): string;
var i, j: integer;
begin
  result := s;
  i := 1;
  while i <= Length(result) do
    for j := 1 to i - 1 do begin
      if result[i] = result[j] then
        Delete(result, i, 1)
      end
      else
        Inc(i);
    end;
end;
und das entspricht deinem.

wobei in While- und Repeat-Schleifen in jedem Durchgang die Ausstiegsbedingung neu bewertet wird.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.534 Beiträge
 
Delphi 11 Alexandria
 
#6

Re: Doppelte Zeichen in einem String finden/löschen

  Alt 6. Nov 2009, 20:49
@himi: Wieso löschst Du aus s und nicht aus Result?

[edit] Hatter selbst gemerkt [/edit]
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Alter Mann

Registriert seit: 15. Nov 2003
Ort: Berlin
934 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#7

Re: Doppelte Zeichen in einem String finden/löschen

  Alt 6. Nov 2009, 20:50
Hallo

vergleiche mal hiermit:
Delphi-Quellcode:
unit frmMain;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Label1: TLabel;
    Edit1: TEdit;
    Button1: TButton;
    Edit2: TEdit;
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  CL : TStringList;
  I : Integer;
  S : String;
begin
  CL := TStringList.Create;
  try
    for I := 1 to Length(Edit1.Text) do
     if CL.IndexOf(Edit1.Text[I]) = -1 then CL.Add(Edit1.Text[I]);
    for I := 0 to CL.Count - 1 do S := S + CL.Strings[I];
    Edit2.Text := S;
  finally
    CL.Free;
  end;
end;

end.
Viele Grüße und Erfolg, sowie gutes Gelingen

wünscht


Alter Mann

PS die 'anderen' waren schneller, trozdem für's Vertsändnis.
  Mit Zitat antworten Zitat
Liu

Registriert seit: 6. Nov 2009
2 Beiträge
 
#8

Re: Doppelte Zeichen in einem String finden/löschen

  Alt 6. Nov 2009, 20:59
Vielen Dank an Alle für die schnellen Antworten. Es funktioniert jetzt
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 13:45 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz