AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Win32/Win64 API (native code) Delphi SHFileOperation: Wie Dateien mit sehr langem Dateinamen kopieren?
Thema durchsuchen
Ansicht
Themen-Optionen

SHFileOperation: Wie Dateien mit sehr langem Dateinamen kopieren?

Ein Thema von HeikoAdams · begonnen am 24. Feb 2011 · letzter Beitrag vom 22. Mär 2014
Antwort Antwort
Benutzerbild von mleyen
mleyen

Registriert seit: 10. Aug 2007
609 Beiträge
 
FreePascal / Lazarus
 
#1

AW: SHFileOperation: Wie Dateien mit sehr langem Dateinamen kopieren?

  Alt 24. Feb 2011, 11:29
Auf die nicht existierende aDest-Datei würd ich es jetzt auch nicht anwenden.
Ansonsten kann man afaik immer den langen Dateinamen wieder rausbekommen.

Aber der '\\?\'-Trick scheint ja die offizielle-ordentliche Variante zu sein.
  Mit Zitat antworten Zitat
Benutzerbild von HeikoAdams
HeikoAdams

Registriert seit: 12. Jul 2004
Ort: Oberfranken
661 Beiträge
 
FreePascal / Lazarus
 
#2

AW: SHFileOperation: Wie Dateien mit sehr langem Dateinamen kopieren?

  Alt 25. Feb 2011, 07:27
Okay, mit dieser Funktion sollte dann also das Kopieren von Dateien mit sehr langem Dateinamen klappen:
Delphi-Quellcode:
function ShellFileCopy(const aSource, aDest: string): Integer;
var
  SH: TSHFileOpStructW;
  sSource, sDest: WideString;
begin
  ZeroMemory(@SH, SizeOf(SH));
  sSource := aSource;
  sDest := ExtractFilePath(aDest);

  if (Length(sSource) > MAX_PATH) then
     if (Copy(sSource, 1, 2) = '\\') then
        sSource := '\\?\UNC' + sSource
    else
       sSource := '\\?\' + sSource;

  if (Length(sDest) > MAX_PATH) then
     if (Copy(sDest, 1, 2) = '\\') then
        sDest := '\\?\UNC' + sDest
    else
       sDest := '\\?\' + sDest;

  try
    with SH do
    begin
      Wnd := 0;
      wFunc := FO_COPY;
      pFrom := PWideChar(sSource + #0);
      pTo := PWideChar(sDest + #0);
      fFlags := FOF_ALLOWUNDO or FOF_NOCONFIRMATION or FOF_NOCONFIRMMKDIR or
        FOF_SILENT;
    end;

    Result := SHFileOperationW(SH);
  finally
     ZeroMemory(@SH, SizeOf(SH));
  end;
end;
Oder ist mir da irgend ein Denkfehler unterlaufen?
Jeder kann ein Held werden und Leben retten!
Einfach beim NKR oder der DKMS als Stammzellenspender registrieren! Also: worauf wartest Du noch?

Geändert von HeikoAdams (25. Feb 2011 um 08:01 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
44.580 Beiträge
 
Delphi 12 Athens
 
#3

AW: SHFileOperation: Wie Dateien mit sehr langem Dateinamen kopieren?

  Alt 25. Feb 2011, 08:04
if (Length(sXYZ) >= MAX_PATH) and not StartsText('\\?\', sXYZ) then ?

Sonst würdest du es auch anhängen, wenn es schon da ist.
Und vergißt bitte nicht, daß in MAX_PATH die abschließende #0 mitgezählt wird (drum >= ).

Und sicherheitshalber noch ein sXYZ := ExpandFileName(sXYZ); davor.
Ein Therapeut entspricht 1024 Gigapeut.
  Mit Zitat antworten Zitat
Benutzerbild von HeikoAdams
HeikoAdams

Registriert seit: 12. Jul 2004
Ort: Oberfranken
661 Beiträge
 
FreePascal / Lazarus
 
#4

AW: SHFileOperation: Wie Dateien mit sehr langem Dateinamen kopieren?

  Alt 25. Feb 2011, 09:27
Zwei Probleme:
1: Der problematische Dateiname ist "nur" 250 Zeichen lang, MAX_PATH steht aber auf 260
2: Wenn ich pauschal den Pfaden ein "\\?\" voranstelle, liefert SHFileOperation den Fehler 124 (Die Ebene des Systemaufrufs ist falsch) zurück
Jeder kann ein Held werden und Leben retten!
Einfach beim NKR oder der DKMS als Stammzellenspender registrieren! Also: worauf wartest Du noch?
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
44.580 Beiträge
 
Delphi 12 Athens
 
#5

AW: SHFileOperation: Wie Dateien mit sehr langem Dateinamen kopieren?

  Alt 25. Feb 2011, 10:06
1: Der problematische Dateiname ist "nur" 250 Zeichen lang, MAX_PATH steht aber auf 260
Der Dateiname?

Also, der gesamte Pfad (Datei + Verzeichnis), ohne Laufwerk ( C:\ ) darf nicht länger als 256 Zeichen sein (inkl. der #0 oder war's ohne dieser ) ,
zumindestens ist das bei den standardmäßig vorhandenen FAT- und NTFS-Treibern so.

2.
Und was ist mit einem '\\.\' ?
Ein Therapeut entspricht 1024 Gigapeut.
  Mit Zitat antworten Zitat
Benutzerbild von HeikoAdams
HeikoAdams

Registriert seit: 12. Jul 2004
Ort: Oberfranken
661 Beiträge
 
FreePascal / Lazarus
 
#6

AW: SHFileOperation: Wie Dateien mit sehr langem Dateinamen kopieren?

  Alt 25. Feb 2011, 10:18
Der Dateiname?

Also, der gesamte Pfad (Datei + Verzeichnis), ohne Laufwerk ( C:\ ) darf nicht länger als 256 Zeichen sein (inkl. der #0 oder war's ohne dieser ) ,
zumindestens ist das bei den standardmäßig vorhandenen FAT- und NTFS-Treibern so.
Mit "Dateiname" hab ich den kompletten Dateinamen inklusive Pfad gemeint

2.
Und was ist mit einem '\\.\' ?
Genau der gleiche Fehlercode: 124 (Die Ebene des Systemaufrufs ist falsch)

Oder kann es vielleicht sein, das SHFileOperation mit diesen Präfixen nicht klar kommt?
Jeder kann ein Held werden und Leben retten!
Einfach beim NKR oder der DKMS als Stammzellenspender registrieren! Also: worauf wartest Du noch?
  Mit Zitat antworten Zitat
Benutzerbild von HeikoAdams
HeikoAdams

Registriert seit: 12. Jul 2004
Ort: Oberfranken
661 Beiträge
 
FreePascal / Lazarus
 
#7

AW: SHFileOperation: Wie Dateien mit sehr langem Dateinamen kopieren?

  Alt 28. Feb 2011, 10:25
Okay, so scheint es zu funktionieren:
Delphi-Quellcode:
function ShellFileCopy(const aSource, aDest: string): Integer;
var
  SH: TSHFileOpStructW;
  sSource, sDest: WideString;
const
  sPrefix: WideString = '\\?\';
  sUNCNewPrefix: WideString = '\\?\UNC';
  sUNCPrefix: WideString = '\\';
begin
  if not StartsText(sUNCPrefix, aSource) then
     sSource := ExpandFileName(aSource);

  if not StartsText(sUNCPrefix, aDest) then
     //sDest := ExtractFilePath(ExpandFileName(aDest));
    sDest := ExpandFileName(aDest);

  if (Length(sSource) >= MAX_PATH)
     and not StartsText(sPrefix, sSource) then
     if StartsText(sUNCPrefix, sSource) then
        sSource := sUNCNewPrefix + sSource
    else
       sSource := sPrefix + sSource;

  if (Length(sDest) >= MAX_PATH)
     and not StartsText(sPrefix, sDest) then
     if StartsText(sUNCPrefix, sDest) then
        sDest := sUNCNewPrefix + sDest
    else
       sDest := sPrefix + sDest;

  ZeroMemory(@SH, SizeOf(SH));

  try
    with SH do
    begin
      Wnd := 0;
      wFunc := FO_COPY;
      pFrom := PWideChar(sSource + #0);
      pTo := PWideChar(sDest + #0);
      fFlags := FOF_ALLOWUNDO or FOF_NOCONFIRMATION or FOF_NOCONFIRMMKDIR or
        FOF_SILENT;
    end;

    Result := SHFileOperationW(SH);
  finally
    ZeroMemory(@SH, SizeOf(SH));
  end;
end;
Jeder kann ein Held werden und Leben retten!
Einfach beim NKR oder der DKMS als Stammzellenspender registrieren! Also: worauf wartest Du noch?

Geändert von HeikoAdams ( 1. Mär 2011 um 08:08 Uhr)
  Mit Zitat antworten Zitat
Antwort Antwort


Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 09:01 Uhr.
Powered by vBulletin® Copyright ©2000 - 2025, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024-2025 by Thomas Breitkreuz