AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Sprachen und Entwicklungsumgebungen Sonstige Fragen zu Delphi Delphi Probleme mit Regedit und Form öffnen!!
Thema durchsuchen
Ansicht
Themen-Optionen

Probleme mit Regedit und Form öffnen!!

Ein Thema von m-werk · begonnen am 14. Jun 2002 · letzter Beitrag vom 17. Jun 2002
 
Christian Seehase
(Co-Admin)

Registriert seit: 29. Mai 2002
Ort: Hamburg
11.124 Beiträge
 
Delphi 11 Alexandria
 
#12
  Alt 14. Jun 2002, 21:05
Moin Zusammen,

dann will ich noch mal
Diesmal weniger stilisiert.

Eine Unit mit allgemeinen Funktionen:
Code:
unit Unit3; // Allgemeine Funktionen

interface

uses windows,registry,sysutils,controls;

function RegOK : Boolean;
function IsValidValue(const p_sValue : string) : Boolean;
function CheckRegistry : Boolean;

implementation
uses unit2; // Hier ist das TRegForm deklariert

function IsValidValue(const p_sValue : string) : Boolean;
begin
  // hier muss noch die Prüfung rein, oder der
  // ausgelesene Wert auch erlaubt ist.
  // In Abhängigkeit davon dann Result setzen
  Result := true;
end;

function RegOK : Boolean;

var
  REG   : TRegistry;
  sValue : string;

begin
  // Be pessimistic :))
  Result := false;
  REG   := TRegistry.Create;
  try
    REG.RootKey := HKEY_CURRENT_USER;
    if REG.OpenKey('\Software\SELF', True) then
    begin
      try
        if REG.ValueExists('CODE??') then
        begin
          try
            sValue := REG.ReadString('CODE??');
          except
            exit;
          end;
          Result := IsValidValue(sValue);
        end;
      finally
        REG.CloseKey;
      end;
    end;
  finally
    FreeAndNil(REG);
  end;
end;

function CheckRegistry : Boolean;

var
  RegForm : TRegForm;
  iResult : integer;
begin
  Result := RegOK;
  if Result then
  begin // Registrierung erfolgt, dann kann das Programm starten
    exit;
  end;
  RegForm := TRegForm.Create(nil); // aus Unit2
  try
    iResult := RegForm.ShowModal;
    Result := iResult = mrOK;
  finally
    FreeAndNil(RegForm);
  end;
end;
end.
und die mit dem Registrierungsformular.

Code:
unit Unit2;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, Registry;

type
  TRegForm = class(TForm)
    // Hier kann der der Registrierungscode eingegeben werden.
    Edit1: TEdit;
    // btOK ist das ModalResult mrOK zugeordnet
    // btCancel dann mrCancel
    btOK: TButton;
    btCancel: TButton;
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  RegForm: TRegForm;

implementation
uses Unit3; // wegen IsValidValue
{$R *.DFM}

procedure TRegForm.FormCloseQuery(Sender: TObject; var CanClose: Boolean);

var
  REG : TRegistry;

begin
  if ModalResult = mrCancel then
  begin // Wenn Abbruch, dann fertig
    CanClose := true;
    exit;
  end;
  If not IsValidValue(Edit1.Text) then
  begin // Ungültig, dann meckern
    CanClose := false;
    MessageBox(self.Handle,'Registrierungscode ungültig','FEHLER',MB_ICONERROR or MB_OK);
    exit;
  end;
  CanClose := true;
  REG := TRegistry.Create;
  try
    REG.RootKey := HKEY_CURRENT_USER;
    if REG.OpenKey('\Software\SELF', True) then
    begin
      try
        try
          REG.WriteString('CODE??',Edit1.Text);
        except
          CanClose := false;
          // Fehlermeldung
        end;
      finally
        REG.CloseKey;
      end;
    end
    else
    begin
      CanClose := false;
      // Fehlermeldung, dass Registrierung nicht geschrieben werden konnte.
    end;
  finally
    FreeAndNil(REG);
  end;
end;
end.
Die Projektdatei dann so wie oben schon angegeben

@Mathias:
Zitat von Mathias:
Du musst "RegOK" nur vor "CheckRegistry" in der Unit definieren, sonst findet letztere die erstere nicht.
Warum? Ich habe die beiden ja schon vor dem Implementation Abschnitt deklariert. Daher "weiss" der Compiler doch, was ihn erwartet
Tschüss Chris
Die drei Feinde des Programmierers: Sonne, Frischluft und dieses unerträgliche Gebrüll der Vögel.
Der Klügere gibt solange nach bis er der Dumme ist
  Mit Zitat antworten Zitat
 


Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 16:21 Uhr.
Powered by vBulletin® Copyright ©2000 - 2025, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024-2025 by Thomas Breitkreuz