Einzelnen Beitrag anzeigen

Delphi.Narium

Registriert seit: 27. Nov 2017
1.724 Beiträge
 
Delphi 7 Professional
 
#7

AW: Leeren Text "" in MS-SQL Feld NOT NULL Problem

  Alt 30. Jun 2020, 14:48
VarChar(Max - 1)?

Edit:

In meinem ollen Delphi 7 finde ich in der ADODB.pas folgendes:
Delphi-Quellcode:
procedure TCustomADODataSet.SetFieldData(Field: TField; Buffer: Pointer; NativeFormat: Boolean);

  procedure BufferToVar(var Data: OleVariant);
  begin
    case Field.DataType of
      ftString, ftFixedChar, ftGuid:
        Data := WideString(PChar(Buffer));
      ftWideString:
        Data := WideString(Buffer^);
      ftAutoInc, ftInteger:
        Data := LongInt(Buffer^);
      ftSmallInt:
        Data := SmallInt(Buffer^);
      ftWord:
        Data := Word(Buffer^);
      ftBoolean:
        Data := WordBool(Buffer^);
      ftFloat, ftCurrency:
        Data := Double(Buffer^);
      ftBlob, ftMemo, ftGraphic, ftVariant:
        Data := Variant(Buffer^);
      ftInterface:
        Data := IUnknown(Buffer^);
      ftIDispatch:
        Data := IDispatch(Buffer^);
      ftDate, ftTime, ftDateTime:
        if NativeFormat then
          DataConvert(Field, Buffer, @TVarData(Data).VDate, False) else
          Data := TDateTime(Buffer^);
      ftBCD:
        if NativeFormat then
          DataConvert(Field, Buffer, @TVarData(Data).VCurrency, False) else
          Data := Currency(Buffer^);
      ftBytes, ftVarBytes:
        if NativeFormat then
          DataConvert(Field, Buffer, @Data, False) else
          Data := OleVariant(Buffer^);
      ftLargeInt:
        Data := LargeInt(Buffer^);
      else
        DatabaseErrorFmt(SUsupportedFieldType, [FieldTypeNames[Field.DataType],
          Field.DisplayName]);
    end;
  end;

var
  Data: OleVariant;
  RecBuf: PChar;
begin
  with Field do
  begin
    if not (State in dsWriteModes) then DatabaseError(SNotEditing, Self);
    GetActiveRecBuf(RecBuf);
    if FieldNo > 0 then
    begin
      if ReadOnly and not (State in [dsSetKey, dsFilter]) then
        DatabaseErrorFmt(SFieldReadOnly, [DisplayName]);
      Validate(Buffer);
      if FModifiedFields.IndexOf(Field) = -1 then
        FModifiedFields.Add(Field);
    end;
    if Buffer = nil then
      Data := Null else
      BufferToVar(Data);
    PVariantList(RecBuf+SizeOf(TRecInfo))[Field.Index] := Data;
    if not (State in [dsCalcFields, dsInternalCalc, dsFilter, dsNewValue]) then
      DataEvent(deFieldChange, Longint(Field));
  end;
end;
In BufferToVar ist eine "Case-Kaskade".

Äquivalent in Deiner Delphiversion suchen und dann "einfach" ftMemo an der vorhandenen Stelle "rausschmeißen" und bei ftString hinzufügen.

Das in 'ner eigenen "Variante" der entsprechenden Unit anpassen und diese, statt des Originals einbinden.

Sprich: Original umbenennen und durch Deine Variante ersetzen

oder

die eigene Variante ins Projekt aufnehmen, im Bibliothekspfad, Suchpfad, ... so platzieren, dass sie vor dem Original vom Compiler gefunden wird.

Am Sinnvollsten wird es wohl dann sein, die eigene Variante ins Projekt aufzunehmen und ins Projektverzeichnis zu legen, damit andere Projekte davon unberührt bleiben.

Geändert von Delphi.Narium (30. Jun 2020 um 15:08 Uhr) Grund: Text ergänzt
  Mit Zitat antworten Zitat